P_MPEInspIssuesByOperation

@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #M, dataClass: #TRANSACTIONAL }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Inspection Issues By Operation'
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view entity P_MPEInspIssuesByOperation as select from I_InspectionOperation

  association [0..1] to P_MPEOpCharcWithRjcn       as _OpCharcWithRjcn
   on     $projection.InspectionLot                 = _OpCharcWithRjcn.InspectionLot
      and $projection.InspPlanOperationInternalID   = _OpCharcWithRjcn.InspPlanOperationInternalID
      and $projection.OrderInternalBillOfOperations = _OpCharcWithRjcn.OrderInternalBillOfOperations
  
  association [0..1] to P_MPEOpInspPtWithRjcn     as _OpInspPtWithRjcn
    on     $projection.InspectionLot               = _OpInspPtWithRjcn.InspectionLot
       and $projection.InspPlanOperationInternalID = _OpInspPtWithRjcn.InspPlanOperationInternalID
       and $projection.OrderInternalBillOfOperations = _OpInspPtWithRjcn.OrderInternalBillOfOperations

  association [0..1] to P_MPEInspOpUsageDecision as _InspOperationUsageDecision
    on     $projection.InspectionLot               = _InspOperationUsageDecision.InspectionLot
       and $projection.InspPlanOperationInternalID = _InspOperationUsageDecision.InspPlanOperationInternalID
       and $projection.OrderInternalBillOfOperations = _InspOperationUsageDecision.OrderInternalBillOfOperations 

{
  key I_InspectionOperation.InspectionLot                 as InspectionLot,
  key I_InspectionOperation.InspPlanOperationInternalID   as InspPlanOperationInternalID,   // = afvc.aplzl = qaop.vorglfnr !

  
      I_InspectionOperation.OrderInternalBillOfOperations as OrderInternalBillOfOperations, // = afvc.aufpl

  
  case
    when _OpCharcWithRjcn.InspPlanOperationInternalID is not null
    then 'X' 
    else ' ' 
  end as InspHasRejectedCharc,
  
  case
    when _OpInspPtWithRjcn.InspPlanOperationInternalID is not null
    then 'X' 
    else ' ' 
  end as InspHasRejectedInspSubset,
  
  case
    when _InspOperationUsageDecision.InspOpUsageDecisionValuation = 'R'
    then 'X' 
    else ' ' 
  end as InspHasRejectedInspLot,
    
  _InspOperationUsageDecision

}