P_InApprovalPurchaseOrderItem

@AbapCatalog.sqlViewName: 'PINAPPO'
@EndUserText.label: 'In Approval Purchase Order Items'
@AbapCatalog.compiler.compareFilter: true
@VDM.private: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST,#UNION]
@AbapCatalog.preserveKey:true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY

define view P_InApprovalPurchaseOrderItem                   //^3349445


  as select from I_PurchaseOrderItem

  association [0..*] to I_PurchasingCategoryMatlGroup as _PurchasingCategoryMatlGroup on $projection.MaterialGroup = _PurchasingCategoryMatlGroup.MaterialGroup


{
  key  PurchaseOrder,
  key  PurchaseOrderItem,

       //Filters

       MaterialGroup,
       _PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory as PurchasingCategory,
       _PurchaseOrder.PurchasingOrganization,
       _PurchaseOrder.PurchasingGroup,
       CompanyCode,
       Plant,


       @ObjectModel.text.element: ['MaterialName']
       @Consumption.labelElement: 'MaterialName'
       Material,

       @Semantics.text: true
       _Material._Text[1: Language = $session.system_language].MaterialName as MaterialName,

       _PurchaseOrder.PurchaseOrderDate,

       @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
       cast(OrderQuantity as abap.dec( 21, 5 )) as OrderQuantity,

       @ObjectModel.text.element: ['SupplierName']
       @Consumption.labelElement: 'SupplierName'
       _PurchaseOrder.Supplier,

       @Semantics.text: true
       _PurchaseOrder._Supplier.SupplierName,

       cast( NetAmount as abap.curr(21,5)) as NetAmount,

       @Semantics.unitOfMeasure: true
       PurchaseOrderQuantityUnit,

       // fields for DCL

       @UI.hidden: true
       _PurchaseOrder
}
where
       PurchasingDocumentDeletionCode                =  ''
  and  _PurchaseOrder.PurchasingDocumentDeletionCode =  ''
  and(
       IsCompletelyDelivered                         =  ''
    or IsFinallyInvoiced                             =  ''
  )
    and PurchaseOrderItemCategory                     <> '9' // do not consider Service PO

    and PurchaseOrderItemCategory                     <> '1'
  //Conditions for In Approval PO Items

  and  _PurchaseOrder.ReleaseIsNotCompleted          =  'X'
  and  _PurchaseOrder.PurchasingCompletenessStatus   <> 'X'
  and  _PurchaseOrder.PurchasingProcessingStatus     <> '08' //08 => Rejected

// filter out statistical Items (excluding Retail i.e Material = '')

  and not( Material = '' and IsStatisticalItem = 'X' )      //v3349445