P_UA_CompanyCodeData

@AbapCatalog.sqlViewName: 'PUACOMPANYDATA'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@VDM.private: true
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
define view P_UA_CompanyCodeData
  as select from    I_CompanyCode
    left outer join P_UA_OrganizationName        as CompanyCodeName on CompanyCodeName.AddressID = I_CompanyCode.AddressID
    left outer join I_AddlCompanyCodeInformation as AddlInfoTIN     on  AddlInfoTIN.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoTIN.CompanyCodeParameterType = 'SAPU03'

    left outer join I_AddlCompanyCodeInformation as AddlInfoSPATO   on  AddlInfoSPATO.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoSPATO.CompanyCodeParameterType = 'SAPU06'

    left outer join I_AddlCompanyCodeInformation as AddlInfoKVED    on  AddlInfoKVED.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoKVED.CompanyCodeParameterType = 'SAPU08'

    left outer join I_AddlCompanyCodeInformation as AddlInfoRUK     on  AddlInfoRUK.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoRUK.CompanyCodeParameterType = 'J1UBOS'

    left outer join I_AddlCompanyCodeInformation as AddlInfoBUH     on  AddlInfoBUH.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoBUH.CompanyCodeParameterType = 'J1UGLB'

    left outer join I_AddlCompanyCodeInformation as AddlInfoOPFCD   on  AddlInfoOPFCD.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoOPFCD.CompanyCodeParameterType = 'SAPU09'

    left outer join I_AddlCompanyCodeInformation as AddlInfoUSR     on  AddlInfoUSR.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoUSR.CompanyCodeParameterType = 'SAPUSR'

    left outer join I_AddlCompanyCodeInformation as AddlInfoKATOT   on  AddlInfoKATOT.CompanyCode              = I_CompanyCode.CompanyCode
                                                                    and AddlInfoKATOT.CompanyCodeParameterType = 'J1UPLC'

{

  key I_CompanyCode.CompanyCode,
      I_CompanyCode.AddressID,
      CompanyCodeName.OrganizationName                           as CompanyName,
      AddlInfoTIN.CompanyCodeParameterValue                      as CompanyCodeTIN,
      AddlInfoSPATO.CompanyCodeParameterValue                    as CompanyCodeSPATO,
      I_CompanyCode._Address.CareOfName                          as CompanyCodeTERR,
      I_CompanyCode._Address.PhoneNumber                         as CompanyCodePhoneNum,
      AddlInfoKVED.CompanyCodeParameterValue                     as CompanyCodeKVED,
      AddlInfoRUK.CompanyCodeParameterValue                      as CompanyCodeRUK,
      AddlInfoBUH.CompanyCodeParameterValue                      as CompanyCodeBUH,
      AddlInfoOPFCD.CompanyCodeParameterValue                    as CompanyCodeOPFCD,
      AddlInfoUSR.CompanyCodeParameterValue                      as CompanyCodeUSR,
      AddlInfoKATOT.CompanyCodeParameterValue                    as CompanyCodeKATOTTG,
      //substring( AddlInfoKVED.CompanyCodeParameterValue, 6, 41 )   as CompanyKVEDNM,

      substring( AddlInfoSPATO.CompanyCodeParameterValue, 1, 2 ) as CompanyOBL,
      substring( AddlInfoSPATO.CompanyCodeParameterValue, 3, 3 ) as CompanyDistCode,
      //substring( AddlInfoOPFCD.CompanyCodeParameterValue, 4, 44 )  as CompanyCodeOPFNM,




      CONCAT_WITH_SPACE( I_CompanyCode._Address.CityName,
        CONCAT_WITH_SPACE( I_CompanyCode._Address.StreetName,
            I_CompanyCode._Address.HouseNumber, 1 ), 1 )         as FirmAdress

}