P_TaxCode

@AbapCatalog.sqlViewName: 'PFITAXCODE'
//@EndUserText.label: 'Private view to retrieve Tax Code Details'

@VDM.private: true
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'TaxCode'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING

define view P_TaxCode
  as select from t007a

  association [0..*] to I_TaxCodeText             as _Text                    on  $projection.TaxCalculationProcedure = _Text.TaxCalculationProcedure
                                                                              and $projection.TaxCode                 = _Text.TaxCode

  association [0..1] to I_TaxType                 as _TaxType                 on  $projection.TaxType = _TaxType.TaxType

  association [0..1] to I_TaxCalculationProcedure as _TaxCalculationProcedure on  $projection.TaxCalculationProcedure = _TaxCalculationProcedure.TaxCalculationProcedure

{
      @ObjectModel.foreignKey.association: '_TaxCalculationProcedure'
  key kalsm                                  as TaxCalculationProcedure,
      @ObjectModel.text.association: '_Text'
  key cast(mwskz as fis_mwskz)               as TaxCode,
      @ObjectModel.foreignKey.association: '_TaxType'
      mwart                                  as TaxType,
      cast (zmwsk as farp_dzmwsk)            as TargetTaxCode,
      egrkz                                  as EUTaxClassification,
      xslta                                  as IsSalesTaxes,
      cast ( txind as smwsk )                as TaxCategory,
      lstml                                  as TaxReturnCountry,
      cast( tolerance as fot_tax_tolerance ) as TaxTolerancePercent,
      zmwsk_esa                              as EUAcqnInputTaxCode,
      zmwsk_ese                              as EUAcqnOutputTaxCode,
      mossc                                  as MossTaxCode,

      _TaxCalculationProcedure,
      _TaxType,
      _Text
}