R_CustomerReturnItemTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
  semanticKey: ['CustomerReturn', 'CustomerReturnItem', 'Language', 'LongTextID'],
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Returns Order Item - Text TP'

define view entity R_CustomerReturnItemTextTP
  as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as CustomerReturnItemText
    inner join   I_SalesDocumentItemBasic                                 as SalesDocumentItemBasic    on  SalesDocumentItemBasic.SalesDocument      = CustomerReturnItemText.SalesDocument
                                                                                                       and SalesDocumentItemBasic.SalesDocumentItem  = CustomerReturnItemText.SalesDocumentItem
                                                                                                       and SalesDocumentItemBasic.SDDocumentCategory = 'H'
    inner join   I_SalesDocumentItemCategory                              as SalesDocumentItemCategory on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory


  association to parent R_CustomerReturnItemTP        as _Item                        on  $projection.CustomerReturn     = _Item.CustomerReturn
                                                                                      and $projection.CustomerReturnItem = _Item.CustomerReturnItem
                                                                                      
  association [1..1] to R_CustomerReturnTP            as _CustomerReturn              on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn
  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID
  
  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

{
  key cast(CustomerReturnItemText.SalesDocument as vdm_customer_return preserving type)          as CustomerReturn,

  key cast(CustomerReturnItemText.SalesDocumentItem as vdm_customer_return_item preserving type) as CustomerReturnItem,

  key CustomerReturnItemText.Language,

  key CustomerReturnItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      CustomerReturnItemText.LongTextID                                                          as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      CustomerReturnItemText.Language                                                            as LanguageForEdit,

      CustomerReturnItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                                as TextDeterminationProcedureItem,

      //For Access Control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                                   as CustomerReturnType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //Associations

      _Item,
      _CustomerReturn,
      _Language,
      _LongTextID
}