P_ProdnModCompDgtlMockUpCharcs

DDL: P_PRODNMODCOMPDGTLMOCKUPCHARCS Type: view_entity COMPOSITE

Prodn Model: Charac values from DMU

P_ProdnModCompDgtlMockUpCharcs is a Composite CDS View that provides data about "Prodn Model: Charac values from DMU" in SAP S/4HANA. It reads from 1 data source (I_DigitalMockUpCharcs) and exposes 4 fields with key field DgtlMockUpUUID.

1 data source(s) 4 fields

Data Sources (1)

SourceAliasJoin Type
I_DigitalMockUpCharcs TransfMatrixGuid inner

Annotations (8)

NameValueLevelField
VDM.private true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Prodn Model: Charac values from DMU view
VDM.viewType #COMPOSITE view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY DgtlMockUpUUID DigitalMockUp DgtlMockUpUUID
DgtlMockUpCharcsUUID I_DigitalMockUpCharcs DgtlMockUpCharcsUUID
DgtlMockUpInstceCount DigitalMockUp DgtlMockUpInstceCount
DgtlMockUpTrnsfmtnMatrixCount DigitalMockUp DgtlMockUpTrnsfmtnMatrixCount 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Prodn Model: Charac values from DMU'
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #X,
    sizeCategory: #S,
    dataClass: #MIXED
}
define view entity P_ProdnModCompDgtlMockUpCharcs
  as select distinct from I_DigitalMockUp       as DigitalMockUp
    inner join            I_DigitalMockUpCharcs as TransfMatrixGuid on TransfMatrixGuid.DgtlMockUpCharcsUUID = DigitalMockUp.DgtlMockUpCharcsUUID
{
  key  DigitalMockUp.DgtlMockUpUUID,
       TransfMatrixGuid.DgtlMockUpCharcsUUID as DgtlMockUpCharcsUUID,
       DigitalMockUp.DgtlMockUpInstceCount,
       DigitalMockUp.DgtlMockUpTrnsfmtnMatrixCount,
       max( case
       when TransfMatrixGuid.DgtlMockUpCharcsName     = 'ORIGINAL_TMXGUID' and TransfMatrixGuid.DgtlMockUpCharcsCategory = 'VEInstanceIdentifier'
       then TransfMatrixGuid.DgtlMockUpCharcsValue
       end )                                 as DgtlMockUpCharcsValue,

       max( case
       when TransfMatrixGuid.DgtlMockUpCharcsName     = 'VE_INSTANCE' and TransfMatrixGuid.DgtlMockUpCharcsCategory = 'VEInstanceIdentifier'
       then TransfMatrixGuid.DgtlMockUpCharcsValue
       end )                                 as DgtlMockUpCharcsVislEntInstce,

       max( case
       when TransfMatrixGuid.DgtlMockUpCharcsName     = 'ID' and TransfMatrixGuid.DgtlMockUpCharcsCategory = 'CADInstanceId'
       then TransfMatrixGuid.DgtlMockUpCharcsValue
       end )                                 as DgtlMockUpCharcsCADInstce,

       max( case
       when TransfMatrixGuid.DgtlMockUpCharcsName     = 'REF_DESIGNATOR' and TransfMatrixGuid.DgtlMockUpCharcsCategory = 'SAP'
       then TransfMatrixGuid.DgtlMockUpCharcsValue
       end )                                 as ReferenceDesignatorValue


}
group by
  DigitalMockUp.DgtlMockUpUUID,
  TransfMatrixGuid.DgtlMockUpCharcsUUID,
  DigitalMockUp.DgtlMockUpInstceCount,
  DigitalMockUp.DgtlMockUpTrnsfmtnMatrixCount

Learn More