R_EBRRServiceDocumentMonitor

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'EBRR Service Document Monitor'

@VDM.viewType:#TRANSACTIONAL

@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@ObjectModel.sapObjectNodeType.name: 'ServiceContract'

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED

define root view entity R_EBRRServiceDocumentMonitor
  as select from           I_AcctgServiceDocumentItem as ServiceDocument
    inner join             I_CompanyCode              as CompanyCode      on CompanyCode.CompanyCode = ServiceDocument.CompanyCode
    inner join             tkkaa                      as tkkaa            on tkkaa.abgsl = ServiceDocument.ResultAnalysisInternalID

    left outer to one join P_EBRRSrvDocMonMaintOrd    as MaintenanceOrder on  ServiceDocument.ServiceDocument     = MaintenanceOrder.ServiceDocument
                                                                          and ServiceDocument.ServiceDocumentItem = MaintenanceOrder.ServiceDocumentItem
                                                                          and ServiceDocument.ServiceDocumentType = MaintenanceOrder.ServiceDocumentType

  association [0..*] to I_ResultAnalysisVersionText as _ResultAnalysisVersionText on $projection.ResultAnalysisInternalID = _ResultAnalysisVersionText.ResultAnalysisInternalID
  association [0..*] to I_ServiceDocumentTypeText   as _ServiceDocumentTypeText   on $projection.ServiceDocumentType = _ServiceDocumentTypeText.ServiceDocumentType
{

  key ServiceDocument.ServiceDocumentType,
  key ServiceDocument.ServiceDocument,
  key ServiceDocument.ServiceDocumentItem,
      ServiceDocument.ControllingObject,
      ServiceDocument.BusinessSolutionOrder,
      MaintenanceOrder.MaintenanceOrder,
      MaintenanceOrder.TotalNumberOfMaintOrders,
      ServiceDocument.CompanyCode                                             as CompanyCode,
      CompanyCode.CompanyCodeName                                             as CompanyCodeName,

      cast ( ServiceDocument.ResultAnalysisInternalID  as fins_trr_recgnkey ) as ResultAnalysisInternalID,

      CompanyCode.Currency                                                    as CompanyCodeCurrency,

      cast( '' as farr_cds_pob_id)                                            as PerformanceObligation,
      cast( '' as farr_cds_contract_id)                                       as RevenueAccountingContract,

      @UI.hidden: true
      cast ( '000'  as fins_fiscalperiod preserving type )                    as FiscalPeriod,
      @UI.hidden: true
      cast ( '0000' as fis_gjahr preserving type)                             as FiscalYear,
      @UI.hidden: true
      cast ( ''     as fins_ledger  )                                         as Ledger,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_recrevn )                                        as RecognizedRevnAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_reccogs )                                        as RecognizedCOGSAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_cntraccrpul )                                    as MnlContrAccrPnLItmAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_recmargin )                                      as RecognizedMarginAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_actcost )                                        as RecognizableCostAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_actrevn )                                        as RecognizableRevenueAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fis_sales_ded_hsl_a )                                     as ActlSlsDeductionAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_revnadjust )                                     as RevenueAdjustmentAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_cogsadj )                                        as COGSAdjustmentAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_defcogs )                                        as DeferredCOGSAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_defrevn )                                        as DeferredRevenueAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_acccogs )                                        as AccruedCOGSAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_accrevn )                                        as AccruedRevenueAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_unbilledrevenue )                                as UnbilledRevnInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_planrev )                                        as PlannedRevenueAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_plancos )                                        as PlannedCosAmtInCCCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast ( '0' as fins_trr_cntraccrbalsht )                                 as MnlContrAccrBalShtAmtInCCCrcy,

      cast( '' as kkatext_abgsl )                                             as TgtRsltAnalysisInternalText,
      cast( '' as fins_trr_abgsl_replace )                                    as TgtRsltAnalysisInternalID,


      _ResultAnalysisVersionText,
      _ServiceDocumentTypeText
}
where
      ServiceDocument.ResultAnalysisInternalID                    <> ' '
  and ServiceDocument._ServiceDocument.SrvcOrdIsBusinessCompleted <> 'X'