R_MaintTaskListOpMaterialTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Operation Components'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}

define view entity R_MaintTaskListOpMaterialTP
  as select distinct from I_MaintTaskListOpMaterial
  association        to parent R_MaintTaskListOperationTP as _NonHistOp         on  $projection.TaskListType                = _NonHistOp.TaskListType
                                                                                and $projection.TaskListGroup               = _NonHistOp.TaskListGroup
                                                                                and $projection.TaskListGroupCounter        = _NonHistOp.TaskListGroupCounter
                                                                                and $projection.TaskListSequence            = _NonHistOp.TaskListSequence
                                                                                and $projection.TaskListOperationInternalId = _NonHistOp.TaskListOperationInternalId
  association [0..1] to R_MaintTaskListOpBasicTP          as _TaskListOperation on  $projection.TaskListGroup                  = _TaskListOperation.TaskListGroup
                                                                                and $projection.TaskListGroupCounter           = _TaskListOperation.TaskListGroupCounter
                                                                                and $projection.TaskListSequence               = _TaskListOperation.TaskListSequence
                                                                                and $projection.TaskListOperationInternalId    = _TaskListOperation.TaskListOperationInternalId
                                                                                and $projection.TaskListType                   = _TaskListOperation.TaskListType
                                                                                and $projection.TaskListOpBOMItmIntVersCounter = _TaskListOperation.TaskListOpBOMItmIntVersCounter

 association        to R_MaintenanceTaskListTP           as _Header               on  $projection.TaskListType         = _Header.TaskListType
                                                                                   and $projection.TaskListGroup        = _Header.TaskListGroup
                                                                                   and $projection.TaskListGroupCounter = _Header.TaskListGroupCounter
                                                                                   
  association [0..1] to I_Equipment            as _Equipment            on  $projection.Equipment            = _Equipment.Equipment 
  association [0..1] to I_FunctionalLocation   as _FunctionalLocation   on  $projection.FunctionalLocation   = _FunctionalLocation.FunctionalLocation 
  association [0..1] to I_EquipmentTimeSeg     as _Equipmentts          on  $projection.Equipment            = _Equipmentts.Equipment   
                                                                        and _Equipmentts.ValidityEndDate     = '99991231'
                                                                        and _Equipmentts.EquipUsagePeriodSequenceNumber = '001' -- HasEquipmentData = 'X'
  

{

  key TaskListType,
  key TaskListGroup,
  key TaskListGroupCounter,
  key TaskListSequence,
  key TaskListOperationInternalId,
  key TaskListOpBOMItmInternalID,
  key TaskListOpBOMItmIntVersCounter,
      _TaskListOperation.MaintenanceTaskListOperation                                                                                          as MaintenanceTaskListOperation,
      BillOfMaterialComponent                                                                                                                  as Material,
      case when BillOfMaterialComponent = ''
        then _BOMItemEAM.BOMItemDescription
        else _BillOfMaterialComponent._Text[1: Language = $session.system_language ].MaterialName
      end                                                                                                                                      as MaterialName,
      @Semantics.quantity.unitOfMeasure: 'BillOfMaterialItemUnit'
      BillOfMaterialItemQuantity,
      BillOfMaterialItemUnit,
      I_MaintTaskListOpMaterial._SafetyRelevance.SafetyRelevantObject                                                                          as SafetyRelevantObject,
      I_MaintTaskListOpMaterial._SafetyRelevance._SafetyRelevanceCode._Text[1: Language = $session.system_language ].SafetyRelevanceActionDesc as SafetyRelevanceActionDesc,
      BillOfMaterialCategory,
      BillOfMaterialVariant,
      BillOfMaterialItemNodeNumber,
      MatlCompIsMarkedForBackflush,
      IsDeleted,
      @Semantics.booleanIndicator: true
      ResvnIsMRPRlvtOrPurReqnIsCrted,

      _BOMItemEAM.BillOfMaterialItemCategory                                                                                                   as BillOfMaterialItemCategory,
      _BOMItemCategoryText.BillOfMaterialItemCategoryDesc                                                                                      as BillOfMaterialItemCategoryDesc,
      _MatlsPlngRelevancy._Text[1: Language = $session.system_language ].MatlsPlngRelevancyCodeName                                            as MatlsPlngRelevancyCodeName,

      /* Associations */
      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsOperation,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BOOOperationInternalID,
      _BillOfMaterialComponent,
      /* Associations - DCL */
      Equipment,
      FunctionalLocation,
      _MaintenanceTaskList.Plant                                                                                                               as Plant,
      _MaintenanceTaskList.TaskListStatus                                                                                                      as TaskListStatus,
      _MaintenanceTaskList.ResponsiblePlannerGroup                                                                                             as ResponsiblePlannerGroup,                                                

      case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipment.AuthorizationGroup
        else _FunctionalLocation.AuthorizationGroup
      end as AuthorizationGroup,
      
      case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts.MaintenancePlanningPlant 
        else _FunctionalLocation.MaintenancePlanningPlant 
      end as MaintenancePlanningPlant,
      
       case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts.MaintenancePlannerGroup 
        else _FunctionalLocation.MaintenancePlannerGroup 
      end as MaintenancePlannerGroup,
      
      case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts._LocationAccountAssignment.ControllingArea  
        else _FunctionalLocation._LocationAccountAssignment.ControllingArea  
      end as ControllingArea,
      
       case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts._LocationAccountAssignment.CostCenter
        else _FunctionalLocation._LocationAccountAssignment.CostCenter  
      end as CostCenter,
      
       case TechObjIsEquipOrFuncnlLoc
        when 'EAMS_EQUI' then _Equipmentts._LocationAccountAssignment.MaintenancePlant  
        else _FunctionalLocation._LocationAccountAssignment.MaintenancePlant  
      end as MaintenancePlant,
      
      _TaskListOperation,
      _NonHistOp,
      _Header

}
where ( TaskListType = 'A' or TaskListType = 'E' or TaskListType = 'T' ) and
  IsDeleted != 'X'