P_OpActyComponentAssignmentDMU

@AbapCatalog.sqlViewName: 'PMPECOMPDMUA'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_OpActyComponentAssignmentDMU
  as select from           I_OpActyComponentAssignment  as comp
    inner join             I_MfgOrderOperationComponent as resb on  comp.Reservation     = resb.Reservation
                                                                and comp.ReservationItem = resb.ReservationItem
                                                                and comp.RecordType      = resb.RecordType
    left outer to one join I_BillOfMaterialItemBasic    as stpo on  resb.BillOfMaterialCategory     = stpo.BillOfMaterialCategory
                                                                and resb.BillOfMaterialInternalID   = stpo.BillOfMaterial
                                                                and resb.BOMItem                    = stpo.BillOfMaterialItemNodeNumber
                                                                and resb.BOMItemInternalChangeCount = stpo.BOMItemInternalChangeCount
{
  key comp.OpActyNtwkInstance             as  OpActyNtwkInstance,
  key comp.OpActyNtwkElement              as  OpActyNtwkElement,
  key comp.Reservation                    as  Reservation,
  key comp.ReservationItem                as  ReservationItem,
  key comp.RecordType                     as  RecordType,
      resb.Material                       as  MaterialComponent,
      resb.Plant                          as  ProductionPlant,
      resb.StorageLocation                as  StorageLocation,
      comp.MfgOrderComponentUsageQuantity as  MfgOrderComponentUsageQuantity,
      comp.MfgOrderComponentUsageNetQty   as  MfgOrderComponentUsageNetQty,
      comp.AssemblySequenceNumber         as  AssemblySequenceNumber,
      resb.MatlCompIsMarkedForBackflush   as  MatlCompIsMarkedForBackflush,
      stpo.BillOfMaterialItemUUID         as  BillOfMaterialItemUUID,

      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _ReservationHeader,
      _Material,
      --    _MaterialPlant,
      _Plant,
      _StorageLocation

}