P_SalesContractProcessFlow41

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PSLSCONPROCFL41'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true
@EndUserText.label: 'Contract process flow level 4-1'
define view P_SalesContractProcessFlow41
  with parameters P_SalesContract: vbeln_von
  as select from P_SalesContractProcessFlow30(P_SalesContract: $parameters.P_SalesContract) as Level30
    inner join I_AccountingDocument as AccountingDocument
    on Level30.SubsequentDocument = AccountingDocument.OriginalReferenceDocument
    and AccountingDocument.ReferenceDocumentType = 'VBRK'    
    and LedgerGroup = ''
    left outer to one join I_SDDocumentCategory  as _SDDocumentCategory on _SDDocumentCategory.SDDocumentCategory = '+'
    association [0..1] to I_UnitOfMeasure as _BaseUnit           on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
    association [0..1] to I_Currency      as _StatisticsCurrency on $projection.StatisticsCurrency = _StatisticsCurrency.Currency
{ 
  key  Level30.SalesContract,
  key  Level30.SubsequentDocument                             as PrecedingDocument,
  key  Level30.SubsequentDocumentItem                         as PrecedingDocumentItem,
  key  Level30.SubsequentDocumentCategory                     as PrecedingDocumentCategory,
  key  AccountingDocument.AccountingDocument                  as SubsequentDocument,
  key  Level30.SubsequentDocumentItem                         as SubsequentDocumentItem,
  key  cast( '+'  as vbtypl_v )                               as SubsequentDocumentCategory,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       cast( 0 as rfmng )                                     as QuantityInBaseUnit,
       cast( '' as meins )                                    as BaseUnit,
       @Semantics.amount.currencyCode: 'StatisticsCurrency'
       cast( 0 as rfwrt )                                     as NetAmount,
       @Semantics.currencyCode: true
       AccountingDocument.Currency                            as StatisticsCurrency,
       cast( '' as status_bez )                               as SDProcessStatusDesc,
       AccountingDocument.FiscalYear                          as FiscalYear,
       AccountingDocument.CompanyCode                         as CompanyCode,
       cast( '0000' as mjahr )                                as MaterialDocumentYear,
       cast( 'AccountingDocument' as bpf_sem_obj )            as SemanticObject,
       _SDDocumentCategory._Text[1:Language=$session.system_language].SDDocumentCategoryName  as SDDocumentCategoryName,
       AccountingDocument.AccountingDocumentCreationDate      as CreationDate,
       AccountingDocument.CreationTime,
       _BaseUnit, 
       _StatisticsCurrency
}
where Level30.SubsequentDocumentCategory = 'M'  --> Invoice      
or    Level30.SubsequentDocumentCategory = 'O'  --> Credit Memo
or    Level30.SubsequentDocumentCategory = 'P'  --> Debit Memo     
or    Level30.SubsequentDocumentCategory = '5'  --> Intercompany Invoice
or    Level30.SubsequentDocumentCategory = '6'  --> Intercompany Credit Memo