R_CustomerReturnPartnerTP

DDL: R_CUSTOMERRETURNPARTNERTP Type: view_entity TRANSACTIONAL

Returns Order Partner - TP

R_CustomerReturnPartnerTP is a Transactional CDS View that provides data about "Returns Order Partner - TP" in SAP S/4HANA. It reads from 1 data source (I_CustomerReturnPartner) and exposes 55 fields with key fields CustomerReturn, PartnerFunction. It has 4 associations to related views.

1 data source(s) 55 fields

Data Sources (1)

SourceAliasJoin Type
I_CustomerReturnPartner CustomerReturnPartner from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_PartnerFunction _PartnerFunction $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
[0..1] I_Language _CorrespondenceLanguage $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
[0..1] I_FormOfAddress _FormOfAddress $projection.FormOfAddress = _FormOfAddress.FormOfAddress
[0..1] I_TransportationZone _TransportationZone $projection.transportzone = _TransportationZone.TransportZone and $projection.country = _TransportationZone.CountryCode

Annotations (8)

NameValueLevelField
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view
EndUserText.label Returns Order Partner - TP view

Fields (55)

KeyFieldSource TableSource FieldDescription
KEY CustomerReturn I_CustomerReturnPartner CustomerReturn
KEY PartnerFunction
PartnerFunctionForEdit
Customer I_CustomerReturnPartner Customer
Supplier I_CustomerReturnPartner Supplier
Personnel I_CustomerReturnPartner Personnel
ContactPerson I_CustomerReturnPartner ContactPerson
ReferenceBusinessPartner I_CustomerReturnPartner ReferenceBusinessPartner
Partner I_CustomerReturnPartner Partner
FullName I_CustomerReturnPartner FullName
SDDocumentPartnerType _PartnerFunction SDDocumentPartnerType
FormOfAddress I_CustomerReturnPartner FormOfAddress
PostalCode
CityName
DistrictName
Country
Region
StreetName
StreetPrefixName1
StreetPrefixName2
StreetSuffixName1
StreetSuffixName2
HouseNumber
InternationalPhoneNumber I_CustomerReturnPartner InternationalPhoneNumber
InternationalMobilePhoneNumber I_CustomerReturnPartner InternationalMobilePhoneNumber
InternationalFaxNumber I_CustomerReturnPartner InternationalFaxNumber
EmailAddress I_CustomerReturnPartner EmailAddress
POBox
POBoxPostalCode
CorrespondenceLanguage I_CustomerReturnPartner CorrespondenceLanguage
TaxJurisdiction
TransportZone
UnloadingPointName I_CustomerReturnPartner UnloadingPointName
VATRegistration I_CustomerReturnPartner VATRegistration
AddressID I_CustomerReturnPartner AddressID
AddressPersonID I_CustomerReturnPartner AddressPersonID
AddressObjectType I_CustomerReturnPartner AddressObjectType
SDDocPartnerAddressRefType I_CustomerReturnPartner SDDocPartnerAddressRefType
BPAddrDeterminationTransaction I_CustomerReturnPartner BPAddrDeterminationTransaction
BPRefAddressIDForDocSpcfcAddr I_CustomerReturnPartner BPRefAddressIDForDocSpcfcAddr
SDDocPartnerAddrIsDocSpecific I_CustomerReturnPartner SDDocPartnerAddrIsDocSpecific
CustomerReturnType _CustomerReturn CustomerReturnType
SalesOrganization _CustomerReturn SalesOrganization
DistributionChannel _CustomerReturn DistributionChannel
OrganizationDivision _CustomerReturn OrganizationDivision
_CustomerReturn _CustomerReturn
_PartnerFunction _PartnerFunction
_CorrespondenceLanguage _CorrespondenceLanguage
_FormOfAddress _FormOfAddress
_TransportationZone _TransportationZone
_DfltAddrRprstn I_CustomerReturnPartner _DfltAddrRprstn
_BusinessPartnerAddress I_CustomerReturnPartner _BusinessPartnerAddress
_BPRefAddressForDocSpcfcAddr I_CustomerReturnPartner _BPRefAddressForDocSpcfcAddr
_Country
_Region 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_DfltAddrRprstn' ]
}
@ObjectModel: {
   semanticKey: ['CustomerReturn', 'PartnerFunction'],
   usageType: {
     dataClass: #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory: #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Returns Order Partner - TP'

define view entity R_CustomerReturnPartnerTP
  as select from I_CustomerReturnPartner        as CustomerReturnPartner

  association to parent R_CustomerReturnTP      as _CustomerReturn          on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn

  association [0..1] to I_PartnerFunction       as _PartnerFunction         on  $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction

  association [0..1] to I_Language              as _CorrespondenceLanguage  on $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
   
  association [0..1] to I_FormOfAddress         as _FormOfAddress           on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress

  association [0..1] to I_TransportationZone    as _TransportationZone      on  $projection.transportzone = _TransportationZone.TransportZone
                                                                            and $projection.country       = _TransportationZone.CountryCode                                                                           
{
  key CustomerReturnPartner.CustomerReturn,

  key cast(CustomerReturnPartner.PartnerFunction as parvw_unv preserving type)  as PartnerFunction,

      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(CustomerReturnPartner.PartnerFunction as parvw_unv preserving type ) as PartnerFunctionForEdit,
      @Consumption.hidden: true
      CustomerReturnPartner.Customer,

      @Consumption.hidden: true
      CustomerReturnPartner.Supplier,

      @Consumption.hidden: true
      CustomerReturnPartner.Personnel,

      @Consumption.hidden: true
      CustomerReturnPartner.ContactPerson,

      CustomerReturnPartner.ReferenceBusinessPartner,
      
      @ObjectModel.text.element: ['FullName']
      CustomerReturnPartner.Partner,
      
      @Semantics.name.fullName: true
      @Semantics.text: true
      CustomerReturnPartner.FullName,
      
      _PartnerFunction.SDDocumentPartnerType, 
      
      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      CustomerReturnPartner.FormOfAddress,     

      @Semantics.address.zipCode:true
      CustomerReturnPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.city:true
      CustomerReturnPartner._OrgNamePostalAddress.CityName,

      CustomerReturnPartner._OrgNamePostalAddress.DistrictName,    
       
      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      CustomerReturnPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      CustomerReturnPartner._OrgNamePostalAddress.Region,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetPrefixName1,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetPrefixName2,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetSuffixName1,

      @Semantics.address.street: true
      CustomerReturnPartner._OrgNamePostalAddress.StreetSuffixName2,

      @Semantics.address.streetNoNumber: true
      CustomerReturnPartner._OrgNamePostalAddress.HouseNumber,

      @Semantics.telephone.type: [#WORK]
      CustomerReturnPartner.InternationalPhoneNumber,

      @Semantics.telephone.type:  [#CELL]
      CustomerReturnPartner.InternationalMobilePhoneNumber,

      @Semantics.telephone.type: [#FAX]
      CustomerReturnPartner.InternationalFaxNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      CustomerReturnPartner.EmailAddress,

      @Semantics.address.postBox: true
      CustomerReturnPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      CustomerReturnPartner._OrgNamePostalAddress.POBoxPostalCode,

      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      CustomerReturnPartner.CorrespondenceLanguage,

      CustomerReturnPartner._OrgNamePostalAddress.TaxJurisdiction,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      CustomerReturnPartner._OrgNamePostalAddress.TransportZone,

      @Semantics.text: true
      CustomerReturnPartner.UnloadingPointName,

      CustomerReturnPartner.VATRegistration,
      
      @Consumption.hidden: true
      CustomerReturnPartner.AddressID,
      @Consumption.hidden: true
      CustomerReturnPartner.AddressPersonID,
      @Consumption.hidden: true
      CustomerReturnPartner.AddressObjectType,
      @Consumption.hidden: true
      CustomerReturnPartner.SDDocPartnerAddressRefType,
      @Consumption.hidden: true
      CustomerReturnPartner.BPAddrDeterminationTransaction,
      @Consumption.hidden: true
      CustomerReturnPartner.BPRefAddressIDForDocSpcfcAddr,
      @Consumption.hidden: true
      CustomerReturnPartner.SDDocPartnerAddrIsDocSpecific,

      //DCL      

      @Consumption.hidden: true
      _CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      _CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      _CustomerReturn.DistributionChannel,
      @Consumption.hidden: true
      _CustomerReturn.OrganizationDivision,

      //Associations

      _CustomerReturn,
      _PartnerFunction,
      _CorrespondenceLanguage,
      _FormOfAddress,
      _TransportationZone,
      
      CustomerReturnPartner._DfltAddrRprstn,
      CustomerReturnPartner._BusinessPartnerAddress, 
      CustomerReturnPartner._BPRefAddressForDocSpcfcAddr,      
      CustomerReturnPartner._OrgNamePostalAddress._Country,
      CustomerReturnPartner._OrgNamePostalAddress._Region
}

Learn More