P_PSDOC_CHANGE

@AbapCatalog.sqlViewName: 'PWBRKPSDOCCHG'
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
// Changeable Personnel Settlement Documents

define view P_PSDOC_CHANGE
  as select from wbrk

  association [0..1] to P_WLF_CDS_PERNR_BEGRU as _PernrBegru on $projection.PersonWorkAgreement = _PernrBegru.Pernr

{
  key cast( wbrk.wbeln as wlf_pers_settlmt_doc preserving type )                                      as PersonnelSettlementDocument,
      wbrk.lfart                                                                                      as SettlmtDocType,
      cast( wbrk.bukrs as fis_bukrs preserving type )                                                 as CompanyCode,
      wbrk.vkorg                                                                                      as SalesOrganization,
      wbrk.vtweg                                                                                      as DistributionChannel,
      wbrk.spart                                                                                      as Division,
      wbrk.pers_kostl                                                                                 as PersonnelCostCenter,
      wbrk.rfbsk                                                                                      as PersSettlmtAcctgTransfSts,
      wbrk.wfdat                                                                                      as PostingDate,
      cast( wbrk.lfgru as wlf_wfgru_header preserving type )                                          as SettlmtDocActivityReason,
      cast( wbrk.kidno as farp_kidno preserving type )                                                as PaymentReference,
      wbrk.zuonr                                                                                      as AssignmentReference,
      cast( cast( concat( '0', wbrk.monat) as abap.numc( 3 ) ) as fins_fiscalperiod preserving type ) as FiscalPeriod,
      wbrk.estatus                                                                                    as SettlmtApplSts,
      wbrk.status_group                                                                               as SettlmtApplStsGrp,
      wbrk.pernr                                                                                      as PersonWorkAgreement,
      cast (case
             when _PernrBegru.pernr_begru is null
               then ''
               else _PernrBegru.pernr_begru
             end as bu_augrp )                                                                        as AuthorizationGroup
}
where
      wdtyp       = 'B'
  and settl_party = '4'