P_Ra_Objects

@AbapCatalog.sqlViewName: 'PRA_OBJECTS'
@ClientDependent: true
@AbapCatalog.compiler.compareFilter: true
@VDM.private:true //= @VDM.private

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Objects of results analysis'


@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER

//Used by view P_Ra_Line_Items_Posting_Rules

//Selects from onr00, prps, proj, aufk, vbap, vbak, P_Kkag_Werk_Bukrs_Kokrs, afpo and tkkaa


define view P_Ra_Objects as

select
  a.objnr,
  case when b.objnr <> ' ' then b.pkokr when d.objnr <> ' ' then d.kokrs when f.objnr <> ' ' then e.kokrs when h.objnp <> ' ' then g.kokrs else ' ' end as kokrs,
  case when b.objnr <> ' ' then b.pbukr when d.objnr <> ' ' then d.bukrs when f.objnr <> ' ' then e.bukrs when h.objnp <> ' ' then g.bukrs else ' ' end as bukrs,
  case when b.objnr <> ' ' then b.werks when d.objnr <> ' ' then d.werks when f.objnr <> ' ' then f.werks when h.objnp <> ' ' then h.dwerk else ' ' end as werks,
  case when b.objnr <> ' ' then b.prctr when d.objnr <> ' ' then d.prctr when f.objnr <> ' ' then f.prctr when h.objnp <> ' ' then g.prctr else ' ' end as prctr,
  
  b.pspnr as pspnr,
  b.posid as posid,
  c.pspnr as psphi,
  c.pspid as pspid,
  case when d.objnr <> ' ' then d.aufnr when h.objnp <> ' ' then g.aufnr else ' ' end as aufnr,
  case when d.objnr <> ' ' then d.auart when h.objnp <> ' ' then g.auart else ' ' end as auart,
  h.posnr as posnr_co,
  f.vbeln as vbeln,
  f.posnr as posnr_va,
  
  case when b.objnr <> ' ' then b.abgsl when d.objnr <> ' ' then d.abgsl when f.objnr <> ' ' then f.abgrs when h.objnp <> ' ' then g.abgsl else ' ' end as abgsl

  from onr00 as a 

  left outer join prps as b on b.objnr = a.objnr and b.abgsl <> ' '
  left outer join proj as c on c.pspnr = b.psphi 
  
  left outer join aufk as d on d.objnr = a.objnr and d.flg_mltps = ' ' and d.abgsl <> ' ' 
  
  left outer join vbap as f on f.objnr = a.objnr and f.abgrs <> ' ' 
  left outer join P_Kkag_Werk_Bukrs_Kokrs as e on e.werks = f.werks
  
  left outer join afpo as h on h.objnp = a.objnr
  left outer join aufk as g on g.flg_mltps = 'X' and g.abgsl <> ' ' and g.aufnr = h.aufnr

  inner join tkkaa as i on    (    i.abgsl = b.abgsl 
                                or i.abgsl = d.abgsl 
                                or i.abgsl = f.abgrs 
                                or i.abgsl = g.abgsl ) 
                           and i.slerg = 'X' 
  
  where ( a.objnr like 'PR%' or a.objnr like 'OR%' or a.objnr like 'VB%' or a.objnr like 'OP%' ) and
        ( a.objnr like 'PR%' and b.posid <> ' ' or 
          a.objnr like 'OR%' and d.aufnr <> ' ' or
          a.objnr like 'VB%' and f.vbeln <> ' ' or
          a.objnr like 'OP%' and h.posnr <> '0000' 
          )
  
;