P_InspectionOperationHeader

@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Header of Inspection Operation'
@Search.searchable: false
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L, //expected number of rows < 10.000.000

    serviceQuality: #D 
}
@VDM.private: true
define view entity P_InspectionOperationHeader 
as select from I_InspectionOperation as _InspOpHeader
left outer to one join I_InspOperationAggregate     as _InspOperationAggregate     on  _InspOpHeader.InspPlanOperationInternalID = _InspOperationAggregate.InspPlanOperationInternalID
                                                                                       and _InspOpHeader.InspectionLot               = _InspOperationAggregate.InspectionLot
{
      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionLotStdVH',
                     element: 'InspectionLot' }
        }]
    key _InspOpHeader.InspectionLot,
    key _InspOpHeader.InspPlanOperationInternalID,
   _InspOpHeader._InspectionLot.InspectionLotType,
   _InspOpHeader._Plant.Plant,
    //Visible controler of sample bar: when 2 ,material sample exist

      case _InspOpHeader._InspectionLot._InspSubsetFieldCombination.SamplingProcedureInspSubset
      when '2' then 1
      else 0 end as InspLotHasSubsets,
      
       //Total number of Characteristics

    case _InspOpHeader._InspectionLot._InspSubsetFieldCombination.SamplingProcedureInspSubset
    when '2' then (_InspOperationAggregate.InspSubsetCharcAcceptedCount +
    _InspOperationAggregate.InspSubsetCharcRejectedCount +
    _InspOperationAggregate.InspSubsetCharcOpenCount)
    else (_InspOperationAggregate.InspCharOpenCount + 
    _InspOperationAggregate.InspCharAcceptedCount + 
    _InspOperationAggregate.InspCharRejectedCount)
    end as InspCharCount,
    _InspOperationAggregate.InspSubsetCharcAcceptedCount,
    _InspOperationAggregate.InspSubsetCharcRejectedCount,
    _InspOperationAggregate.InspSubsetCharcOpenCount,
    _InspOperationAggregate.InspCharOpenCount,
    _InspOperationAggregate.InspCharAcceptedCount,
    _InspOperationAggregate.InspCharRejectedCount,
     //Check whether this operation has characteristics: when 0 no characteristic

      case _InspOpHeader._InspectionLot.InspectionSubsetType
      when '3' then case(_InspOperationAggregate.InspCharcAcceptedSampleCount+
                         _InspOperationAggregate.InspCharOpenSampleCount+
                         _InspOperationAggregate.InspCharRejectedSampleCount)
                    when 0 then 0 else 1 end
      else case(_InspOperationAggregate.InspCharOpenCount+
                _InspOperationAggregate.InspCharAcceptedCount+
                _InspOperationAggregate.InspCharRejectedCount)
           when 0 then 0 else 1 end
      end        as InspOpHasCharc,
      
    //Asscociations

    _InspOpHeader._InspectionLot
}