P_PL_SAFTVATHeader

@AbapCatalog.sqlViewName: 'PPLSAFTVATHDR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@VDM.private: true
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #P
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_PL_SAFTVATHeader
  with parameters
    P_StartDate : datum,
    P_EndDate   : datum
  as select from           I_CompanyCode  as Company
    left outer to one join snc_pl_bc      as Settings     on  Settings.bukrs = Company.CompanyCode
                                                          and Settings.endda >= $parameters.P_StartDate
                                                          and Settings.begda <= $parameters.P_EndDate

{

  key Company.CompanyCode,
      concat_with_space( concat_with_space( concat_with_space(
        Company._Address.BusinessPartnerName1,
        Company._Address.BusinessPartnerName2, 1),
        Company._Address.BusinessPartnerName3, 1),
        Company._Address.BusinessPartnerName4, 1)          as CompanyName,

      concat_with_space(concat_with_space(concat_with_space(
        Company._Address.CityName,
        Company._Address.PostalCode, 1),
        Company._Address.StreetName, 1),
        Company._Address.HouseNumber, 1)                   as CompanyCodeAddress,

      Company._Address.PhoneNumber                         as PhoneNumber,

      replace(Company.VATRegistration, Company.Country,'') as CompanyVATRegistration,

      cast(Settings.file_email as abap.sstring(241))       as EmailAddress,

      Settings.tax_office                                  as LocalTaxOffice,
      
      Company.Currency                                     as CompanyCodeCurrency,
      
      Company.Country                                      as Country,
      
      
      
      _Currency
}