R_CFinAAPurchasingValidItemTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'CFinAA Purchasing Valid Item -TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM: { usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ],
        viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ObjectModel.sapObjectNodeType.name: 'CFinAAPurchasingItem'
define root view entity R_CFinAAPurchasingValidItemTP
  as select from I_CFinAAPurchasingValidItem
  composition [0..1] of R_CFinAAPurgManagedAssetTP  as _Asset
  association [1..1] to I_CFinRpldPurchasingDocItem as _PurchasingDocItem on  $projection.SenderLogicalSystem            = _PurchasingDocItem.SenderLogicalSystem
                                                                          and $projection.CFinRpldPurchasingDocument     = _PurchasingDocItem.CFinRpldPurchasingDocument
                                                                          and $projection.CFinRpldPurchasingDocumentItem = _PurchasingDocItem.CFinRpldPurchasingDocumentItem
  association [0..1] to I_CompanyCode               as _CompanyCode       on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ProductGroupText_2        as _MaterialGroupText on  $projection.MaterialGroup   = _MaterialGroupText.ProductGroup
                                                                          and _MaterialGroupText.Language = $session.system_language
  association [0..1] to I_AccAssgnmtCategory        as _AccAssgmtCategory on  $projection.AccountAssignmentCategory = _AccAssgmtCategory.AccountAssignmentCategory
  association [0..1] to I_LogicalSystem             as _LogicalSystem     on  $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem
{
  key CFinAAPurchasingValidItemUUID,
      CFinAAManagedAssetUUID,
      SenderLogicalSystem,
      CFinRpldPurchasingDocument,
      CFinRpldPurchasingDocumentItem,
      cast(concat(concat( ltrim(CFinRpldPurchasingDocument, '0') , '-'), ltrim(CFinRpldPurchasingDocumentItem, '0' ))
        as fins_cfin_caa_pur_itm_number preserving type ) as CFinAAPurchasingLineItem,
      CompanyCode,
      MaterialGroup,
      AccountAssignmentCategory,
      CFinAAPurchasingItemStatus,
      CFinAAAssetCompanyCode,
      MasterFixedAsset,
      FixedAsset,
      FixedAssetExternalID,
      AssetClass,
      FixedAssetDescription,
      CFinAAManagedAssetCreationType,
      CFinAAPurgConfignIsConsistent,
      case CFinAAPurgConfignIsConsistent when ' ' then 1
      else 3
      end                                                 as CFinAAPurgConfignCriticality,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangedAtDateTime,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LocalLastChangedAtDateTime,
      _Asset,
      _PurchasingDocItem,
      _PurchasingActivation,
      _CompanyCode,
      _MaterialGroupText,
      _AccAssgmtCategory,
      _LogicalSystem
}