P_OverdueMaintenanceOrderC

@VDM.private: true
@VDM.viewType: #COMPOSITE

@AbapCatalog.sqlViewName: 'POVDMAINTORDC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}

define view P_OverdueMaintenanceOrderC
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    P_Date : sydate
  as select from I_MaintenanceOrder
{
  key MaintenanceOrder,
      MaintenanceOrderInternalID,
      MaintenanceProcessingPhase,

      MaintenanceOrderDesc,

      MaintenancePlannerGroup,

      MaintenanceRevision,

      MaintenancePlant,

      MaintenancePlanningPlant,

      @ObjectModel.text.element:  [ 'MaintenanceOrderTypeName' ]
      MaintenanceOrderType,
      _MaintenanceOrderType._Text[1: Language = $session.system_language ].OrderTypeName                        as MaintenanceOrderTypeName,

      @ObjectModel.text.element:  [ 'MaintPriorityDesc' ]
      MaintPriority,
      _MaintenancePriority._Text[1: Language = $session.system_language ].MaintPriorityDesc,
      
      _MaintenancePriority.MaintPriorityColorCode, 

      @ObjectModel.text.element: [ 'MaintenanceActivityTypeName' ]
      MaintenanceActivityType,
      _MaintenanceActivityType._Text[1: Language = $session.system_language ].MaintenanceActivityTypeName,

      @ObjectModel.text.element: [ 'MaintenanceWorkCenterText' ]
      _LocationAccountAssignment._WorkCenter.WorkCenter                                                         as MaintenanceWorkCenter,
      _LocationAccountAssignment._WorkCenter.Plant                                                              as MaintenanceWorkCenterPlant,
      _LocationAccountAssignment._WorkCenter._Text[1: Language = $session.system_language ].WorkCenterText      as MaintenanceWorkCenterText,

      @ObjectModel.text.element: [ 'MainWorkCenterText' ]
      _MainWorkCenter.WorkCenter                                                                                as MainWorkCenter,
      _MainWorkCenter._Text[1: Language = $session.system_language ].WorkCenterText                             as MainWorkCenterText,
      _MainWorkCenter.Plant                                                                                     as MainWorkCenterPlant,

      MaintOrdBasicEndDate                                                                                      as ReferenceDate,

      --No UoM because it will always be "days" (overwritten via UI annotation)
      --@Semantics.quantity.unitOfMeasure: 'UnitForDaysOverdue'
      dats_days_between(MaintOrdBasicEndDate, :P_Date)                                                          as OverdueDays,
      
      -- For DCL:
      Equipment,
      MaintObjectLocAcctAssgmtNmbr,
      ResponsibleCostCenter,
      ControllingArea,

      _StatusObjectStatus,

      -- For DCL:
      _Equipment,
      _LocationAccountAssignment,
      _Order
}