P_PurchasingInfoRecMassUpdate

@AbapCatalog.sqlViewName: 'PPURINFRECMASS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Union of General and Org. Data'

@VDM.viewType: #CONSUMPTION
@VDM.private: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@Metadata.ignorePropagatedAnnotations: true

define view P_PurchasingInfoRecMassUpdate

  as select from I_PurchasingInfoRecord
{

  key cast (PurchasingInfoRecord as abap.char(22)) as FormattedInfoRec,

      cast (' ' as abap.char(16))                  as ParentNode,

      PurchasingInfoRecord,

      cast ('0' as abap.char(1))                   as HierarchyNodeLevel,

      //---------------------------------------------------------------------------------

      // General Data

      //---------------------------------------------------------------------------------


      cast (Supplier as vdm_lifnr)                 as Supplier,

      Material,

      SupplierSubrange,

      MaterialGroup,

      case CreationDate
      when (' ') then '00000000'
      else  CreationDate
      end                                          as CreationDate,

      //---------------------------------------------------------------------------------


      IsDeleted,

      PurchasingInfoRecordDesc,

      SupplierMaterialNumber,

      SupplierRespSalesPersonName,

      SupplierPhoneNumber,

      SupplierMaterialGroup,

      PriorSupplier,

      case AvailabilityStartDate
      when (' ') then '00000000'
      else AvailabilityStartDate
      end                                          as AvailabilityStartDate,

      case AvailabilityEndDate
      when (' ') then '00000000'
      else AvailabilityEndDate
      end                                          as AvailabilityEndDate,

      VarblPurOrdUnitIsActive,

      Manufacturer,

      IsRegularSupplier,

      NoDaysReminder1,

      NoDaysReminder2,

      NoDaysReminder3,

      ProductPurchasePointsQty,

      ProductPurchasePointsQtyUnit,

      ReturnAgreement,

      SupplierCertOriginCat,

      SupplierCertOriginNumber,

      case SupplierCertValidityEndDate
      when (' ') then '00000000'
      else SupplierCertValidityEndDate
      end                                          as SupplierCertValidityEndDate,

      SupplierCertOriginCountry,

      SupplierCertOriginRegion,

      SuplrCertOriginClassfctnNumber,

      SupplierSubrangeSortNumber,


      //---------------------------------------------------------------------------------

      // Cast all Organizational Data

      //---------------------------------------------------------------------------------


      cast ('' as ekorg)                           as PurchasingOrganization,

      cast ('' as /sapapo/cif_esokz)               as PurchasingInfoRecordCategory,

      cast ('' as ewerk)                           as Plant,

      cast ('' as bkgrp)                           as PurchasingGroup,

      cast ('' as ekkog)                           as MaterialConditionGroup,

      //---------------------------------------------------------------------------------


      cast ('' as iloee)                           as IsMarkedForDeletion,

      cast ('' as waers)                           as Currency,

      cast ('0' as minbm)                          as MinimumPurchaseOrderQuantity,

      cast ('0' as norbm)                          as StandardPurchaseOrderQuantity,

      cast ('0' as plifz)                          as MaterialPlannedDeliveryDurn,

      cast ('0' as uebto)                          as OverdelivTolrtdLmtRatioInPct,

      cast ('0' as untto)                          as UnderdelivTolrtdLmtRatioInPct,

      cast ('' as uebtk)                           as UnlimitedOverdeliveryIsAllowed,

      cast ('0' as iprei)                          as NetPriceAmount,

      cast ('0' as epein)                          as MaterialPriceUnitQty,

      cast ('' as bbprm)                           as PurchaseOrderPriceUnit,

      cast ('00000000' as prgbi)                   as PriceValidityEndDate,

      cast ('' as webre)                           as InvoiceIsGoodsReceiptBased,

      cast ('' as mwskz)                           as TaxCode,

      cast ('' as inco1)                           as IncotermsClassification,

      cast ('' as inco2)                           as IncotermsTransferLocation,

      cast ('' as inco2_l)                         as IncotermsLocation1,

      cast ('' as inco3_l)                         as IncotermsLocation2,

      cast ('0' as maxbm)                          as MaximumOrderQuantity,

      cast ('' as aut_source)                      as IsRelevantForAutomSrcg,

      cast ('' as incov)                           as IncotermsVersion,

      cast ('0' as mhdrz)                          as MinRemainingShelfLife,

      cast ('' as evers)                           as ShippingInstruction,

      cast ('' as xersn)                           as IsEvaluatedRcptSettlmtAllowed,

      cast ('' as /spe/cre_ref_doc)                as IsPurOrderAllwdForInbDeliv,

      cast ('' as kzabs)                           as IsOrderAcknRqd,

      cast ('' as bstae)                           as SupplierConfirmationControlKey,

      cast ('' as rdprf)                           as MaterialRoundingProfile,

      cast ('0' as wrf_pscd_mst)                   as MaterialStagingTime,

      cast ('' as megru)                           as ProductUnitGroup,

      cast ('' as msr_vrma_req_eine)               as IsRetMatlAuthznRqdBySupplier,

      cast ('' as esktof )                         as IsCashDiscountGranted,

      cast ('' as meprf)                           as PricingDateControl,

      //cast ('' as dattp)                           as ShelfLifeExpirationDatePeriod,


      @DefaultAggregation: #SUM
      cast(0 as abap.int4 )                        as NumberOfItems,


      //---------------------------------------------------------------------------------

      // Text Fields

      //---------------------------------------------------------------------------------


      _Supplier.SupplierName,

      _Material._Text[1: Language = $session.system_language].MaterialName,

      cast ('' as mm_a_purg_grp_name)              as PurchasingGroupName,

      cast ('' as werks_name)                      as PlantName,

      _MaterialGroup._Text[1: Language = $session.system_language].MaterialGroupName,

      cast ('' as mm_a_purg_org_name)              as PurchasingOrganizationName

}

where

  IsDeleted = ''



union select from I_PurgInfoRecordWithOrgData

{
      //---------------------------------------------------------------------------------

      // Key Fields and Filter Fields

      //---------------------------------------------------------------------------------


  key cast (concat(concat(concat(concat(concat(concat(PurchasingInfoRecord, '/'),
            PurchasingOrganization),'/'),
            PurchasingInfoRecordCategory),'/'),
            Plant)
            as abap.char(22))                                     as FormattedInfoRec,

      PurchasingInfoRecord                                        as ParentNode,

      PurchasingInfoRecord,

      cast ('1' as abap.char(1))                                  as HierarchyNodeLevel,

      //---------------------------------------------------------------------------------

      // Cast all General Data

      //---------------------------------------------------------------------------------


      Supplier,

      Material,

      SupplierSubrange,

      MaterialGroup,

      CreationDate,

      //---------------------------------------------------------------------------------


      cast ('' as iloea)                                          as IsDeleted,

      PurchasingInfoRecordDesc,

      cast ('' as idnlf)                                          as SupplierMaterialNumber,

      cast ('' as verkf)                                          as SupplierRespSalesPersonName,

      cast ('' as telf0)                                          as SupplierPhoneNumber,

      cast ('' as wglif)                                          as SupplierMaterialGroup,

      PriorSupplier,

      cast ('00000000' as lifab)                                  as AvailabilityStartDate,

      cast ('00000000' as lifbi)                                  as AvailabilityEndDate,

      VarblPurOrdUnitIsActive,

      Manufacturer,

      cast ('' as relif)                                          as IsRegularSupplier,

      cast ('0' as mahn1)                                         as NoDaysReminder1,

      cast ('0' as mahn2)                                         as NoDaysReminder2,

      cast ('0' as mahn3)                                         as NoDaysReminder3,

      cast ('0' as anzpu)                                         as ProductPurchasePointsQty,

      cast ('' as punei)                                          as ProductPurchasePointsQtyUnit,

      ReturnAgreement,

      cast ('' as urztp)                                          as SupplierCertOriginCat,

      cast ('' as urznr)                                          as SupplierCertOriginNumber,

      cast ('00000000' as urzdt)                                  as SupplierCertValidityEndDate,

      cast ('' as uland)                                          as SupplierCertOriginCountry,

      cast ('' as regio)                                          as SupplierCertOriginRegion,

      cast ('' as urzzt)                                          as SuplrCertOriginClassfctnNumber,

      cast ('00000' as urznr)                                     as SupplierSubrangeSortNumber,


      //---------------------------------------------------------------------------------

      // Organizational Data

      //---------------------------------------------------------------------------------


      PurchasingOrganization,

      cast (PurchasingInfoRecordCategory as /sapapo/cif_esokz )   as PurchasingInfoRecordCategory,

      Plant,

      PurchasingGroup,

      MaterialConditionGroup,

      //---------------------------------------------------------------------------------


      IsMarkedForDeletion,

      Currency,

      MinimumPurchaseOrderQuantity,

      StandardPurchaseOrderQuantity,

      MaterialPlannedDeliveryDurn,

      OverdelivTolrtdLmtRatioInPct,

      UnderdelivTolrtdLmtRatioInPct,

      UnlimitedOverdeliveryIsAllowed,

      NetPriceAmount,

      MaterialPriceUnitQty,

      PurchaseOrderPriceUnit,

      case PriceValidityEndDate
      when (' ') then '00000000'
      else PriceValidityEndDate
      end                                                         as PriceValidityEndDate,

      InvoiceIsGoodsReceiptBased,

      TaxCode,

      IncotermsClassification,

      IncotermsTransferLocation,

      IncotermsLocation1,

      IncotermsLocation2,

      MaximumOrderQuantity,

      IsRelevantForAutomSrcg,

      IncotermsVersion,

      MinRemainingShelfLife,

      ShippingInstruction,

      IsEvaluatedRcptSettlmtAllowed,

      IsPurOrderAllwdForInbDeliv,

      IsOrderAcknRqd,

      SupplierConfirmationControlKey,

      MaterialRoundingProfile,

      MaterialStagingTime,

      ProductUnitGroup,

      IsRetMatlAuthznRqdBySupplier,

      IsCashDiscountGranted,

      PricingDateControl,

      //ShelfLifeExpirationDatePeriod,


      @DefaultAggregation: #SUM
      cast(0 as abap.int4 )                                       as NumberOfItems,


      //---------------------------------------------------------------------------------

      // Text Fields

      //---------------------------------------------------------------------------------


      cast ('' as md_supplier_name)                               as SupplierName,

      cast ('' as maktx)                                          as MaterialName,

      _PurchasingGroup.PurchasingGroupName,

      _Plant.PlantName,

      cast ('' as wgbez)                                          as MaterialGroupName,

      _PurchasingOrganization.PurchasingOrganizationName

}

where

      IsMarkedForDeletion = ''
  and IsDeleted           = ''