R_BatchTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Batch'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.sapObjectNodeType.name: 'Batch' 
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_BatchTP
  as select from I_BatchDistinct
  composition [0..*] of R_BatchPlantTP as _BatchPlantTP
  composition [0..1] of R_BatchClassTP as _BatchClassTP
  composition [0..*] of R_BatchCharacteristicTP as _BatchCharacteristicTP
  composition [0..*] of R_BatchTextTP as _BatchTextTP
{
  key Material,
  key Plant as BatchIdentifyingPlant,
  key Batch,
      BatchIsMarkedForDeletion,
      MatlBatchIsInRstrcdUseStock,
      Supplier,
      BatchBySupplier,
      CountryOfOrigin,
      RegionOfOrigin,
      MatlBatchAvailabilityDate,
      ShelfLifeExpirationDate,
      ManufactureDate,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedDate3,
      FreeDefinedDate4,
      FreeDefinedDate5,
      FreeDefinedDate6,
      CreationDateTime,
      case when LastChangeDateTime = 0 or LastChangeDateTime is null
        then cast('20170331120000' as lobm_last_changed)
        else LastChangeDateTime
      end as LastChangeDateTime,
      BatchExtWhseMgmtInternalId,
      NextInspectionDate,
      LastGoodsReceiptDate,
      ExportAndImportProductGroup,
      BatchCertificationDate,
      BatchVersion,
    
  /* Compositions */  
      _BatchPlantTP,
      _BatchClassTP,
      _BatchCharacteristicTP,
      _BatchTextTP,

  /* Associations */  
      _Product
}