P_PurchaseContractWithDraft

@AbapCatalog.sqlViewName: 'PPURCHASECTRWD'
@VDM.private: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientDependent: true

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
define view P_PurchaseContractWithDraft
  as select from    I_PurchaseContract as ActiveDocument
    left outer join purchasectr_d      as DraftDocument on DraftDocument.activepurchasecontract = ActiveDocument.PurchaseContract

{
  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x preserving type ) as PurchaseContractDraftUUID,
  key ActiveDocument.PurchaseContract                                                    as ActivePurchaseContract,
      ActiveDocument.PurchaseContract,
      ActiveDocument.PurchaseContractType,
      ActiveDocument.PurchasingDocumentCategory,
      ActiveDocument.CreationDate,
      ActiveDocument.Supplier,
      ActiveDocument.CompanyCode,
      ActiveDocument.PurchasingOrganization,
      ActiveDocument.PurchasingGroup,
      ActiveDocument.DocumentCurrency,
      ActiveDocument.IncotermsClassification,
      ActiveDocument.IncotermsTransferLocation,
      ActiveDocument.PaymentTerms,
      ActiveDocument.CashDiscount1Days,
      ActiveDocument.CashDiscount2Days,
      ActiveDocument.NetPaymentDays,
      ActiveDocument.CashDiscount1Percent,
      ActiveDocument.CashDiscount2Percent,
      ActiveDocument.PurchaseContractTargetAmount,
      ActiveDocument.ValidityStartDate,
      ActiveDocument.ValidityEndDate,
      ActiveDocument.ReleaseCode,
      ActiveDocument.CreatedByUser,
      ActiveDocument.PurchasingDocumentDeletionCode,
      ActiveDocument.SupplierAddressID,
      ActiveDocument.SupplyingSupplier,
      ActiveDocument.InvoicingParty,
 //     ActiveDocument.SupplierName,

      ActiveDocument.ExchangeRate,
      ActiveDocument.ExchangeRateIsFixed,
      ActiveDocument.QuotationSubmissionDate,
      ActiveDocument.SupplierQuotation,
      ActiveDocument.ReleaseIsNotCompleted,
      ActiveDocument.CorrespncExternalReference,
      ActiveDocument.CorrespncInternalReference,
      ActiveDocument.SupplierRespSalesPersonName,
      ActiveDocument.SupplierPhoneNumber,
      ActiveDocument.IncotermsVersion,
      ActiveDocument.IncotermsLocation1,
      ActiveDocument.IncotermsLocation2,
      ActiveDocument.PurchasingDocumentName,
      DraftDocument.purchasecontractdraftuuid                                            as DraftAdministrativeDataUUID,
      DraftDocument.ctrtmplrefguid as ChangeRecordReferenceUUID,
      cast( 'X' as sdraft_is_active preserving type )                                    as IsActiveEntity,
      cast( ' ' as sdraft_has_active preserving type )                                   as HasActiveEntity,      
      cast(
      case
      when DraftDocument.purchasecontractdraftuuid is null then ' '
      else 'X'
      end  as sdraft_has_draft preserving type )                                         as HasDraftEntity,
      cast( ' ' as mm_oa_template_flag)                                 as IsPurContrTemplate
}
union all select from purchasectr_d             as DraftDocument
  inner join          I_DraftAdministrativeData as I_DraftAdministrativeData on I_DraftAdministrativeData.DraftUUID = DraftDocument.purchasecontractdraftuuid

{
  key DraftDocument.purchasecontractdraftuuid,
  key DraftDocument.activepurchasecontract,
      DraftDocument.purchasecontract,
      DraftDocument.purchasecontracttype,
      DraftDocument.purchasingdocumentcategory,
      DraftDocument.creationdate,
      DraftDocument.supplier,
      DraftDocument.companycode,
      DraftDocument.purchasingorganization,
      DraftDocument.purchasinggroup,
      DraftDocument.documentcurrency,
      DraftDocument.incotermsclassification,
      DraftDocument.incotermstransferlocation,
      DraftDocument.paymentterms,
      DraftDocument.cashdiscount1days,
      DraftDocument.cashdiscount2days,
      DraftDocument.netpaymentdays,
      DraftDocument.cashdiscount1percent,
      DraftDocument.cashdiscount2percent,
      DraftDocument.purchasecontracttargetamount,
      DraftDocument.validitystartdate,
      DraftDocument.validityenddate,
      DraftDocument.releasecode,
      DraftDocument.createdbyuser,
      DraftDocument.purchasingdocumentdeletioncode,
      DraftDocument.supplieraddressid,
      DraftDocument.supplyingsupplier,
      DraftDocument.invoicingparty,
 //     DraftDocument.suppliername,

      DraftDocument.exchangerate,
      DraftDocument.exchangerateisfixed,
      DraftDocument.quotationsubmissiondate,
      DraftDocument.supplierquotation,
      DraftDocument.releaseisnotcompleted,
      DraftDocument.correspncexternalreference,
      DraftDocument.correspncinternalreference,
      DraftDocument.supplierrespsalespersonname,
      DraftDocument.supplierphonenumber,
      DraftDocument.incotermsversion,
      DraftDocument.incotermslocation1,
      DraftDocument.incotermslocation2,
      DraftDocument.purchasingdocumentname,
      DraftDocument.purchasecontractdraftuuid          as DraftAdministrativeDataUUID,
      DraftDocument.ctrtmplrefguid as ChangeRecordReferenceUUID,
      cast( ' '  as sdraft_is_active preserving type ) as IsActiveEntity,
      DraftDocument.hasactiveentity,
      cast( ' '  as sdraft_has_draft preserving type ) as HasDraftEntity,
      DraftDocument.ispurcontrtemplate
}
where
     ((((I_DraftAdministrativeData.CreatedByUser   = $session.user
  or I_DraftAdministrativeData.InProcessByUser = $session.user) and DraftDocument.ispurcontrtemplate = '' ) 
  or DraftDocument.ispurcontrtemplate = 'X'  ) 
  )
  //and DraftDocument.ctrtmplrefguid = hextobin('00000000000000000000000000000000'))