R_CFinRpldPurchasingDocItemTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'CFin Replicated Purchasing Document Item'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
define view entity R_CFinRpldPurchasingDocItemTP
  as select from I_CFinRpldPurchasingDocItem

  association        to parent R_CFinRpldPurchasingDocumentTP as _CFinRpldPurchasingDocumentTP on  $projection.CFinRpldPurchasingDocument = _CFinRpldPurchasingDocumentTP.CFinRpldPurchasingDocument
                                                                                               and $projection.SourceSystemLogicalSystem  = _CFinRpldPurchasingDocumentTP.SourceSystemLogicalSystem

  composition [0..*] of R_CFinRpldPurgDocAcctAssgmtTP         as _CFinRpldPurgDocAcctAssgmtTP

  composition [0..*] of R_CFinRpldPurgDocSchedLineTP          as _CFinRpldPurgDocSchedLineTP

  composition [0..*] of R_CFinRpldPurgReltdMatlDocTP          as _CFinRpldPurgReltdMatlDocTP

  composition [0..*] of R_CFinRpldPurgDocReltdInvcTP          as _CFinRpldPurgDocReltdInvcTP
  association [1..1] to E_CFinRpldPurchasingDocItem           as _Extension                    on  $projection.CFinRpldPurchasingDocument     = _Extension.CFinRpldPurchasingDocument
                                                                                               and $projection.SourceSystemLogicalSystem      = _Extension.SourceSystemLogicalSystem
                                                                                               and $projection.CFinRpldPurchasingDocumentItem = _Extension.CFinRpldPurchasingDocumentItem

{
  key SenderLogicalSystem                                    as SourceSystemLogicalSystem,
  key CFinRpldPurchasingDocument,
  key CFinRpldPurchasingDocumentItem,
      PurchasingDocumentDeletionCode,
      LastChangedDate,
      PurchasingDocumentItemText,
      Material,
      CompanyCode,
      Plant,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      TargetQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      OrderQuantity,
      OrderQuantityUnit,
      OrderPriceUnit,
      OrderPriceUnitToOrderUnitNmrtr,
      OrdPriceUnitToOrderUnitDnmntr,
      OrderItemQtyToBaseQtyNmrtr,
      OrderItemQtyToBaseQtyDnmntr,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetPriceAmount,
      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      NetPriceQuantity,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetAmount,
      TaxCode,
      ValuationType,
      IsCompletelyDelivered,
      IsFinallyInvoiced,
      PurchasingDocumentItemCategory,
      AccountAssignmentCategory,
      ConsumptionPosting,
      MultipleAcctAssgmtDistribution,
      PartialInvoiceDistribution,
      GoodsReceiptIsExpected,
      GoodsReceiptIsNonValuated,
      InvoiceIsExpected,
      InvoiceIsGoodsReceiptBased,
      BaseUnit,
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NonDeductibleInputTaxAmount,
      TaxJurisdiction,
      IsStatisticalItem,
      EvaldRcptSettlmtIsAllowed,
      IsReturnsItem,
      InvoiceIsMMServiceEntryBased,
      FunctionalArea,
      ProductType                                            as ProductTypeCode,
      RequisitionerName,
      DocumentCurrency,

      cast( '00000000000000' as fins_cfin_av_lastchangedon ) as LastChangeDateTime,

      /* Associations */
      _CFinRpldPurchasingDocumentTP,
      _CFinRpldPurgDocAcctAssgmtTP,
      _CFinRpldPurgDocSchedLineTP,
      _CFinRpldPurgReltdMatlDocTP,
      _CFinRpldPurgDocReltdInvcTP
}