P_WBHK_ValueHelp

@AbapCatalog.sqlViewName: 'PWBHKVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #MANDATORY
// 'Trading Contract Value Help' with access control for display activity

// ABAP unit tests available in class: CL_CDS_P_WBHK_VALUEHELP

define view P_WBHK_ValueHelp

  as select from    wbhk
    inner join      wbhd on wbhd.tkonn = wbhk.tkonn
    left outer to one join tvta on tvta.vkorg = wbhk.vkorg and tvta.vtweg = wbhk.vtweg and tvta.spart = wbhk.spart

  association [0..1] to knvv as _CustomerSalesArea on $projection.kunnr = _CustomerSalesArea.kunnr 
                                                  and $projection.vkorg = _CustomerSalesArea.vkorg 
                                                  and tvta.vtwku        = _CustomerSalesArea.vtweg
                                                  and tvta.spaku        = _CustomerSalesArea.spart
  association [0..1] to P_WLF_CDS_LFA1_BG as _Supplier on $projection.elifn = _Supplier.vendor_account

{
  key wbhk.tkonn,
      wbhk.tkonn_ex,
      wbhk.tctyp,
      wbhk.tksachb,
      wbhk.kunnr,
      wbhd.elifn as elifn,
      wbhk.vkorg,
      wbhk.vtweg,
      wbhk.spart,
      wbhd.ekorg as ekorg,
      wbhd.ekgrp as ekgrp,
      wbhk.ernam,
      wbhk.erdat,
      wbhk.erzeit,
      wbhk.aenam,
      wbhk.aedat,
      wbhk.aezeit,
      wbhk.tccat,
      wbhk.use_case,
      wbhk.purpose,
      wbhk.complete,
      _Supplier.vendor_begru,
      _CustomerSalesArea.begru as customer_begru
}
where
      wbhd.tposn     = '000000'
  and wbhd.tposn_sub = '000000'