R_BasicConditionContract

@EndUserText.label: 'Basic Condition Contract'
@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #('TRANSACTIONAL_DATA'),
    privilegedAssociations: [  '_LastChangedByUser', '_CreatedByUser'  ]
    }
@ObjectModel: {
    representativeKey:        'BasicConditionContract',
    usageType.serviceQuality: #B,
    usageType.dataClass:      #TRANSACTIONAL,
    usageType.sizeCategory:   #XXL
    }
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #SAP_INTERNAL_API
    }
@Metadata: {
    ignorePropagatedAnnotations: true,
    allowExtensions: false
    }

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity R_BasicConditionContract
  as select from R_ConditionDocument

  association [0..*] to R_BscCndnContrRefcdCndnContr as _BscCndnContrRefcdCndnContr    on $projection.BasicConditionContract = _BscCndnContrRefcdCndnContr.BasicConditionContract

  association [0..1] to I_CndnContrActvtnStatus      as _BscCndnContrActivationStatus  on $projection.BscCndnContrActivationStatus = _BscCndnContrActivationStatus.CndnContrActvtnStatus
  association [0..1] to I_Currency                   as _BscConditionContractCurrency  on $projection.BscConditionContractCurrency = _BscConditionContractCurrency.Currency
  association [0..1] to I_CndnContrSuplrSettlmtCat   as _BscCndnContrSuplrSettlmtCat   on $projection.BscCndnContrSuplrSettlmtCat = _BscCndnContrSuplrSettlmtCat.CndnContrSuplrSettlmtCat
  association [0..1] to I_CndnContrCustSettlmtCat    as _BscCndnContrCustSettlmtCat    on $projection.BscCndnContrCustSettlmtCat = _BscCndnContrCustSettlmtCat.CndnContrCustSettlmtCat

  association [0..1] to I_CndnContrPurposeCat        as _BscCndnContrPurposeCategory   on $projection.BscCndnContrPurposeCategory = _BscCndnContrPurposeCategory.CndnContrPurposeCat
  association [0..1] to I_CndnContrSourceDocCat      as _BscCndnContrSrceDocCategory   on $projection.BscCndnContrSrceDocCategory = _BscCndnContrSrceDocCategory.CndnContrSourceDocCat

  association [0..1] to I_UnitOfMeasure              as _BasicConditionContractUnit    on $projection.BasicConditionContractUnit = _BasicConditionContractUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _BscCndnContrWeightUnit        on $projection.BscCndnContrWeightUnit = _BscCndnContrWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _BscCndnContrVolumeUnit        on $projection.BscCndnContrVolumeUnit = _BscCndnContrVolumeUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _BscCndnContrPtsQuantityUnit   on $projection.BscCndnContrPtsQuantityUnit = _BscCndnContrPtsQuantityUnit.UnitOfMeasure

  association [0..1] to I_CndnContrPrcgDetnRlvnceCat as _BscCndnContrPrcgDetnRlvnceCat on $projection.BscCndnContrPrcgDetnRlvnceCat = _BscCndnContrPrcgDetnRlvnceCat.CndnContrPrcgDetnRlvnceCat

{

  key cast( ConditionDocument as wcb_num_basic_contract preserving type )                 as BasicConditionContract,
      @ObjectModel.foreignKey.association: '_CndnContrType'
      CndnContrType,
      @ObjectModel.foreignKey.association: '_CndnContrClassfctnType'
      CndnContrClassfctnType,
      @ObjectModel.foreignKey.association: '_CndnContrProcVar'
      @Consumption: {
      valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcVarStdVH', element: 'CndnContrProcVar' } }]
      }
      CndnContrProcVar,
      DocumentReferenceID,
      CndnDocAssignmentReference                                                          as BscCndnContrAssgmtReference,
      ExternalDocumentReferenceID,
      CndnDocExternalPartner                                                              as BscCndnContrExternalPartner,
      @ObjectModel.foreignKey.association: '_BscCndnContrActivationStatus'
      CndnDocActivationStatus                                                             as BscCndnContrActivationStatus,

      /* Validity */
      @Semantics.businessDate.from: true
      ConditionDocumentValidFromDate                                                      as BscCndnContrValidFromDate,
      @Semantics.businessDate.to: true
      ConditionDocumentValidToDate                                                        as BscCndnContrValidToDate,

      /* Partners */
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
      }
      Customer,
      @ObjectModel.foreignKey.association: '_PriorSupplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      PriorSupplier,

      /* Organizational Data */
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
      }
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_Salesgroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,

      /* Administrative Data */
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      CreationTime,
      CreationTimeZone,
      @Semantics.systemDateTime.createdAt: true
      CreationUTCDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangedDate,
      LastChangeTime,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeUTCDateTime,

      /* Currency and Exchange Rate */
      @ObjectModel.foreignKey.association: '_BscConditionContractCurrency'
      cast( ConditionDocumentCurrency as wcb_bsc_cndn_contr_curr preserving type )        as BscConditionContractCurrency,
      ExchangeRate,
      @ObjectModel.foreignKey.association: '_ExchangeRateType'
      ExchangeRateType,
      ExchangeRateDate,

      /* Payment terms and method */
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount1Percent,
      CashDiscount2Days,
      CashDiscount2Percent,
      NetPaymentDays,
      PaymentMethod,

      @ObjectModel.foreignKey.association: '_BscCndnContrSuplrSettlmtCat'
      CndnDocSuplrSettlmtCat                                                              as BscCndnContrSuplrSettlmtCat,
      @ObjectModel.foreignKey.association: '_BscCndnContrCustSettlmtCat'
      CndnDocCustSettlmtCat                                                               as BscCndnContrCustSettlmtCat,
      @ObjectModel.foreignKey.association: '_SettlmtProduct'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductVH', element: 'Product' } }]
      }
      SettlmtProduct,

      /* Calendars */
      @ObjectModel.foreignKey.association: '_FinalSettlmtCalendar'
      FinalSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_PartialSettlmtCalendar'
      PartialSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaSettlmtCalendar'
      DeltaSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaAccrualSettlmtCalendar'
      DeltaAccrualSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_AccrualClearingSettlmtCal'
      AccrualClearingSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_CndnContrExtensionCalendar'
      CndnContrExtensionCalendar,

      PrecedingConditionDocument,
      @ObjectModel.foreignKey.association: '_BscCndnContrPurposeCategory'
      CndnDocPurposeCategory                                                              as BscCndnContrPurposeCategory,

      /* Source Document */
      @ObjectModel.foreignKey.association: '_BscCndnContrSrceDocCategory'
      CndnDocSourceDocumentCategory                                                       as BscCndnContrSrceDocCategory,
      CndnDocSourceDocument                                                               as BscCndnContrSourceDocument,
      CndnDocSourceDocumentItem                                                           as BscCndnContrSourceDocumentItem,

      @ObjectModel.foreignKey.association: '_BusVolTableGroup'
      BusVolTableGroup,
      @ObjectModel.foreignKey.association: '_AmountFieldGroup'
      AmountFieldGroup,

      /* Units */
      @ObjectModel.foreignKey.association: '_BasicConditionContractUnit'
      ConditionDocumentUnit                                                               as BasicConditionContractUnit,
      @ObjectModel.foreignKey.association: '_BscCndnContrWeightUnit'
      ConditionDocumentWeightUnit                                                         as BscCndnContrWeightUnit,
      @ObjectModel.foreignKey.association: '_BscCndnContrVolumeUnit'
      ConditionDocumentVolumeUnit                                                         as BscCndnContrVolumeUnit,
      @ObjectModel.foreignKey.association: '_BscCndnContrPtsQuantityUnit'
      CndnDocPointsQuantityUnit                                                           as BscCndnContrPtsQuantityUnit,

      AccrualUpdateIsRequired,

      /* UUIDs */
      cast( ConditionDocumentUUID as wcb_bsc_cndn_contr_uuid preserving type )            as BasicConditionContractUUID,
      cast( ConditionDocumentSourceUUID as wcb_bsc_cndn_contr_srce_uuid preserving type ) as BscCndnContrSourceUUID,

      /* Tax */
      @ObjectModel.foreignKey.association: '_TaxCountry'
      TaxCountry,
      @ObjectModel.foreignKey.association: '_SettlmtPartTxRegnCntry'
      SettlmtPartTxRegnCntry,

      /* VAT Registration */
      SettlmtPartTxRegnNmbr,

      @ObjectModel.foreignKey.association: '_BscCndnContrPrcgDetnRlvnceCat'
      CndnDocPrcgDetnRlvnceCat                                                            as BscCndnContrPrcgDetnRlvnceCat,
      @ObjectModel.foreignKey.association: '_BusVolTotAmtSpltCritraGrp'
      BusVolTotAmtSpltCritraGrp,

      @ObjectModel.foreignKey.association: '_CndnContrPartnerCat'
      CndnContrPartnerCat,
      @ObjectModel.foreignKey.association: '_CndnContrProcessCategory'
      CndnContrProcessCategory,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtType'
      CndnContrSettlmtType,


      /* Associations */
      _BscCndnContrRefcdCndnContr,
      _CndnContrType,
      _CndnContrClassfctnType,
      _CndnContrProcVar,
      _BscCndnContrActivationStatus,
      _Supplier,
      _Customer,
      _PriorSupplier,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesGroup,
      _SalesOffice,
      _CreatedByUser,
      _LastChangedByUser,
      _BscConditionContractCurrency,
      _ExchangeRateType,
      _BscCndnContrSuplrSettlmtCat,
      _BscCndnContrCustSettlmtCat,
      _SettlmtProduct,
      _FinalSettlmtCalendar,
      _PartialSettlmtCalendar,
      _DeltaSettlmtCalendar,
      _DeltaAccrualSettlmtCalendar,
      _AccrualClearingSettlmtCal,
      _CndnContrExtensionCalendar,
      _PrecedingConditionDocument,
      _BscCndnContrPurposeCategory,
      _BscCndnContrSrceDocCategory,
      _BusVolTableGroup,
      _AmountFieldGroup,
      _BasicConditionContractUnit,
      _BscCndnContrWeightUnit,
      _BscCndnContrVolumeUnit,
      _BscCndnContrPtsQuantityUnit,
      _TaxCountry,
      _SettlmtPartTxRegnCntry,
      _BscCndnContrPrcgDetnRlvnceCat,
      _BusVolTotAmtSpltCritraGrp,
      _CndnContrPartnerCat,
      _CndnContrProcessCategory,
      _CndnContrSettlmtType

}
where
  CndnDocObjNodeTypeAbbr = 'BCC'