P_SalesContractProcessFlow20

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PSLSCONPROCFL20'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true
@EndUserText.label: 'Contract process flow level 2-0'
define view P_SalesContractProcessFlow20
  with parameters P_SalesContract: vbeln_von
  as select from P_SalesContractProcessFlow10(P_SalesContract: $parameters.P_SalesContract) as Level10
    inner join I_SDDocumentProcessFlow as _ProcessFlow on Level10.SubsequentDocument          = _ProcessFlow.PrecedingDocument
                                                      and Level10.SubsequentDocumentItem      = _ProcessFlow.PrecedingDocumentItem
                                                      and Level10.SubsequentDocumentCategory  = _ProcessFlow.PrecedingDocumentCategory
                                                      and (
                                                           _ProcessFlow.SubsequentDocumentCategory = 'J' or   --> Delivery
                                                           _ProcessFlow.SubsequentDocumentCategory = 'T' or   --> Returns Delivery 
                                                           _ProcessFlow.SubsequentDocumentCategory = 'M' or   --> Invoice  
                                                           _ProcessFlow.SubsequentDocumentCategory = 'O' or   --> Credit Memo
                                                           _ProcessFlow.SubsequentDocumentCategory = 'P' or   --> Debit Memo
                                                           _ProcessFlow.SubsequentDocumentCategory = 'C' or   --> Order
                                                           _ProcessFlow.SubsequentDocumentCategory = 'I' or   --> Order w/o charge
                                                           _ProcessFlow.SubsequentDocumentCategory = 'K' or   --> Credit Memo Request  
                                                           _ProcessFlow.SubsequentDocumentCategory = 'L' or   --> Debit Memo Request  
                                                           _ProcessFlow.SubsequentDocumentCategory = 'U' or   --> Pro Forma Invoice
                                                           _ProcessFlow.SubsequentDocumentCategory = '5' or   --> Intercompany Invoice
                                                           _ProcessFlow.SubsequentDocumentCategory = '6' or   --> Intercompany Credit Memo
                                                           _ProcessFlow.SubsequentDocumentCategory = 'V' or   --> Purchase Order
                                                           _ProcessFlow.SubsequentDocumentCategory = 'H'   --> Customer Return
                                                          )
    left outer to one join I_SDDocumentCategory  as _SDDocumentCategory on _SDDocumentCategory.SDDocumentCategory = _ProcessFlow.SubsequentDocumentCategory
    association [0..1] to I_UnitOfMeasure as _BaseUnit           on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
    association [0..1] to I_Currency      as _StatisticsCurrency on $projection.StatisticsCurrency = _StatisticsCurrency.Currency
{ 
  key  Level10.SalesContract,
  key  _ProcessFlow.PrecedingDocument,
  key  _ProcessFlow.PrecedingDocumentItem,
  key  _ProcessFlow.PrecedingDocumentCategory,
  key  _ProcessFlow.SubsequentDocument,
  key  _ProcessFlow.SubsequentDocumentItem,
  key  _ProcessFlow.SubsequentDocumentCategory,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       _ProcessFlow.QuantityInBaseUnit,
       _ProcessFlow.BaseUnit,
       @Semantics.amount.currencyCode: 'StatisticsCurrency'
       _ProcessFlow.NetAmount,
       @Semantics.currencyCode: true
       _ProcessFlow.StatisticsCurrency,
       cast( '' as status_bez )                               as SDProcessStatusDesc,
       cast( '0000' as gjahr )                                as FiscalYear,
       cast( '' as bukrs )                                    as CompanyCode,
       cast( '0000' as mjahr )                                as MaterialDocumentYear,
       cast( ( case _ProcessFlow.SubsequentDocumentCategory 
               when 'C' then 'SalesOrder'
               when 'J' then 'OutboundDelivery'
               when 'H' then 'CustomerReturn'
               when 'K' then 'CreditMemoRequest'
               when 'L' then 'DebitMemoRequest'
               when 'M' then 'BillingDocument'
               when 'N' then 'BillingDocument'
               when 'O' then 'BillingDocument'
               when 'P' then 'BillingDocument'
               when 'S' then 'BillingDocument'
               when 'U' then 'BillingDocument'
               end ) as bpf_sem_obj )                         as SemanticObject,
       _SDDocumentCategory._Text[1:Language=$session.system_language].SDDocumentCategoryName  as SDDocumentCategoryName,
       _ProcessFlow.CreationDate,
       _ProcessFlow.CreationTime,
       _BaseUnit, 
       _StatisticsCurrency
}