P_ProjBillgCustomerProjectDets

DDL: P_PROJBILLGCUSTOMERPROJECTDETS Type: view_entity COMPOSITE

P_ProjBillgCustomerProjectDets is a Composite CDS View in SAP S/4HANA. It reads from 1 data source (I_EnterpriseProject) and exposes 27 fields with key field ProjectUUID. It has 4 associations to related views.

1 data source(s) 27 fields

Data Sources (1)

SourceAliasJoin Type
I_EnterpriseProject EnterpriseProject from

Associations (4)

CardinalityTargetAliasCondition
[0..1] I_EngagementProjectSrvcOrgText _ServiceOrganizationText _ServiceOrganizationText.EngagementProjectServiceOrg = $projection.EnterpriseProjectServiceOrg and _ServiceOrganizationText.Language = $session.system_language
[1..1] I_CustomerToBusinessPartner _CustomerToBusinessPartner _CustomerToBusinessPartner.BusinessPartnerUUID = $projection.CustomerUUID
[0..1] I_CostCenter _ResponsibleCostCenter $projection.ControllingArea = _ResponsibleCostCenter.ControllingArea and $projection.ResponsibleCostCenter = _ResponsibleCostCenter.CostCenter and $projection.ProjectStartDate <= _ResponsibleCostCenter.ValidityEndDate and $projection.ProjectStartDate >= _ResponsibleCostCenter.ValidityStartDate
[0..1] I_ProfitCenter _ProfitCenter $projection.ProfitCenter = _ProfitCenter.ProfitCenter and $projection.ControllingArea = _ProfitCenter.ControllingArea and $projection.ProjectStartDate <= _ProfitCenter.ValidityEndDate and $projection.ProjectStartDate >= _ProfitCenter.ValidityStartDate

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
VDM.private true view
VDM.viewType #COMPOSITE view

Fields (27)

KeyFieldSource TableSource FieldDescription
KEY ProjectUUID ProjectUUID
ProjectInternalID ProjectInternalID
Project Project
ProjectDescription ProjectDescription
ProjectStartDate ProjectStartDate
ProjectEndDate ProjectEndDate
CustomerUUID CustomerUUID
StoreCustomerName Customer
ResponsibleCostCenter ResponsibleCostCenter
CostCenterName Cost Center
ControllingArea ControllingArea
ProfitCenter ProfitCenter
ProfitCenterName Profit Center
ProfitCenterName
EnterpriseProjectServiceOrg EnterpriseProjectServiceOrg
EngmtProjectServiceOrgName _ServiceOrganizationText EngmtProjectServiceOrgName Service Organization
ProcessingStatus ProcessingStatus
CompanyCode CompanyCode
ProjectProfileCode ProjectProfileCode
ProjectCategory ProjectCategory
EntProjectIsConfidential EntProjectIsConfidential
ProjectSummaryTaskUUID ProjectSummaryTaskUUID
_AuthGroup _AuthGroup
_AuthRole _AuthRole
_AuthSubst _AuthSubst
_AuthUser _AuthUser
_ProfitCenter _ProfitCenter 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.private:true
@VDM.viewType: #COMPOSITE
define view entity P_ProjBillgCustomerProjectDets
  as select from I_EnterpriseProject as EnterpriseProject

  association [0..1] to I_EngagementProjectSrvcOrgText as _ServiceOrganizationText   on  _ServiceOrganizationText.EngagementProjectServiceOrg = $projection.EnterpriseProjectServiceOrg
                                                                                     and _ServiceOrganizationText.Language                    = $session.system_language

  association [1..1] to I_CustomerToBusinessPartner    as _CustomerToBusinessPartner on  _CustomerToBusinessPartner.BusinessPartnerUUID = $projection.CustomerUUID

  association [0..1] to I_CostCenter                   as _ResponsibleCostCenter     on  $projection.ControllingArea       =  _ResponsibleCostCenter.ControllingArea
                                                                                     and $projection.ResponsibleCostCenter =  _ResponsibleCostCenter.CostCenter
                                                                                     and $projection.ProjectStartDate      <= _ResponsibleCostCenter.ValidityEndDate
                                                                                     and $projection.ProjectStartDate      >= _ResponsibleCostCenter.ValidityStartDate
  association [0..1] to I_ProfitCenter                 as _ProfitCenter              on  $projection.ProfitCenter     =  _ProfitCenter.ProfitCenter
                                                                                     and $projection.ControllingArea  =  _ProfitCenter.ControllingArea
                                                                                     and $projection.ProjectStartDate <= _ProfitCenter.ValidityEndDate
                                                                                     and $projection.ProjectStartDate >= _ProfitCenter.ValidityStartDate

{

  key ProjectUUID,
      ProjectInternalID,
      Project,
      ProjectDescription,
      ProjectStartDate,
      ProjectEndDate,
      
      
      CustomerUUID,
      @Semantics.name.fullName: true
      @Semantics.text: true
      @EndUserText.label: 'Customer'
      _CustomerToBusinessPartner._Customer.CustomerName   as StoreCustomerName,


      ResponsibleCostCenter,
      @Semantics.text: true
      @EndUserText.label: 'Cost Center'
      _ResponsibleCostCenter._Text[1:Language = $session.system_language].CostCenterName,

      ControllingArea,

      ProfitCenter,
      @Semantics.text: true
      @EndUserText.label: 'Profit Center'
      --_ProfitCenterText.ProfitCenterName,
      _ProfitCenter._Text[1:Language = $session.system_language].ProfitCenterName,

      EnterpriseProjectServiceOrg,
      @Semantics.text: true
      @EndUserText.label: 'Service Organization'
      _ServiceOrganizationText.EngmtProjectServiceOrgName as EngmtProjectServiceOrgName,


      ProcessingStatus,
      CompanyCode,
      ProjectProfileCode,
      ProjectCategory,
      EntProjectIsConfidential,

      ProjectSummaryTaskUUID,
      _AuthGroup,
      _AuthRole,
      _AuthSubst,
      _AuthUser,
      _ProfitCenter
}
where
  ProjectCategory = '7'

Learn More