R_MaintTaskListOpRelshpTP
Operation Relationships
R_MaintTaskListOpRelshpTP is a Transactional CDS View that provides data about "Operation Relationships" in SAP S/4HANA. It reads from 3 data sources (I_BillOfOperationsRelationship, I_MaintTaskListOperation, I_BOOSqncOperationAssgmtChgSt) and exposes 35 fields with key fields TaskListType, TaskListGroup, TaskListGroupCounter, TaskListSequence, TaskListOperationInternalId. It has 1 association to related views.
Data Sources (3)
| Source | Alias | Join Type |
|---|---|---|
| I_BillOfOperationsRelationship | _OpRelation | from |
| I_MaintTaskListOperation | _TLOperation | inner |
| I_BOOSqncOperationAssgmtChgSt | plas | inner |
Associations (1)
| Cardinality | Target | Alias | Condition |
|---|---|---|---|
| [1..*] | R_MaintTaskListOpBasicTP | _Operation | $projection.TaskListType = _Operation.TaskListType and $projection.TaskListGroup = _Operation.TaskListGroup and $projection.TaskListGroupCounter = _Operation.TaskListGroupCounter and $projection.SuccssrBOOOpInternalID = _Operation.TaskListOperationInternalId and $projection.TaskListSequence = _Operation.TaskListSequence |
Annotations (10)
| Name | Value | Level | Field |
|---|---|---|---|
| AbapCatalog.dataMaintenance | #RESTRICTED | view | |
| AccessControl.authorizationCheck | #CHECK | view | |
| EndUserText.label | Operation Relationships | view | |
| AccessControl.personalData.blocking | #NOT_REQUIRED | view | |
| Metadata.ignorePropagatedAnnotations | true | view | |
| VDM.viewType | #TRANSACTIONAL | view | |
| VDM.lifecycle.contract.type | #SAP_INTERNAL_API | view | |
| ObjectModel.usageType.serviceQuality | #C | view | |
| ObjectModel.usageType.sizeCategory | #L | view | |
| ObjectModel.usageType.dataClass | #MIXED | view |
Fields (35)
| Key | Field | Source Table | Source Field | Description |
|---|---|---|---|---|
| KEY | TaskListType | I_BillOfOperationsRelationship | BillOfOperationsType | |
| KEY | TaskListGroup | I_BillOfOperationsRelationship | PrdcssrBOOGroup | |
| KEY | TaskListGroupCounter | I_BillOfOperationsRelationship | PrdcssrBOOVariant | |
| KEY | TaskListSequence | I_MaintTaskListOperation | TaskListSequence | |
| KEY | TaskListOperationInternalId | I_BillOfOperationsRelationship | PrdcssrBOOOpInternalID | |
| KEY | TaskListOpBOMItmIntVersCounter | I_BillOfOperationsRelationship | BOOInternalVersionCounter | |
| SuccssrBOOGroup | I_BillOfOperationsRelationship | SuccssrBOOGroup | ||
| SuccssrBOOOpInternalID | I_BillOfOperationsRelationship | SuccssrBOOOpInternalID | ||
| MasterRecipeRelationshipType | I_BillOfOperationsRelationship | MasterRecipeRelationshipType | ||
| MaxTimeIntvlIsUsedForSchedg | I_BillOfOperationsRelationship | MaxTimeIntvlIsUsedForSchedg | ||
| MaintenanceTaskListOperation | ||||
| SuperiorOperation | ||||
| OperationText | I_MaintTaskListOperation | OperationText | ||
| BOORelationshipType | I_BillOfOperationsRelationship | BOORelationshipType | ||
| WorkCenter | ||||
| ValidityStartDate | I_BillOfOperationsRelationship | ValidityStartDate | ||
| ValidityEndDate | I_BillOfOperationsRelationship | ValidityEndDate | ||
| CreationDate | I_BillOfOperationsRelationship | CreationDate | ||
| CreatedByUser | I_BillOfOperationsRelationship | CreatedByUser | ||
| LastChangeDate | I_BillOfOperationsRelationship | LastChangeDate | ||
| LastChangedByUser | I_BillOfOperationsRelationship | LastChangedByUser | ||
| ChangeNumber | I_BillOfOperationsRelationship | ChangeNumber | ||
| TimeIntvlBtwnRelshp | I_BillOfOperationsRelationship | TimeIntvlBtwnRelshp | ||
| MaxTimeIntvlBtwnRelshp | I_BillOfOperationsRelationship | MaxTimeIntvlBtwnRelshp | ||
| TimeIntvlBtwnRelshpUnit | I_BillOfOperationsRelationship | TimeIntvlBtwnRelshpUnit | ||
| OperationIsSuccessor | I_BillOfOperationsRelationship | OperationIsSuccessor | ||
| OperationIsPredecessor | I_BillOfOperationsRelationship | OperationIsPredecessor | ||
| FactoryCalendar | I_BillOfOperationsRelationship | FactoryCalendar | ||
| IsDeleted | I_BillOfOperationsRelationship | IsDeleted | ||
| IsImplicitlyDeleted | I_BillOfOperationsRelationship | IsImplicitlyDeleted | ||
| WorkCenterInternalID | I_BillOfOperationsRelationship | WorkCenterInternalID | ||
| Plant | I_BillOfOperationsRelationship | Plant | ||
| _Operation | _Operation | |||
| _NonHistOp | _NonHistOp | |||
| _Header | _Header |
//@AbapCatalog.sqlViewName: 'RMAINTTLOPRELSHP'
//@AbapCatalog : { preserveKey: true, dataMaintenance:#RESTRICTED }
@AbapCatalog : { dataMaintenance:#RESTRICTED }
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Operation Relationships'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
//@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
define view entity R_MaintTaskListOpRelshpTP
as select from I_BillOfOperationsRelationship as _OpRelation
inner join I_BOOSqncOperationAssgmtChgSt as plas on _OpRelation.BillOfOperationsType = plas.BillOfOperationsType
and _OpRelation.PrdcssrBOOGroup = plas.BillOfOperationsGroup
and _OpRelation.PrdcssrBOOOpInternalID = plas.BOOOperationInternalID
inner join I_MaintTaskListOperation as _TLOperation on _OpRelation.BillOfOperationsType = _TLOperation.TaskListType
and _OpRelation.PrdcssrBOOGroup = _TLOperation.TaskListGroup
and _OpRelation.PrdcssrBOOVariant = _TLOperation.TaskListGroupCounter
and _OpRelation.PrdcssrBOOOpInternalID = _TLOperation.TaskListOperationInternalId
association [1..*] to R_MaintTaskListOpBasicTP as _Operation on $projection.TaskListType = _Operation.TaskListType
and $projection.TaskListGroup = _Operation.TaskListGroup
and $projection.TaskListGroupCounter = _Operation.TaskListGroupCounter
and $projection.SuccssrBOOOpInternalID = _Operation.TaskListOperationInternalId
and $projection.TaskListSequence = _Operation.TaskListSequence
association to parent R_MaintTaskListOperationTP as _NonHistOp on $projection.TaskListType = _NonHistOp.TaskListType
and $projection.TaskListGroup = _NonHistOp.TaskListGroup
and $projection.TaskListGroupCounter = _NonHistOp.TaskListGroupCounter
and $projection.TaskListSequence = _NonHistOp.TaskListSequence
and $projection.TaskListOperationInternalId = _NonHistOp.TaskListOperationInternalId
association to R_MaintenanceTaskListTP as _Header on $projection.TaskListType = _Header.TaskListType
and $projection.TaskListGroup = _Header.TaskListGroup
and $projection.TaskListGroupCounter = _Header.TaskListGroupCounter
{
key _OpRelation.BillOfOperationsType as TaskListType,
key _OpRelation.PrdcssrBOOGroup as TaskListGroup,
key _OpRelation.PrdcssrBOOVariant as TaskListGroupCounter,
key _TLOperation.TaskListSequence as TaskListSequence,
key _OpRelation.PrdcssrBOOOpInternalID as TaskListOperationInternalId,
key _OpRelation.BOOInternalVersionCounter as TaskListOpBOMItmIntVersCounter,
// plas.BillOfOperationsSequence as TaskListSequence,
_OpRelation.SuccssrBOOGroup,
_OpRelation.SuccssrBOOOpInternalID,
_OpRelation.MasterRecipeRelationshipType,
_OpRelation.MaxTimeIntvlIsUsedForSchedg,
cast(_Operation.MaintenanceTaskListOperation as pph_vornr preserving type) as MaintenanceTaskListOperation,
cast(_TLOperation.MaintenanceTaskListOperation as pph_vornr preserving type) as SuperiorOperation,
_TLOperation.OperationText as OperationText,
_OpRelation.BOORelationshipType,
_TLOperation._WorkCenter.WorkCenter as WorkCenter,
@Semantics.businessDate.from: true
_OpRelation.ValidityStartDate,
@Semantics.businessDate.to: true
_OpRelation.ValidityEndDate,
@Semantics.systemDate.createdAt: true
_OpRelation.CreationDate,
@Semantics.user.createdBy: true
_OpRelation.CreatedByUser,
@Semantics.systemDate.lastChangedAt: true
_OpRelation.LastChangeDate,
@Semantics.user.lastChangedBy: true
_OpRelation.LastChangedByUser,
_OpRelation.ChangeNumber as ChangeNumber,
@Semantics.quantity.unitOfMeasure: 'TimeIntvlBtwnRelshpUnit'
_OpRelation.TimeIntvlBtwnRelshp,
@Semantics.quantity.unitOfMeasure: 'TimeIntvlBtwnRelshpUnit'
_OpRelation.MaxTimeIntvlBtwnRelshp,
_OpRelation.TimeIntvlBtwnRelshpUnit,
_OpRelation.OperationIsSuccessor,
_OpRelation.OperationIsPredecessor,
_OpRelation.FactoryCalendar,
_OpRelation.IsDeleted,
_OpRelation.IsImplicitlyDeleted,
_OpRelation.WorkCenterInternalID,
_OpRelation.Plant as Plant,
_Operation,
_NonHistOp,
_Header
}
where
_TLOperation.MaintTaskListSubOperation = ' ';
Learn More
- What Is a CDS View in SAP S/4HANA?
- Types of CDS Views: Basic, Composite, Consumption, and Transactional
- SAP Tables vs CDS Views — Key Differences
- Understanding Data Lineage in SAP S/4HANA
- VDM (Virtual Data Model) in SAP S/4HANA Explained
- CDS View Annotations — A Complete Guide
- CDS View Field Mapping and Associations
- Understanding the SAP S/4HANA Data Model
- CDS View Extensions and Custom Fields in SAP S/4HANA
- Released APIs and Stability Contracts in SAP S/4HANA