P_MaintOrdEnhcdObjectListItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.ignorePropagatedAnnotations: true
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
define view entity P_MaintOrdEnhcdObjectListItem
  as select from I_MaintOrderObjectListItem
  association [1..1] to I_MaintenanceOrder        as _MaintenanceOrder        on $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
  association [0..1] to I_MaintenanceNotification as _MaintenanceNotification on $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
  association [0..1] to I_Material                as _Assembly                on $projection.Assembly = _Assembly.Material
  association [0..1] to I_Material                as _Material                on $projection.Material = _Material.Material
{
  key MaintenanceOrder,
  key MaintenanceOrderObjectList,
  key MaintenanceObjectListItem,
  key cast ('' as maintordenhcdobjlistitemsource preserving type ) as MaintOrdEnhcdObjListItemSource,
  key Equipment,
  key cast ( FunctionalLocation as vdm_eam_tplnr preserving type ) as FunctionalLocation,
      MaintObjectLocAcctAssgmtNmbr,
      MaintenanceNotification,
      Assembly,
      Material,
      SerialNumber,
      UniqueItemIdentifier,
      MaintObjectListItemSequence,

      _MaintenanceOrder,
      _Equipment,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Assembly,
      _Material
}

union all select from I_MaintenanceOrder
association [1..1] to I_MaintenanceOrder          as _MaintenanceOrder          on $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
association [0..1] to I_Equipment                 as _Equipment                 on _Equipment.Equipment = $projection.Equipment
association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.MaintObjectLocAcctAssgmtNmbr
association [0..1] to I_MaintenanceNotification   as _MaintenanceNotification   on $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
association [0..1] to I_Material                  as _Assembly                  on $projection.Assembly = _Assembly.Material
association [0..1] to I_Material                  as _Material                  on $projection.Material = _Material.Material
{
  key MaintenanceOrder,
  key cast(0 as objknr)                                                                       as MaintenanceOrderObjectList,
  key cast(0 as objza)                                                                        as MaintenanceObjectListItem,
  key cast ('2' as maintordenhcdobjlistitemsource )                                           as MaintOrdEnhcdObjListItemSource,
  key Equipment,
  key cast ( _LocationAccountAssignment.FunctionalLocation as vdm_eam_tplnr preserving type ) as FunctionalLocation,
      MaintObjectLocAcctAssgmtNmbr,
      cast ('' as qmnum )                                                                     as MaintenanceNotification,
      Assembly,
      Material,
      SerialNumber,
      cast ('' as uii_char72)                                                                 as UniqueItemIdentifier,
      cast('' as obsort)                                                                      as MaintObjectListItemSequence,

      _MaintenanceOrder,
      _Equipment,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Assembly,
      _Material
}
where
     _LocationAccountAssignment.FunctionalLocation is not initial
  or Equipment                                     is not initial

union all select distinct from I_MaintOrderOperAndSubOper
association [1..1] to I_MaintenanceOrder          as _MaintenanceOrder          on $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
association [0..1] to I_Equipment                 as _Equipment                 on _Equipment.Equipment = $projection.Equipment
association [0..1] to I_LocationAccountAssignment as _LocationAccountAssignment on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = $projection.maintobjectlocacctassgmtnmbr
association [0..1] to I_MaintenanceNotification   as _MaintenanceNotification   on $projection.MaintenanceNotification = _MaintenanceNotification.MaintenanceNotification
association [0..1] to I_Material                  as _Assembly                  on $projection.Assembly = _Assembly.Material
association [0..1] to I_Material                as _Material                on $projection.material = _Material.Material
{
  key MaintenanceOrder,
  key cast(0 as objknr)                                            as MaintenanceOrderObjectList,
  key cast(0 as objza)                                             as MaintenanceObjectListItem,
  key cast ('1' as maintordenhcdobjlistitemsource )                as MaintOrdEnhcdObjListItemSource,
  key Equipment,
  key cast ( FunctionalLocation as vdm_eam_tplnr preserving type ) as FunctionalLocation,
      _FunctionalLocation._LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr,
      cast('' as qmnum)                                            as MaintenanceNotification,
      Assembly,
      _Assembly.Material,
      _Equipment.SerialNumber,
      cast ('' as uii_char72)                                      as UniqueItemIdentifier,
      cast('' as obsort)                                           as MaintObjectListItemSequence,

      _MaintenanceOrder,
      _Equipment,
      _LocationAccountAssignment,
      _MaintenanceNotification,
      _Assembly,
      _Material
}
where
     FunctionalLocation is not initial
  or Equipment          is not initial