P_TradingContractOverview

@AbapCatalog:
{
  sqlViewName: 'PTRDGCTROVW',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl.authorizationCheck: #CHECK
@ClientHandling:
{
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}
@VDM:
{
  viewType: #COMPOSITE,
  private: true
}
@ObjectModel.usageType:
{
  dataClass: #TRANSACTIONAL,
  serviceQuality: #C,
  sizeCategory: #XL
}
define view P_TradingContractOverview
  as select from           P_TradingContractHeader       as Header
    inner join             P_TradingContractBusinessDets as Business              on Header.tkonn = Business.TradingContractNumber
    left outer to one join I_ACMSalesCounterparty        as Sales_Counterparty    on Header.kunnr = Sales_Counterparty.Counterparty
    left outer to one join I_ACMPurchaseCounterparty     as Purchase_Counterparty on Business.PurchaseOrderSupplier = Purchase_Counterparty.Counterparty
    left outer to one join I_CmmdtyDrvtvGenericDomainVH  as Side                  on  Business.DocumentSide        = Side.DomainValue
                                                                                  and Side.SAPDataDictionaryDomain = '/ACCGO/D_CNTRCT_SIDE'
{
  key Header.tkonn                         as TradingContractNumber,
      Header.tctyp                         as TradingContractType,
      Header.tctyp_descr                   as TradingContractTypeName,
      Business.DocumentSide                as Side,
      Header.btbsta                        as ContractStatus,
      Header.bezei                         as TrdgContrApplStsName,

      case Business.DocumentSide
        when 'M'
         then Business.TradingContractCurrency
        else
          Header.sdwrs
        end                                as TradingContractCurrency,

      Header.vkorg                         as SalesOrganization,
      Header.vtweg                         as DistributionChannel,
      Header.spart                         as Division,
      Business.PurchasingOrganization      as PurchasingOrganization,
      Business.ekotx,
      Business.PurchasingGroup             as PurchasingGroup,
      Business.eknam,
      Header.tkonn_ex                      as TradingContractExternalID,
      Header.erdat                         as TradingContrCreatedOnDate,
      Header.budat                         as DocumentDate,
      Header.tksachb                       as PersonResponsible,
      Header.PersonResponsible             as PersonResponsibleName,
      Header.ernam                         as TradingContractCreatedBy,
      Header.CreatedBy                     as TradingContractCreatedByName,
      Header.aenam                         as TradingContractChangedBy,
      Header.ChangedBy                     as TradingContractChangedByName,
      Header.aedat                         as TradingContractChangedOnDate,
      Header.DistributionChannelDescr,
      Header.SalesDivisionDescr,
      Header.SalesOrgDescr,
      Side.DomainText                      as DocumentSide,

      case Business.DocumentSide
       when 'M'
        then Purchase_Counterparty.Counterparty
       else
         Sales_Counterparty.Counterparty
       end                                 as Counterparty,

      case Business.DocumentSide
      when 'M'
        then Business.ACMPurgIncotermsPart1
      else
        Business.ACMSlsIncotermsPart1
      end                                  as Incoterms,

      Business.IncotermsClassificationName as IncotermsClassificationName,
      case Business.DocumentSide
      when 'M'
       then Business.TrdgContrPurgIncotermsLoc1Text
      else
       Business.TrdgContrSlsIncotermsLoc1Text
      end                                  as IncotermsLocation1,

      Business.TrdgContrPurgIncotermsLoc1Text, //+Free Text Search

      Business.TrdgContrSlsIncotermsLoc1Text, //+Free Text Search


      company_code                         as CompanyCode,

      case Business.DocumentSide
      when 'M'
        then Business.TrdgContrPurgPaymentTerms
      else   Business.TrdgContrSalesPaymentTerms
      end                                  as AlternatePaymentTerm,
      Header.resp_trader_id,
      Header.orig_resp_trader_id,
      Header.TradingContractTradeOffice,
      Header.TradingContractCreditSales,
      Header.ACMSignedStatus,
      Header.ACMTrdgContrIsStatusClosed,
      Business.ACMSupplyingPlant,
      Business.ACMReferencePO,
      Business.ACMCustomerReference,
      Business.ACMYourReference


}