P_PrepaymentCMMContractAmount

@AbapCatalog.sqlViewName: 'PPMGCTRCMMAMT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm                   : #SESSION_VARIABLE
@VDM.private                                : true
@VDM.viewType                               : #COMPOSITE
@ObjectModel.usageType.sizeCategory         : #L
@ObjectModel.usageType.serviceQuality       : #C
@ObjectModel.usageType.dataClass            : #TRANSACTIONAL
@EndUserText.label: 'Prepayment Contract CMM Amount'
define view P_PrepaymentCMMContractAmount
  -- Valid Doc Types
  as select from I_PrepayWrkCtrAllowedDocTypes as DocTypes
  -- Document Header
    inner join   I_PreAgrmtTradingContract     as Document     on Document.TradingContractType = DocTypes.PrepaymentAgrmtRefDocumentType
  -- Trading Contract Status
    inner join   I_PreAgrmtTradingContractStat as ContractApplicationStatus on ContractApplicationStatus.ContractApplicationStatus = Document.TrdgContrApplicationStatus
  -- Document Item
    inner join   I_PreAgrmtTradingContractItem as DocumentItem on DocumentItem.TradingContract = Document.TradingContract
  -- Material and Commodity
    inner join   I_PrepaymentMaterial          as Material     on DocumentItem.Material = Material.Material
  -- CMM Price
  association [0..1] to P_PrepayDocVersLogPrcgValTC as CMMPrice on  CMMPrice.PrepaymentAgrmtRefBusObject  = 'BUS2124'
                                                                and CMMPrice.PrepaymentDocumentNumber     = Document.TradingContract
                                                                and CMMPrice.PrepaymentDocumentItemNumber = DocumentItem.TradingContractItem
                                                                and Material.Commodity                    is not initial

{
  key DocTypes.PrepaymentAgrmtWorkCenterType                 as PrepaymentAgrmtWorkCenterType,
  key DocTypes.PrepaymentAgrmtRefDocumentCat                 as PrepaymentAgrmtRefDocumentCat,
  key cast( 'BUS2124' as ppmgac_e_link_bus )                 as PrepaymentAgrmtRefBusObject,
  key Document.TradingContract                               as DocNumber,
  key DocumentItem.TradingContractItem                       as DocumentItemNumber,
      cast('00000' as abap.numc(5))                          as PurchasingDocumentItem,
      lpad( Document.TradingContract, 25, '0' )              as PrepaymentAgrmtRefDocument,
      Document.CompanyCode                                   as CompanyCode,
      Document.TradingContractType                           as DocumentType,
      @Semantics.amount.currencyCode: 'PrepaymentTotalAmtCrcy'
      cast( CMMPrice.PrepaymentTotalAmt as abap.curr(23,2) ) as PrepaymentTotalAmt,
      @Semantics.currencyCode: true
      DocumentItem.TrdgContrTotalNetAmountCrcy               as PrepaymentTotalAmtCrcy,
      case when  CMMPrice.PrepaymentDocCmmdtyMarketQty is initial and Material.Commodity is not initial
           then 'X' else '' end                              as PrepaymentTotalAmtIsFixedPrice,
      CMMPrice.PrepaymentWrkCtrDocPricingOptn,
      Document.Counterparty,
      Document.TrdgContrApplicationStatus,
      DocumentItem.PrepaymentRefDocItmValdFromDte,
      DocumentItem.PrepaymentRefDocItmValdToDte,
      DocumentItem.Material,
      Material.Commodity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      DocumentItem.TradingContractItemQuantity               as OrderQuantity,
      @Semantics.unitOfMeasure: true
      DocumentItem.TrdgContractItemUnitOfMeasure             as OrderQuantityUnit

}
where
      DocTypes.PrepaymentAgrmtRefDocumentCat = 'TC'
  and DocTypes.PrepaymentAgrmtWorkCenterType = '1'