P_MatlStkAtKeyDateInAltUoM1

@AbapCatalog: {
                sqlViewName: 'PMATSTKDATEAUOM1',
                compiler.compareFilter: true,
                preserveKey: true
              }
@ObjectModel: {
                usageType: {
                              sizeCategory: #XXL,
                              serviceQuality: #D,
                              dataClass:#TRANSACTIONAL
                            }
               }
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
         viewType: #COMPOSITE,
         private: true
       }

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */

define view P_MatlStkAtKeyDateInAltUoM1 with parameters
    P_KeyDate : vdm_v_key_date    
  as select from I_MaterialStock_2
{
      // Stock Identifier

  key Material,
  key Plant,
  key StorageLocation,
  key Batch,
  key Supplier,
  key SDDocument,
  key SDDocumentItem,
  key cast( WBSElementInternalID as mat_pspnr preserving type ) as WBSElementInternalID,   --I_MaterailStock_2 does a cast to a DE w/o conversion exit, for compatibility reason: cast back
  key Customer,
  key SpecialStockIdfgStockOwner,
  key InventoryStockType,
  key InventorySpecialStockType,
      // Units

  @Semantics.unitOfMeasure: true
  key MaterialBaseUnit,
      CompanyCode,
      FiscalYearVariant,

      // Quantities

      sum(MatlWrhsStkQtyInMatlBaseUnit) as MatlWrhsStkQtyInMatlBaseUnit,
      sum(MatlCnsmpnQtyInMatlBaseUnit) as  MatlCnsmpnQtyInMatlBaseUnit,
      sum(MatlStkIncrQtyInMatlBaseUnit) as MatlStkIncrQtyInMatlBaseUnit,
      sum(MatlStkDecrQtyInMatlBaseUnit) as MatlStkDecrQtyInMatlBaseUnit
}
where   MatlDocLatestPostgDate <= $parameters.P_KeyDate
group by Material, Plant, StorageLocation, Batch, Supplier, SDDocument, SDDocumentItem, WBSElementInternalID, Customer,
SpecialStockIdfgStockOwner, InventoryStockType, InventorySpecialStockType, MaterialBaseUnit, CompanyCode, FiscalYearVariant