P_MatlBasedCmpstnCompSemObj

@EndUserText.label: 'Semantic Object of Material Based Composition Components'
@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'PMCOMPSEMOBJ',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #CONSUMPTION
@VDM.private: true

define view P_MatlBasedCmpstnCompSemObj
  as select from I_ChmlCmplncInfo

  association [1..1] to P_CChmlCmplConstants as _Constants on _Constants.ConstantRawMaterialSemObj = _Constants.ConstantRawMaterialSemObj
{
      --ChmlCmplncInfoUUID
  key ChmlCmplncInfoUUID,

      --SemanticObject
      case
        when MaterialIsSourced = 'X'
          then _Constants[inner].ConstantRawMaterialSemObj --'RawMaterialChemicalInfo'
        when MaterialIsProduced = 'X'
          then _Constants[inner].ConstantUnpackagedProdSemObj --'UnpackagedChemicalInfo'
      end as SemanticObject,

      -- needed for DCL
      MaterialIsSold,
      MaterialIsTransported,
      MaterialIsSourced,
      MaterialIsProduced,
      ProdStewardshipRespUnit
}