R_CustomerReturnTextTP

DDL: R_CUSTOMERRETURNTEXTTP Type: view_entity TRANSACTIONAL

Returns Order - Text TP

R_CustomerReturnTextTP is a Transactional CDS View that provides data about "Returns Order - Text TP" in SAP S/4HANA. It reads from 3 data sources (P_SalesDocumentText, I_SalesDocumentBasic, I_SalesDocumentType) and exposes 15 fields with key fields CustomerReturn, Language, LongTextID. It has 3 associations to related views.

3 data source(s) 15 fields

Data Sources (3)

SourceAliasJoin Type
P_SalesDocumentText P_SalesDocumentText from
I_SalesDocumentBasic SalesDocumentBasic inner
I_SalesDocumentType SalesDocumentType inner

Associations (3)

CardinalityTargetAliasCondition
[0..*] I_TextDeterminationProcedItem _TextDeterminationProcedItem $projection.TextDeterminationProcedure = _TextDeterminationProcedItem.TextDeterminationProcedure and $projection.LongTextID = _TextDeterminationProcedItem.LongTextID and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'
[0..1] I_Language _Language $projection.LanguageForEdit = _Language.Language
[0..1] I_SDDocumentLongTextID _LongTextID $projection.LongTextIDForEdit = _LongTextID.LongTextID

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Returns Order - Text TP view

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY CustomerReturn
KEY Language CustomerReturnText Language
KEY LongTextID CustomerReturnText LongTextID
LongTextIDForEdit CustomerReturnText LongTextID
LanguageForEdit CustomerReturnText Language
LongText CustomerReturnText LongText
TextDeterminationProcedure I_SalesDocumentType TextDeterminationProcedure
TextDeterminationProcedureItem _TextDeterminationProcedItem TextDeterminationProcedureItem
CustomerReturnType _CustomerReturn CustomerReturnType
SalesOrganization _CustomerReturn SalesOrganization
DistributionChannel _CustomerReturn DistributionChannel
OrganizationDivision _CustomerReturn OrganizationDivision
_CustomerReturn _CustomerReturn
_Language _Language
_LongTextID _LongTextID 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['CustomerReturn', 'Language', 'LongTextID'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Returns Order - Text TP'

define view entity R_CustomerReturnTextTP
  as select from P_SalesDocumentText( P_SAPClient : $session.client ) as CustomerReturnText
    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic                 on  SalesDocumentBasic.SalesDocument      = CustomerReturnText.SalesDocument
                                                                                                            and SalesDocumentBasic.SDDocumentCategory = 'H'
    inner join   I_SalesDocumentType                                  as SalesDocumentType                  on  SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType

  association        to parent R_CustomerReturnTP                     as _CustomerReturn                    on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn

  association [0..*] to I_TextDeterminationProcedItem                 as _TextDeterminationProcedItem       on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                                            and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                                            and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'
  association [0..1] to I_Language                                    as _Language                          on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID                        as _LongTextID                        on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(CustomerReturnText.SalesDocument as vdm_customer_return preserving type) as CustomerReturn,

  key CustomerReturnText.Language,

  key CustomerReturnText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      CustomerReturnText.LongTextID                                                 as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      CustomerReturnText.Language                                                   as LanguageForEdit,

      CustomerReturnText.LongText,

      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                   as TextDeterminationProcedureItem,

      // For Access Control

      @Consumption.hidden: true
      _CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      _CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      _CustomerReturn.DistributionChannel,
      @Consumption.hidden: true
      _CustomerReturn.OrganizationDivision,

      // Associations

      _CustomerReturn,
      _Language,
      _LongTextID
}

Learn More