R_DebitMemoRequestTextTP

DDL: R_DEBITMEMOREQUESTTEXTTP Type: view_entity TRANSACTIONAL

Debit Memo Request - Text TP

R_DebitMemoRequestTextTP is a Transactional CDS View that provides data about "Debit Memo Request - Text TP" in SAP S/4HANA. It reads from 3 data sources (P_SalesDocumentText, I_SalesDocumentBasic, I_SalesDocumentType) and exposes 15 fields with key fields DebitMemoRequest, Language, LongTextID. It has 3 associations to related views.

3 data source(s) 15 fields

Data Sources (3)

SourceAliasJoin Type
P_SalesDocumentText P_SalesDocumentText from
I_SalesDocumentBasic SalesDocumentBasic inner
I_SalesDocumentType SalesDocumentType inner

Associations (3)

CardinalityTargetAliasCondition
[0..*] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.TextDeterminationProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID

Annotations (9)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Debit Memo Request - Text TP view
ObjectModel.dataCategory #TEXT view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY DebitMemoRequest
KEY Language DebitMemoRequestText Language
KEY LongTextID DebitMemoRequestText LongTextID
LongTextIDForEdit DebitMemoRequestText LongTextID
LanguageForEdit DebitMemoRequestText Language
LongText DebitMemoRequestText LongText
TextDeterminationProcedure I_SalesDocumentType TextDeterminationProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
DebitMemoRequestType _DebitMemoRequest DebitMemoRequestType
SalesOrganization _DebitMemoRequest SalesOrganization
DistributionChannel _DebitMemoRequest DistributionChannel
OrganizationDivision _DebitMemoRequest OrganizationDivision
_DebitMemoRequest _DebitMemoRequest
_Language _Language
_LongTextID _LongTextID 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['DebitMemoRequest', 'Language', 'LongTextID'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Debit Memo Request - Text TP'
@ObjectModel.dataCategory: #TEXT

define view entity R_DebitMemoRequestTextTP
  as select from P_SalesDocumentText( P_SAPClient : $session.client ) as DebitMemoRequestText

    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic on  SalesDocumentBasic.SalesDocument      = DebitMemoRequestText.SalesDocument
                                                                                            and SalesDocumentBasic.SDDocumentCategory = 'L'

    inner join   I_SalesDocumentType                                  as SalesDocumentType  on SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType


  association        to parent R_DebitMemoRequestTP  as _DebitMemoRequest           on  $projection.DebitMemoRequest = _DebitMemoRequest.DebitMemoRequest

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID        as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(DebitMemoRequestText.SalesDocument as debit_memo_request preserving type) as DebitMemoRequest,
      @Semantics.language: true
  key DebitMemoRequestText.Language,

  key DebitMemoRequestText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      @ObjectModel.editableFieldFor: '_LongTextID'
      DebitMemoRequestText.LongTextID                                                 as LongTextIDForEdit,
      @ObjectModel.editableFieldFor: '_Language'
      @ObjectModel.foreignKey.association: '_Language'
      DebitMemoRequestText.Language                                                   as LanguageForEdit,
      @Semantics.text: true
      DebitMemoRequestText.LongText,

      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                      as TextDeterminationProcedureItem,

      // For Access control

      @Consumption.hidden: true
      _DebitMemoRequest.DebitMemoRequestType,
      @Consumption.hidden: true
      _DebitMemoRequest.SalesOrganization,
      @Consumption.hidden: true
      _DebitMemoRequest.DistributionChannel,
      @Consumption.hidden: true
      _DebitMemoRequest.OrganizationDivision,


      // Exposed associations

      _DebitMemoRequest,
      _Language,
      _LongTextID
}

Learn More