R_InhRepairItemNoteTP

@EndUserText.label: 'Notes for In-House Repair Item'
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY
}
@Metadata: {
  ignorePropagatedAnnotations: true
}
@ObjectModel: {
  usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
}

define view entity R_InhRepairItemNoteTP
  as select from           P_InhRepairItemNote as ihritemnote

  // We need an empty string field for the text. String fields cannot be created as "cast('' as systring)...".

  // Hence, we implement a dummy join that never returns a matching record but provides the string field (which then is null).

    left outer to one join crms4t_note_temp    as _InoteTemp on _InoteTemp.id = ihritemnote.InHouseRepair

  association        to parent I_InHouseRepairItemTP as _InHouseRepairItemTP on  $projection.InHouseRepair     = _InHouseRepairItemTP.InHouseRepair
                                                                             and $projection.InHouseRepairItem = _InHouseRepairItemTP.InHouseRepairItem

  association [1..1] to I_InHouseRepairTP            as _InHouseRepairTP     on  $projection.InHouseRepair = _InHouseRepairTP.InHouseRepair

  //required for authorization check

  association [1..1] to I_InHouseRepair              as _InHouseRepair       on  $projection.CustMgmtObjectType = _InHouseRepair.CustMgmtObjectType
                                                                             and $projection.InHouseRepair      = _InHouseRepair.InHouseRepair
  association [0..1] to I_TextObjectType             as _TextObjectType      on  $projection.TextObjectType     = _TextObjectType.TextObjectType
                                                                             and $projection.TextObjectCategory = _TextObjectType.TextObjectCategory

  association [0..1] to I_TextObjectCategory         as _TextObjectCategory  on  $projection.TextObjectCategory = _TextObjectCategory.TextObjectCategory

  association [0..1] to I_Language                   as _Language            on  $projection.Language = _Language.Language
{
  key  ihritemnote.InHouseRepair,
  key  ihritemnote.InHouseRepairItem,
       @ObjectModel.foreignKey.association: '_TextobjectType'
  key  ihritemnote.TextObjectType,
       @Semantics.language: true
       @ObjectModel.foreignKey.association: '_Language'
  key  ihritemnote.Language,

       ihritemnote.InHouseRepairItemUUID,

       @ObjectModel.foreignKey.association: '_Textobjectcategory'
       ihritemnote.TextObjectCategory,

       @Semantics.user.createdBy: true
       ihritemnote.CreatedByUser,

       @Semantics.text:true
       _InoteTemp.text as InhRepairNoteText,

        // used as ETag (ETag dependent setting not possible due to custom query)

       _InHouseRepairItemTP.LastChangeDateTime,

       // required for association to I_InhouseRepair. This is neccessary due to restrictions in projection view

       // when using custom query

       ihritemnote.CustMgmtObjectType,

      // Responsible Employee

      _InHouseRepair.ResponsibleEmployee                                   as RespEmployeeBusinessPartnerId,

      // Organizational Data

      @Consumption.hidden: true
      _InHouseRepair.SalesOrganization                                     as SalesOrganization,
      @Consumption.hidden: true
      _InHouseRepair.DistributionChannel                                   as DistributionChannel,
      @Consumption.hidden: true
      _InHouseRepair.Division                                              as Division,
      @Consumption.hidden: true
      _InHouseRepair.SalesOffice                                           as SalesOffice,
      @Consumption.hidden: true
      _InHouseRepair.SalesGroup                                            as SalesGroup,

      // CRM Org units

      //these fields are only ON PREMISE

      @Feature: 'BF:API_FULLSCOPE'
      @Consumption.hidden: true
      _InHouseRepair.SalesOrganizationOrgUnitID                            as SalesOrganizationOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @Consumption.hidden: true
      _InHouseRepair.SalesOfficeOrgUnitID                                  as SalesOfficeOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @Consumption.hidden: true
      _InHouseRepair.SalesGroupOrgUnitID                                   as SalesGroupOrgUnitID,

       _TextObjectType,
       _TextObjectCategory,
       _Language,
       _InHouseRepairItemTP,
       _InHouseRepair,
       _InHouseRepairTP
}
where
  ihritemnote.CustMgmtObjectType = 'BUS2000256'