R_CADisputeCaseTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Dispute case'
@AccessControl.personalData.blocking: #REQUIRED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'ContrAcctgDisputeCase' 
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
define root view entity R_CADisputeCaseTP as select from I_CADisputeCase
  composition [1..*] of R_CADisputeCaseObjectTP as _CACaseObject
  composition [0..*] of R_CADisputedDocumentTP as _DisputedDocument
  composition [0..*] of R_CADisputedPaymentTP as _DisputedPayment
  composition [0..*] of R_CADisputeCaseFllwUpDocTP as _DisputedFollowUp
  composition [0..*] of R_CADisputedCreditTP as _DisputeCredit
  composition [0..*] of R_CADisputedInvcgDocTP as _DisputedInvoicing
  composition [0..*] of R_CADisputedInvcgDocItemTP  as _DisputedInvoicingItem  
  composition [0..*] of R_CADisputedBllbleItmTP  as _DisputedBit
  // Extension Include View 

  association [1] to E_CADisputeCase as _Extension on $projection.CaseUUID = _Extension.CaseUUID
{
  key CaseUUID,
      @ObjectModel.text.element: ['BusinessPartnerFullName']  
      BusinessPartner,
      BusinessPartnerFullName,
      @ObjectModel.text.element: ['ContractAccountName']
      ContractAccount,
      ContractAccountName,
      CAContract,
      CAApplicationArea, 
      CASubApplication,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      TotalReceivablesAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputeCaseCorrectionAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputeCaseReversedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      CreditedAmount, 
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      WriteOffAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      DisputeCaseReplacedAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      PaidAmount,
      @Semantics.amount.currencyCode: 'DisputeCaseCurrency'
      CARemainingDisputedAmount, 
      DisputeCaseCurrency,
      LogicalSystem,
      @ObjectModel.text.element: ['CADisputeTypeText']
      CADisputeType,
      CADisputeTypeText,
      @ObjectModel.text.element: ['CompanyCodeName'] 
      CompanyCode,
      CompanyCodeName,
      DisputeCaseCoordinator,
      @ObjectModel.text.element: ['CaseRootCauseDescription'] 
      DisputeCaseRootCause,
      CaseRootCauseDescription,      
      CaseProcessingDeadlineDate,  
      ContactPersonFullName,
      ContactPersonEmailAddress,
      ContactPersonPhoneNumber,
      ContactPersonFaxNumber,
      ContactPersonFaxCountry, 
      DisputeCaseBPCorrespondenceKey,
      DisputeCaseInformationText,
      DisputeCaseTransactionDate,
      CADisputeCase,
      CaseType,
      CaseID,
      CaseExternalReference,
      CaseCreatedBy,
      CaseCreationDate,
      CaseLastChangedBy,
      CaseLastChangedOn,
      CaseStatusProfile,
      CaseClosedBy,
      CaseClosedTime,
      CasePlannedCloseDate,
      CaseProcessor,
      CaseResponsible,
      CaseTitle,
      CaseAuthorizationLevel,
      @ObjectModel.text.element: ['CaseStatusName']
      CaseStatus,
      CaseStatusName,
      @ObjectModel.text.element: ['CaseUserStatusName']
      CaseSystemStatus,
      CaseUserStatusName,
      @ObjectModel.text.element: ['DisputeCasePriorityName']
      CasePriority,
      DisputeCasePriorityName, 
      @ObjectModel.text.element: ['DisputeCaseCategoryName']
      CaseCategory,
      DisputeCaseCategoryName,  
      @ObjectModel.text.element: ['CaseReasonName']
      CaseReason,
      CaseReasonName,     
      @ObjectModel.text.element: ['DsputCaseEscalationRsnName']
      CaseEscalationReason,
      DsputCaseEscalationRsnName,
      CaseIsDisplayOnly,
      StreetName,
      HouseNumber,  
      CountryName,
      PostalCode, 
      CityName,
      cast('' as calld_kk )  as CADisputeExternalCallerCode,
      DisputeCaseOrigin,
      cast('' as opbel_gfn_kk) as CADocumentNumber,
      cast( concat('AAAAAAAAAAAAAAAAAAAA', CaseID) as sysuuid_c) as TemporaryDisputeCaseUUID,
      cast(concat_with_space( StreetName, HouseNumber, 1) as secdep_house_number_kk ) as AddressLine1,
      cast(concat_with_space( PostalCode, CityName, 1) as secdep_home_town_kk)   as AddressLine2,
      ''                     as UserDefinedText,
      
      //@ObjectModel.virtualElement

      //@ObjectModel.filter.transformedBy: 'ABAP:CL_FKK_CADSPUTCASE_CADOC_VH'

      //cast( 'XXXXXXXXXXXX' as opbel_gfn_kk preserving type ) as CADocument,


      CACaseConversionStatus,
      CaseAttributeProfile,
      @ObjectModel.text.element: ['CADisputeCaseOriginText']
      CADisputeCaseOrigin,
      CADisputeCaseOriginText,
      case
        when ( ContractAccount = '' )
          then ''
          else _ContractAccount.CAAuthorizationGroup
          end as CAAuthorizationGroup,
      _CACaseObject,
      _DisputedDocument,
      _DisputedPayment,
      _DisputedFollowUp,
      _DisputeCredit,
      _DisputedInvoicing,
      _DisputedInvoicingItem,
      _DisputedBit,
      _BusinessPartner,
      _ContractAccount,
      _CaseProcessor,
      _CaseResponsible,
      _DisputeCaseCoordinator,
      _CaseCreatedBy,
      _CaseLastChangedBy,
      _CaseClosedBy
}