R_FinTransSecurity

@AbapCatalog.sqlViewName: 'RFINTRANSSCRTY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Fin. Trans.: Securities Information'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions:false
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE
define view R_FinTransSecurity
as select from R_FinTransSecurityQuantityFlow  as MainFlow

    left outer to one join R_FinTransSecurityPaytFlow  as PaymentFlow on  MainFlow.CompanyCode                 = PaymentFlow.CompanyCode
                                                             and MainFlow.FinancialTransaction        = PaymentFlow.FinancialTransaction
                                                             and MainFlow.FinancialInstrumentActivity = PaymentFlow.FinancialInstrumentActivity

{
  MainFlow.CompanyCode,
  MainFlow.FinancialTransaction,
  MainFlow.FinancialInstrumentActivity,
  MainFlow.FinTransFlowCreationDate,
  MainFlow.FinTransFlowCreationTime,
  MainFlow.FinTransFlowNumber,
  @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'
  cast( case when ( MainFlow.FinTransTradedNomAmt is initial
        and   PaymentFlow.FinTransTradedNomAmt is not initial)
       then   PaymentFlow.FinTransTradedNomAmt
       else   MainFlow.FinTransTradedNomAmt
       end as ftr_traded_norminal_amount )                          as FinTransTradedNomAmt,
  case when ( MainFlow.FinTransFlowNomAmtCrcy is initial
        and   PaymentFlow.FinTransFlowNomAmtCrcy is not initial)
       then   PaymentFlow.FinTransFlowNomAmtCrcy
       else   MainFlow.FinTransFlowNomAmtCrcy
       end                                                          as FinTransFlowNomAmtCrcy,
  @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'    
  MainFlow.FinTransTradedOriglNomAmt,
  MainFlow.FinTransTradedNumberOfUnits,
  MainFlow.FinTransTradedPricePercent,
  MainFlow.FinTransTrdPriceCrcyUnitRate,
  MainFlow.FinTransTradedPriceCrcyUnit,
  MainFlow.MarketValueInQtanCurrency,
  MainFlow.QuotationCurrency,
  @Semantics.amount.currencyCode: 'PaymentCurrency'
  case when ( MainFlow.MarketValInPaytCurrency is initial
        and   PaymentFlow.MarketValInPaytCurrency is not initial)
       then   PaymentFlow.MarketValInPaytCurrency
       else   MainFlow.MarketValInPaytCurrency
       end                                                          as MarketValInPaytCurrency,
  case when ( MainFlow.PaymentCurrency is initial
        and   PaymentFlow.PaymentCurrency is not initial)
       then   PaymentFlow.PaymentCurrency
       else   MainFlow.PaymentCurrency
       end                                                          as PaymentCurrency,
  cast( case when ( MainFlow.FinTransPaymentCrcyCnvrsnRate is initial
        and   PaymentFlow.FinTransPaymentCrcyCnvrsnRate is not initial)
       then   PaymentFlow.FinTransPaymentCrcyCnvrsnRate
       else   MainFlow.FinTransPaymentCrcyCnvrsnRate
       end as ftr_payment_crcy_cnvrsn_rate preserving type )        as FinTransPaymentCrcyCnvrsnRate,
  @Semantics.amount.currencyCode: 'PositionCurrency'
  case when ( MainFlow.MarketValueInPositionCurrency is initial
        and   PaymentFlow.MarketValueInPositionCurrency is not initial)
       then   PaymentFlow.MarketValueInPositionCurrency
       else   MainFlow.MarketValueInPositionCurrency
       end                                                          as MarketValueInPositionCurrency, 
  case when ( MainFlow.PositionCurrency is initial
        and   PaymentFlow.PositionCurrency is not initial)
       then   PaymentFlow.PositionCurrency
       else   MainFlow.PositionCurrency
       end                                                          as PositionCurrency,
  cast( case when ( MainFlow.FinTransPositionCrcyCnvrsnRate is initial
        and   PaymentFlow.FinTransPositionCrcyCnvrsnRate is not initial)
       then   PaymentFlow.FinTransPositionCrcyCnvrsnRate
       else   MainFlow.FinTransPositionCrcyCnvrsnRate
       end as ftr_position_crcy_cnvrsn_rate preserving type )       as FinTransPositionCrcyCnvrsnRate,      
  @Semantics.amount.currencyCode: 'LocalCurrency'
  cast( case when ( MainFlow.MarketValueInLocalCurrency is initial
        and   PaymentFlow.MarketValueInLocalCurrency is not initial)
       then   PaymentFlow.MarketValueInLocalCurrency
       else   MainFlow.MarketValueInLocalCurrency
       end as market_value_in_local_currency preserving type )      as MarketValueInLocalCurrency,
  MainFlow.LocalCurrency,
  cast( case when ( MainFlow.FinTransLoclCrcyCnvrsnRate is initial
        and   PaymentFlow.FinTransLoclCrcyCnvrsnRate is not initial)
       then   PaymentFlow.FinTransLoclCrcyCnvrsnRate
       else   MainFlow.FinTransLoclCrcyCnvrsnRate
       end as ftr_cnvrsn_rate_in_locl_crcy preserving type )        as FinTransLoclCrcyCnvrsnRate,
  MainFlow.FinTransSpotPricePercent,
  MainFlow.FinTransSpotPriceCrcyUnitRate,
  MainFlow.FinTransMaturitySpotPricePct,
  MainFlow.FinTransMatSpotPrcCrcyUnitRate,
  MainFlow.FinTransForwardPriceCostRate,
  MainFlow.FinTransFwdPrcIntrstCompRate,
  MainFlow.FinTransFwdPrcDividendPercent,
  MainFlow.SecurityExchange,
  MainFlow.SecurityClass,
  MainFlow.SecurityAccount,
  MainFlow.FinTransPositionValueDate,
  MainFlow.FinTransFlowPaymentDate,
  MainFlow.CalculationDate
}