R_MaintItemObjectListItemTP

@EndUserText.label: 'Maintenance Item Object List Item'
@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@Metadata.ignorePropagatedAnnotations:true

@ObjectModel: {
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #L,
    usageType.dataClass: #MASTER,
    modelingPattern: #TRANSACTIONAL_ENTITY,
    supportedCapabilities: [ #TRANSACTIONAL_PROVIDER ]
}


define view entity R_MaintItemObjectListItemTP
  as select from I_MaintItemObjectListItem

  association        to parent R_MaintenanceItemTP     as _MaintenanceItemTP             on $projection.MaintenanceItem = _MaintenanceItemTP.MaintenanceItem
  association [0..1] to R_MaintenanceItemTP            as _MaintenanceItem               on $projection.MaintenanceItem = _MaintenanceItem.MaintenanceItem
  association [0..1] to I_FunctionalLocationLabel      as _FunctionalLocationLabel       on $projection.FunctionalLocation = _FunctionalLocationLabel.FunctionalLocation
  association [0..*] to I_TechObjIsEquipOrFuncnlLocT   as _TechObjIsEquipOrFuncnlLocDesc on $projection.TechObjIsEquipOrFuncnlLoc = _TechObjIsEquipOrFuncnlLocDesc.TechObjIsEquipOrFuncnlLoc
  association [0..*] to I_EquipmentText                as _EquipmentText                 on $projection.Equipment = _EquipmentText.Equipment
  association [0..*] to I_FunctionalLocationText       as _FunctionalLocationText        on $projection.FunctionalLocation = _FunctionalLocationText.FunctionalLocation
  association [0..*] to I_MaintItemRefObjectTypeText   as _ReferenceObjectTypeText       on $projection.MaintItemReferenceObjectType = _ReferenceObjectTypeText.MaintItemReferenceObjectType
  association [0..*] to I_MaintItmRefObjTypeForSrvcTxt as _RefObjectTypeForSrvcText      on $projection.MaintItemRefObjTypeForService = _RefObjectTypeForSrvcText.MaintItemReferenceObjectType
{

  key MaintenanceItem,

  key MaintenanceItemObjectList,

  key MaintenanceObjectListItem,

      MaintenanceObjectListUsageCode,

      Equipment,

      FunctionalLocation,

      _FunctionalLocationLabel.FunctionalLocationLabelName,

      cast( case when Equipment <> '' then 'EAMS_EQUI'
                 when FunctionalLocation <> '' then 'EAMS_FL' end as eams_tec_obj_type_value ) as TechObjIsEquipOrFuncnlLoc,

      cast( case when Equipment <> '' then Equipment
                 else FunctionalLocation end as eams_tec_obj )                                 as TechnicalObject,

      cast( case when Equipment <> '' then Equipment
                 else case when FunctionalLocation <> '' then _FunctionalLocationLabel.FunctionalLocationLabelName
                           else '' end end as eams_tech_obj_alpha_conv )                       as TechnicalObjectLabel,

      @Semantics.text: true
      cast( case when Equipment <> '' then _EquipmentText[1:Language = $session.system_language].EquipmentName
                 else case when FunctionalLocation <> '' then _FunctionalLocationText[1:Language = $session.system_language].FunctionalLocationName
                           else '' end end as eams_tec_obj_des )                               as TechnicalObjectDescription,


      //      -- Reference Object


      cast( case when MaintenancePlanCallObject <> '5' then ''
            else case when Equipment               <> '' then 'EAMS_EQUI'
                      when FunctionalLocation      <> '' then 'EAMS_FLOC'
                      when ServiceReferenceProduct <> '' then 'EAMS_PROD'
                      else '' end end as eam_maintitmrefobjtypeforsrvc )                       as MaintItemRefObjTypeForService,

      cast( case when Equipment                    <> '' then 'EAMS_EQUI'
                 when FunctionalLocation           <> '' then 'EAMS_FLOC'
                 when Assembly                     <> '' then 'EAMS_ASSY'
                 else ' '   end as eam_maintitemrefobjecttype )                                as MaintItemReferenceObjectType,

      cast( case when Equipment                    <> '' then Equipment
                 when FunctionalLocation           <> '' then _FunctionalLocationLabel.FunctionalLocationLabelName
                 when Assembly                     <> '' then Assembly
                 when ServiceReferenceProduct      <> '' then ServiceReferenceProduct
                 else ' ' end as  eam_maintitemreferenceobject preserving type )               as MaintenanceItemReferenceObject,

      @Semantics.text: true
      cast( case when Equipment                   <> '' then _EquipmentText[1:Language = $session.system_language].EquipmentName
                 when FunctionalLocation          <> '' then _FunctionalLocationText[1:Language = $session.system_language].FunctionalLocationName
                 when Assembly                    <> '' then _Assembly._Text[1:Language = $session.system_language].MaterialName
                 when ServiceReferenceProduct     <> '' then _Product._Text[1:Language = $session.system_language].ProductName
                 else '' end as eam_maintitemrefobjdescription preserving type )               as MaintItemRefObjectDescription,

      MaintenanceNotification,

      Assembly,

      MaintObjectLocAcctAssgmtNmbr,

      Material,

      SerialNumber,

      UniqueItemIdentifier,

      CreationDate,

      MaintObjectListItemSequence,

      MaintObjListEntryIsProcessed,

      -- Service Field
      ServiceReferenceProduct,

      /* Needed for authorization */
      MaintenancePlanCallObject,
      MaintenancePlanningPlant,
      MaintenancePlannerGroup,
      MaintenancePlant,

      I_MaintItemObjectListItem.ControllingArea,
      I_MaintItemObjectListItem.CostCenter,

      /* Local Association */
      _MaintenanceItem,
      _MaintenanceItemTP,
      _FunctionalLocationText,
      _TechObjIsEquipOrFuncnlLocDesc,
      _ReferenceObjectTypeText,
      _RefObjectTypeForSrvcText,

      /* Inherited Associations */
      _Assembly,
      _Equipment,
      //_FunctionalLocation,

      _LocationAccountAssignment,
      _MaintenancePlanningPlant,
      _PMNotifMaintenanceData,
      _Product,
      _SerialNumber,
      _UniqueItemIdentifier,
      I_MaintItemObjectListItem._FunctionalLocation                                            as _FunctionalLocation


}