P_WBSElementWithVersion

@AbapCatalog.sqlViewName: 'PWBSWITHVERS'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@VDM.private: true
@AccessControl.authorizationCheck: #CHECK

define view P_WBSElementWithVersion
  as select from I_WBSElementVersion

{

  key WBSElement,

  key Version,
      WBSElementWithCodingMask,  //Not finalized field - please donot use


      'X'               as  IsProjectVersionObject,
      WBSElementInternalID,
      WBSElementHierarchyLevel,
      OverheadCode,
      ResultAnalysisInternalID,
      WBSElementObject,
      WBSDescription,
      ProjectInternalID,
      Project,
      ResponsiblePerson,
      ResponsiblePersonName,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      ApplicantCode,
      ApplicantName,
      ProjectType,
      WBSElementIsPlanningElement,
      WBSIsAccountAssignmentElement,
      WBSElementIsBillingElement,
      CostingSheet,
      PriorityCode,
      CompanyCode,
      BusinessArea,
      ControllingArea,
      ReqgCostCenterControllingArea,
      RequestingCostCenter,
      RespCostCenterControllingArea,
      ResponsibleCostCenter,
      Plant,
      ProfitCenter,
      ControllingObjectClass,
      BasicStartDate,
      BasicEndDate,
      ForecastedStartDate,
      ForecastedEndDate,
      ActualStartDate,
      ActualEndDate,
      SchedldBasicEarliestStartDate,
      SchedldBasicEarliestEndDate,
      SchedldBasicLatestStartDate,
      ScheduledBasicLatestEndDate,
      TentativeActualStartDate,
      TentativeActualEndDate,
      SchedldFcstdEarliestStartDate,
      SchedldFcstdEarliestEndDate,
      LatestSchedldFcstdStartDate,
      LatestSchedldFcstdEndDate,
      IsMarkedForDeletion,
      WBSIsMarkedForIntegratedPlng,
      WBSIsStatisticalWBSElement,
      TaxJurisdiction,
      FunctionalArea,
      Currency,
      FactoryCalendar,
      Location,
      Equipment,
      FunctionalLocation,
      ProjectObjectChangeNumber,
      ProjectObjectReferenceElement,
      ProgressAnlysAggregationWeight,
      ProjInterestCalcProfile,
      InvestmentProfile,
      ForecastedDuration,
      ForecastedDurationUnit,
      ActualDuration,
      BasicDuration,
      BasicDurationUnit,

      //Calculate Due Overdue Dates

      cast( 0 as int4 ) as  DueToStartDays,

      cast( 0 as int4 ) as  DueToEndDays,

      cast( 0 as int4 ) as  OverdueToStartDays,

      cast( 0 as int4 ) as  OverdueToEndDays,
      CostCenter,
      FreeDefinedTableFieldSemantic,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      FreeDefinedQuantity1,
      FreeDefinedQuantity1Unit,
      FreeDefinedQuantity2,
      FreeDefinedQuantity2Unit,
      FreeDefinedAmount1,
      FreeDefinedAmount1Currency,
      FreeDefinedAmount2,
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,
//  Joint Venture fields inclusion in the view      

      JointVenture,
      JointVentureRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,
      //-->Associations


      //I_WBSElementVersion._WBSElementLangBsdDesc,

      _ControllingObjectClass,
      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _ProfitCenter,
      _Plant,
      _ProjectType,
      _PriorityCode,
      _TaxJurisdiction,
      _Location,
      _Equipment,
      _FunctionalLocation,
      _FunctionalArea,
      _Interestcalculationprofile,
      _FactoryCalendar,
      _ResponsiblePerson,
      _ProjectApplicant,
      _WBSElementShortText
      //<--Associations


}

union all

select from I_WBSElement

{

  key WBSElement,

  key ''  as Version,

      WBSElementWithCodingMask, //Not finalized field - please donot use

      ''  as IsProjectVersionObject,
      WBSElementInternalID,
      WBSElementHierarchyLevel,
      OverheadCode,
      ResultAnalysisInternalID,
      WBSElementObject,
      WBSDescription,
      ProjectInternalID,
      Project,
      ResponsiblePerson,
      ResponsiblePersonName,
      CreatedByUser,
      CreationDate,
      LastChangedByUser,
      LastChangeDate,
      ApplicantCode,
      ApplicantName,
      ProjectType,
      WBSElementIsPlanningElement,
      WBSIsAccountAssignmentElement,
      WBSElementIsBillingElement,
      CostingSheet,
      PriorityCode,
      CompanyCode,
      BusinessArea,
      ControllingArea,
      ReqgCostCenterControllingArea,
      RequestingCostCenter,
      RespCostCenterControllingArea,
      ResponsibleCostCenter,
      Plant,
      ProfitCenter,
      ControllingObjectClass,
      BasicStartDate,
      BasicEndDate,
      ForecastedStartDate,
      ForecastedEndDate,
      ActualStartDate,
      ActualEndDate,
      SchedldBasicEarliestStartDate,
      SchedldBasicEarliestEndDate,
      SchedldBasicLatestStartDate,
      ScheduledBasicLatestEndDate,
      TentativeActualStartDate,
      TentativeActualEndDate,
      SchedldFcstdEarliestStartDate,
      SchedldFcstdEarliestEndDate,
      LatestSchedldFcstdStartDate,
      LatestSchedldFcstdEndDate,
      IsMarkedForDeletion,
      WBSIsMarkedForIntegratedPlng,
      WBSIsStatisticalWBSElement,
      TaxJurisdiction,
      FunctionalArea,
      Currency,
      FactoryCalendar,
      Location,
      Equipment,
      FunctionalLocation,
      ProjectObjectChangeNumber,
      ProjectObjectReferenceElement,
      ProgressAnlysAggregationWeight,
      ProjInterestCalcProfile,
      InvestmentProfile,
      ForecastedDuration,
      ForecastedDurationUnit,
      ActualDuration,
      BasicDuration,
      BasicDurationUnit,
      //Calculate Due Overdue Dates

      case
          when I_WBSElement.SchedldBasicLatestStartDate != '00000000' and I_WBSElement.SchedldBasicLatestStartDate > $session.system_date
           and I_WBSElement.TentativeActualStartDate = '00000000' and I_WBSElement.TentativeActualEndDate = '00000000'
           and I_WBSElement.ActualStartDate = '00000000' and I_WBSElement.ActualEndDate = '00000000'
              then dats_days_between( cast($session.system_date as sydatum),
                                      I_WBSElement.SchedldBasicLatestStartDate
                                    )
      else
          case
              when I_WBSElement.BasicStartDate != '00000000'  and I_WBSElement.BasicStartDate > $session.system_date
               and I_WBSElement.TentativeActualStartDate = '00000000' and I_WBSElement.TentativeActualEndDate = '00000000'
               and I_WBSElement.ActualStartDate = '00000000' and I_WBSElement.ActualEndDate = '00000000'
               and I_WBSElement.SchedldBasicLatestStartDate = '00000000'
                  then dats_days_between( cast($session.system_date as sydatum),
                                          I_WBSElement.BasicStartDate
                                        )
              else 0
           end
      end as DueToStartDays,
      case
         when I_WBSElement.ScheduledBasicLatestEndDate != '00000000' and I_WBSElement.ScheduledBasicLatestEndDate > $session.system_date
          and I_WBSElement.ActualEndDate = '00000000'
             then dats_days_between( cast($session.system_date as sydatum),
                                     I_WBSElement.ScheduledBasicLatestEndDate
                                   )
          else
             case
                 when I_WBSElement.BasicEndDate != '00000000'  and I_WBSElement.BasicEndDate > $session.system_date
                  and I_WBSElement.ActualEndDate = '00000000' and I_WBSElement.ScheduledBasicLatestEndDate = '00000000'
                     then dats_days_between( cast($session.system_date as sydatum),
                                             I_WBSElement.BasicEndDate
                                           )
                 else 0
              end
      end as DueToEndDays,
      case
         when I_WBSElement.SchedldBasicLatestStartDate != '00000000' and I_WBSElement.SchedldBasicLatestStartDate < $session.system_date
          and I_WBSElement.TentativeActualStartDate = '00000000' and I_WBSElement.TentativeActualEndDate = '00000000'
          and I_WBSElement.ActualStartDate = '00000000' and I_WBSElement.ActualEndDate = '00000000'
             then dats_days_between( I_WBSElement.SchedldBasicLatestStartDate,
                                     cast($session.system_date as sydatum)
                                   )
         else
             case
                 when I_WBSElement.BasicStartDate != '00000000'  and I_WBSElement.BasicStartDate < $session.system_date
                  and I_WBSElement.TentativeActualStartDate = '00000000' and I_WBSElement.TentativeActualEndDate = '00000000'
                  and I_WBSElement.ActualStartDate = '00000000' and I_WBSElement.ActualEndDate = '00000000'
                  and I_WBSElement.SchedldBasicLatestStartDate = '00000000'
                     then dats_days_between( I_WBSElement.BasicStartDate,
                                             cast($session.system_date as sydatum)
                                           )
                 else 0
              end
      end as OverdueToStartDays,
      case
         when I_WBSElement.ScheduledBasicLatestEndDate != '00000000' and I_WBSElement.ScheduledBasicLatestEndDate < $session.system_date
          and I_WBSElement.ActualEndDate = '00000000'
             then dats_days_between( I_WBSElement.ScheduledBasicLatestEndDate,
                                     cast($session.system_date as sydatum)
                                   )
         else
             case
                 when I_WBSElement.BasicEndDate != '00000000'  and I_WBSElement.BasicEndDate < $session.system_date
                  and I_WBSElement.ActualEndDate = '00000000' and I_WBSElement.ScheduledBasicLatestEndDate = '00000000'
                     then dats_days_between( I_WBSElement.BasicEndDate,
                                             cast($session.system_date as sydatum)
                                           )
                 else 0
              end
      end as OverdueToEndDays,
      CostCenter,
      FreeDefinedTableFieldSemantic,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      FreeDefinedQuantity1,
      FreeDefinedQuantity1Unit,
      FreeDefinedQuantity2,
      FreeDefinedQuantity2Unit,
      FreeDefinedAmount1,
      FreeDefinedAmount1Currency,
      FreeDefinedAmount2,
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,
//  Joint Venture fields inclusion in the view      

      JointVenture,
      JointVentureRecoveryCode,
      JointVentureEquityType,
      JointVentureObjectType,
      JointVentureClass,
      JointVentureSubClass,      
      //-->Associations


      //I_WBSElement._WBSElementLangBsdDesc,

      _ControllingObjectClass,
      _ControllingArea,
      _CompanyCode,
      _BusinessArea,
      _ProfitCenter,
      _Plant,
      _ProjectType,
      _PriorityCode,
      _TaxJurisdiction,
      _Location,
      _Equipment,
      _FunctionalLocation,
      _FunctionalArea,
      _Interestcalculationprofile,
      _FactoryCalendar,
      _ResponsiblePerson,
      _ProjectApplicant,
      _WBSElementShortText
      //<--Associations


}