P_RRBWrittenOffDynamicItem

@AbapCatalog.sqlViewName: 'PRRBWRTOFFDYNITM'
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED


define view P_RRBWrittenOffDynamicItem as select from I_RRBDynamicItemTotalFlow as DynamicTotalFlow
 
 inner join I_RRBDynamicItem             as DynamicItem             on DynamicTotalFlow.RRBDynamicItem = DynamicItem.RRBDynamicItem
 
 inner join I_RRBSalesPricingDynamicItem as SalesPricingDynamicItem on DynamicTotalFlow.RRBDynamicItem = SalesPricingDynamicItem.RRBDynamicItem

 inner join I_RRBSalesPricingHeader      as RRBSalesPricingHeader   on SalesPricingDynamicItem.RRBSalesPricingDocument = RRBSalesPricingHeader.RRBSalesPricingDocument
                                                                            
left outer join P_RRBWrittenOffDynamicItem01 as JournalEntryItem        on  JournalEntryItem.AccountingDocument  = DynamicItem.AccountingDocument
                                                                              and JournalEntryItem.LedgerGLLineItem    = DynamicItem.LedgerGLLineItem
                                                                              and JournalEntryItem.ControllingObject   = DynamicItem.ControllingObject
                                                                              and JournalEntryItem.TransactionCurrency = DynamicItem.TransactionCurrency
                                                                              and JournalEntryItem.FiscalYear          = DynamicItem.FiscalYear

association [0..1] to I_BillingPlanItemUsageText   as _ItemUsage               on DynamicItem.BillingPlanItemUsage = _ItemUsage.BillingPlanItemUsage
                                                                    and DynamicItem.BillingDocumentCategory = _ItemUsage.BillingPlanUsageCategory
                                                                    and _ItemUsage.Language  = $session.system_language

 
 
 association [0..1] to I_BillingControlCategory as _BillingControlCategory on $projection.BillingControlCategory = _BillingControlCategory.BillingControlCategory

 association [0..1] to I_SalesDocumentItem      as _SalesDocumentItem      on $projection.SalesDocument = _SalesDocumentItem.SalesDocument
                                                                           and $projection.SalesDocumentItem = _SalesDocumentItem.SalesDocumentItem

 //association [0..1] to I_Employment             as _Employment             on  $projection.Personnel = _Employment.EmploymentInternalID

 association [0..1] to I_PersonWorkAgreement_1 as _PersonWorkAgreement_1 on $projection.Personnel = _PersonWorkAgreement_1.PersonWorkAgreement      //changed as per HR Decoupling in CE 2008 - Scope change


{
  key SalesPricingDynamicItem.RRBSalesPricingDocument,
  key DynamicTotalFlow.RRBDynamicItem,                              /* Changed for longtext */

            SalesPricingDynamicItem.SalesDocumentItem,
            SalesPricingDynamicItem.Material,
      
            RRBSalesPricingHeader.SalesDocument,
      
            DynamicItem.BillingDocumentCategory                 as BillingDocumentCategory,
            DynamicItem.BillingPlanItemUsage                    as BillingPlanItemUsage,            
            DynamicItem.ControllingObject                       as ControllingObject,
            DynamicItem.WorkItem                                as WorkItem, 
            DynamicItem.Personnel                               as Personnel,
            DynamicItem.DocumentItemText                        as DocumentItemText,
            DynamicItem.BillingPlan                             as BillingPlan,
            DynamicItem.BillingPlanItem                         as BillingPlanItem,
            DynamicItem.TimeSheetOvertimeCategory,
            
      
       
            _ItemUsage.BillingPlanItemUsageName                 as BillingPlanItemUsageName,
            
            
           
      
      
            //For non-billable DI's

            case
            when DynamicItem.BillingControlCategory is null
              then 'BILLABLE'
            else DynamicItem.BillingControlCategory
            end                                                as BillingControlCategory,
      
      
            case
            when JournalEntryItem.ServicesRenderedDate != '00000000'
            then JournalEntryItem.ServicesRenderedDate
            else
            JournalEntryItem.DocumentDate end                  as PostingDate,

     
            cast( _SalesDocumentItem.SalesDocumentItemText     as ps_s4_arktx preserving type ) as SalesDocumentItemText,         
            
            JournalEntryItem.LedgerGLLineItem            as LedgerGLLineItem,
            JournalEntryItem.ReferenceDocument           as ReferenceDocument,
            JournalEntryItem.ReferenceDocumentItem       as ReferenceDocumentItem,
            JournalEntryItem.FiscalYear                  as FiscalYear,
            JournalEntryItem.CompanyCode                 as CompanyCode,
            JournalEntryItem.AccountingDocument          as AccountingDocument,
      
      
            /*======================= AD01LISF Feilds================================*/
            DynamicTotalFlow.BilledAmountInTransacCrcy  as BilledAmountInTransacCrcy,
            DynamicTotalFlow.RejectedAmtInTransCrcy     as RejectedAmtInTransCrcy,
            DynamicTotalFlow.RejectedQuantity           as RejectedQuantity,
            DynamicTotalFlow.BilledQuantity             as BilledQuantity,
      
      
            /*============= Units ================================*/
                  
            @Semantics.currencyCode: true
            DynamicItem.TransactionCurrency             as TransactionCurrency,
            @Semantics.currencyCode: true
            SalesPricingDynamicItem.DocumentCurrency    as DocumentCurrency,
            @Semantics.unitOfMeasure: true
            DynamicItem.UnitOfMeasure                   as UnitOfMeasure,
      
      
            /*============= Quantities ===========================*/
            @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
            SalesPricingDynamicItem.TotalQuantity       as OpenQuantity,
            @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
            SalesPricingDynamicItem.TotalBillableQtyInBaseUnit as TotalBillableQtyInBaseUnit,
      
      
            /*============= Amounts ==============================*/
            SalesPricingDynamicItem.NetAmount                       as NetAmount,
            SalesPricingDynamicItem.AmountToBeBilledInTransacCrcy   as AmountToBeBilledInTransacCrcy,
            SalesPricingDynamicItem.AmtToBePostponedInTransacCrcy   as AmtToBePostponedInTransacCrcy,
            SalesPricingDynamicItem.AmtToBeRejectedInTransacCrcy    as AmtToBeRejectedInTransacCrcy,
            //SalesPricingDynamicItem.BilledAmountInTransacCrcy     as BilledAmountInTransacCrcy,

            SalesPricingDynamicItem.CanceledAmountInTransacCrcy     as CanceledAmountInTransacCrcy,
            SalesPricingDynamicItem.OriginalAmountInTransacCrcy     as OriginalAmountInTransacCrcy,
            SalesPricingDynamicItem.TotalAmountInTransactionCrcy    as OpenAmountInTransCrcy,          
      
            
            /*============= Associations =========================*/
      
            SalesPricingDynamicItem._Material,
            SalesPricingDynamicItem._DocumentCurrency,
            
            DynamicItem._UnitOfMeasure,
            DynamicItem._TransactionCurrency,
      
           _ItemUsage,
           _SalesDocumentItem,
           _BillingControlCategory,
           //_Employment,

           _PersonWorkAgreement_1,
           DynamicTotalFlow._RRBDynamicItemLongText
      
          
}