P_RSHCapacityInOpTimeFrame

@AbapCatalog.sqlViewName: 'PRSHCAPOPTMFR'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE

/*
CONTRACT**********************************************************************************************************************

Name:                       Work Center Capacity in Operations Time Frame
Specification:              This view will return work center capacity between effective/largest date interval that is spanned by the operations
                            and sub operations under the maintenance orders as well as under the maintenance plans (The Maintenance Plan interval 
                            will be same as the incoming period, since maintencne plan operations will not span more
                            than one day)
Requires:                   NA
Ensures:                    Work Center Capacity in Operations Time Frame is returned
Owners:                     PRP
Contributors:               CK, AN
Unit Test required Y/N:     Yes
Additional comments         None

END OF CONTRACT***************************************************************************************************************
*/

define view P_RSHCapacityInOpTimeFrame
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum

  as select from P_RSHCALWORKDAYS( P_SAPClient : $session.client )                                                 as date_series

    cross join   P_RSHOperationTimeFrame(P_StartDate : $parameters.P_StartDate, P_EndDate : $parameters.P_EndDate) as OperationTimeFrame

    inner join   P_RSHWCCapacityWithNights                                                                         as WorkCenterCapacity on  WorkCenterCapacity.CapacityInternalID             =       date_series.CapacityInternalID
                                                                                                                                         and date_series.CalendarDate                          between WorkCenterCapacity.ValidityBeginDate and WorkCenterCapacity.ValidityEndDate

                                                                                                                                         and (
                                                                                                                                            (
                                                                                                                                              WorkCenterCapacity.AvailableCapacityIntervalDurn =       '01'
                                                                                                                                            )     // 1 day shift interval duration

                                                                                                                                            or(
                                                                                                                                              WorkCenterCapacity.AvailableCapacityIntervalDurn =       '07'
                                                                                                                                              and // 7 day shift interval duration

                                                                                                                                              date_series.WeekDay                              =       WorkCenterCapacity.WeekDay
                                                                                                                                            )
                                                                                                                                          )

{

  key date_series.CapacityInternalID,
  key CalendarDate,
      date_series.WeekDay,
      WorkDays,

      WorkCenterCapacity.ValidityEndDate,
      WorkCenterCapacity.AvailableCapacityShift,
      WorkCenterCapacity.CapacityStartTime,
      WorkCenterCapacity.ValidityBeginDate,
      WorkCenterCapacity.NightSplitDate,
      WorkCenterCapacity.AvailableCapacityIntervalDurn,
      WorkCenterCapacity.WorkDayRule,
      WorkCenterCapacity.CapacityEndTime,
      WorkCenterCapacity.TotOperatingDurationInSeconds,
      WorkCenterCapacity.OperatingDurationInSeconds,
      WorkCenterCapacity.CapacityNumberOfCapacities,
      WorkCenterCapacity.CapacityPlanUtilizationPercent,
      WorkCenterCapacity.WorkCenterInternalID,
      WorkCenterCapacity.WorkCenter,
      WorkCenterCapacity.WorkCenterCategoryCode,
      WorkCenterCapacity.WorkCenterTypeCode,
      WorkCenterCapacity.Plant,
      WorkCenterCapacity.FactoryCalendar
}
where
  CalendarDate between OperationTImeFrameStartDate and OperationTImeFrameEndDate