P_SimulationObjectSearch

@AbapCatalog.sqlViewName: 'PSIMOBJSR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED


@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION
@VDM.private: true

define view P_SimulationObjectSearch
  as select from    P_SimulationObjectUnion        as SimulationObjectUnion

  //Only existing Products shall be considered

  //inner join I_Material as _Product on SimulationObjectUnion.Product = _Product.Material

    inner join      I_Product                      as _Product                 on  SimulationObjectUnion.Product = _Product.Product
                                                                               and _Product.IsMarkedForDeletion != 'X'

  //Attributes for Product Variant templates

    left outer join I_Material                     as _ProductVariant          on  SimulationObjectUnion.Product = _ProductVariant.Material
                                                                               and SimulationObjectUnion.Type    = 'MVAR'

  //Attributes for Sales Document templates (only header level)

    left outer join P_VarConfignSalesDocument      as _SalesDocument           on  SimulationObjectUnion.SalesDocument = _SalesDocument.SalesDocument
                                                                               and ( SimulationObjectUnion.Type          = 'SORD'
                                                                               or    SimulationObjectUnion.Type          = 'QUOT' )

    left outer join P_VarConfignPurchasingDocument as _PurchasingDocument      on  SimulationObjectUnion.PurchasingDocument = _PurchasingDocument.PurchasingDocument
                                                                               and SimulationObjectUnion.Type               = 'PURO'

    left outer join P_VarConfignPurchaseReqnItem   as _PurchaseRequisitionItem on  SimulationObjectUnion.PurchaseRequisition     = _PurchaseRequisitionItem.PurchaseRequisition
                                                                               and SimulationObjectUnion.PurchaseRequisitionItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
                                                                               and SimulationObjectUnion.Type                    = 'PURR'

  //Attributes for authorization checks

  //I_ProductGroup is deprecated to I_ProductGroup_2

  association [0..1] to I_ProductGroup                 as _ProductGroup             on  $projection.ProductGroup = _ProductGroup.MaterialGroup

  association [0..1] to I_ProductGroup_2               as _ProductGroup_2           on  $projection.ProductGroup = _ProductGroup_2.ProductGroup

  association [1..1] to I_Producttype                  as _ProductType              on  $projection.ProductType = _ProductType.ProductType

  //I_ProductGroup is deprecated to I_ProductGroup_2

  association [0..1] to I_ProductGroup                 as _ProductVariantGroup      on  $projection.ProductVariantGroup = _ProductVariantGroup.MaterialGroup

  association [0..1] to I_ProductGroup_2               as _ProductVariantGroup_2    on  $projection.ProductGroup = _ProductVariantGroup_2.ProductGroup

  association [1..1] to I_Producttype                  as _ProductVariantType       on  $projection.ProductVariantType = _ProductVariantType.ProductType

  //Source of description for the configurable Product

  association [1..1] to I_ProductText                  as _ProductText              on  $projection.Product   = _ProductText.Product
                                                                                    and _ProductText.Language = $session.system_language

  //Source of description for the Product Variant template

  association [0..1] to I_ProductText                  as _ProductVariantText       on  $projection.ConfigurationObject = _ProductVariantText.Product
                                                                                    and _ProductVariantText.Language    = $session.system_language
                                                                                    and $projection.Type                = 'MVAR'

  //Favorites

  association [0..1] to P_SimulationFavorite           as _Favorite                 on  _Favorite.UserAlias                 = $session.user
                                                                                    and $projection.ConfigurationObject     = _Favorite.ConfigurationObject
                                                                                    and $projection.ConfigurationObjectItem = _Favorite.ConfigurationObjectItem
                                                                                    and $projection.Type                    = _Favorite.Type

  //Value Helps

  association [0..1] to I_VarConfignSimlnTypeValueHelp as _TypeValueHelp            on  $projection.Type = _TypeValueHelp.Type

  association [1..*] to C_VarConfignConfigblProdVH     as _ConfigblProductValueHelp on  $projection.Product = _ConfigblProductValueHelp.Product

  association [0..1] to C_VarConfignPlantVH            as _PlantValueHelp           on  $projection.Plant = _PlantValueHelp.Plant

  association [0..1] to I_ConfigurationStatusValueHelp as _StatusValueHelp          on  $projection.ConfigurationStatus = _StatusValueHelp.ConfigurationStatus

  association [0..1] to I_VarConfignSimlnFavoriteVH    as _FavoriteValueHelp        on  _Favorite.IsFavoriteConfigurationObject = _FavoriteValueHelp.IsFavoriteConfigurationObject
{

  key  SimulationObjectUnion.Type,

  key  SimulationObjectUnion.ConfigurationObject,
  key  ConfigurationObjectItem,

       _TypeValueHelp.VariantConfignOwnerTypeDesc          as VariantConfignOwnerTypeDesc,

       _ProductVariantText.ProductName                     as ProductVariantDescription,
       SimulationObjectUnion.Product,
       _ProductText.ProductName                            as ProductName,
       SimulationObjectUnion.Plant,
       _PlantValueHelp.PlantName,
       SimulationObjectUnion.CreatedByUser,
       SimulationObjectUnion.CreationDate,
       SimulationObjectUnion.LastChangeDate,
       SimulationObjectUnion.LastChangedByUser,
       _Favorite.IsFavoriteConfigurationObject,
       SimulationObjectUnion.VariantConfigurationSimlnName,
       SimulationObjectUnion.VarConfignSimlnExternalID,
       SimulationObjectUnion.ProductConfiguration,
       SimulationObjectUnion.DraftUUID,
       SimulationObjectUnion.HasActiveEntity,
       SimulationObjectUnion.ConfigurationProfileNumber,
       SimulationObjectUnion.VariantConfigurationSimlnDate,
       SimulationObjectUnion.ConfigurationProfileProcess,
       ConfigurationStatus,
       _StatusValueHelp.ConfigurationStatusText            as ConfigurationStatusText,
       case ConfigurationStatus
        when '1' then 3
        when '2' then 1
        when '5' then 1
        when ''  then 0
        else 0
       end                                                 as ConfigurationStatusCriticality,

       //Helper fields

       ConfigurationObjTypeForSorting,

       //These fields are exposed only for enabling searching in them

       SimulationObjectUnion.SalesDocument,
       SimulationObjectUnion.SalesDocumentItem,
       SimulationObjectUnion.ProductVariant,
       SimulationObjectUnion.PurchasingDocument,
       SimulationObjectUnion.PurchasingDocumentItem,
       SimulationObjectUnion.PurchaseRequisition,
       SimulationObjectUnion.PurchaseRequisitionItem,

       //Fields required for athorization checks

       SimulationObjectUnion.ClassType,

       /*_Product.MaterialType                                                        as ProductType,
       _Product.MaterialGroup                                                       as ProductGroup,
       _Product.AuthorizationGroup                                                  as ProductAuthorizationGroup,*/
       _Product.ProductType                                as ProductType,
       _Product.ProductGroup                               as ProductGroup,
       _Product.AuthorizationGroup                         as ProductAuthorizationGroup,
       _Product.ProductExternalID,

       _SalesDocument.SalesDocumentType,
       _SalesDocument.OrganizationDivision,
       _SalesDocument.SalesOrganization,
       _SalesDocument.DistributionChannel,

       _ProductVariant.MaterialType                        as ProductVariantType,
       _ProductVariant.MaterialGroup                       as ProductVariantGroup,
       _ProductVariant.AuthorizationGroup                  as ProductVariantAuthorizationGrp,

       _PurchasingDocument.PurchasingDocumentType          as PurchasingDocumentType,
       _PurchaseRequisitionItem.PurchaseRequisitionType    as PurchaseRequisitionType,

       coalesce(
        _PurchasingDocument.PurchasingOrganization,
        _PurchaseRequisitionItem.PurchasingOrganization  ) as PurchasingOrganization,

       coalesce(
        _PurchasingDocument.PurchasingGroup,
        _PurchaseRequisitionItem.PurchasingGroup  )        as PurchasingGroup,

       //Value Helps

       _ConfigblProductValueHelp,
       _StatusValueHelp,
       _PlantValueHelp,

       //Associations

       _ProductText,
       _ProductVariantType,
       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: '_ProductVariantGroup_2'
       _ProductVariantGroup,
       _ProductVariantGroup_2,
       _TypeValueHelp,
       _FavoriteValueHelp,
       _ProductType,
       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: '_ProductGroup_2'
       _ProductGroup,
       _ProductGroup_2
}