P_OrderItemStatusBasic

@AbapCatalog.sqlViewName: 'PORDITEMSTSBASIC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE   // technically a BASIC but due to view layering a COMPOSITE)

@VDM.private: true
// provides the non-aggregated status

// to be used in aggregation views such as P_OrderItemStatusAggr only


/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ]  } */
define view P_OrderItemStatusBasic
  as select from I_StatusObjectStatusBasic as jest

{
    // Key

key jest.StatusObject as ObjectInternalID,

    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0001' then 'X'
      else ''
    end as OrderItemIsCreated,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0002' then 'X'
      else ''
    end as OrderItemIsReleased,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0028' then 'X'
      else ''
    end as SettlementRuleIsCreated,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0046' then 'X'
      else ''
    end as OrderItemIsClosed,
    @Semantics.booleanIndicator: true 
    case jest.StatusCode
      when 'I0074' then 'X'
      else ''
    end as OrderItemIsPartiallyDelivered,

    // Associations

    _StatusObject
}
where
  (     jest.StatusCode       = 'I0001'
    or  jest.StatusCode       = 'I0002'
    or  jest.StatusCode       = 'I0028'
    or  jest.StatusCode       = 'I0046'
    or  jest.StatusCode       = 'I0074'
  ) and jest.StatusIsInactive = ' ' 
    and jest.StatusObject like 'OP%';