P_IRM_Financial_Transaction

DDL: P_IRM_FINANCIAL_TRANSACTION SQL: PFINTRANS Type: view BASIC

P_IRM_Financial_Transaction is a Basic CDS View in SAP S/4HANA. It reads from 2 data sources (vtbfha, vtbfhazu) and exposes 16 fields with key fields CompanyCode, FinancialTransaction, FinancialInstrumentActivity. It has 3 associations to related views.

2 data source(s) 16 fields

Data Sources (2)

SourceAliasJoin Type
vtbfha FinancialTransaction from
vtbfhazu TransactionHistory inner

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_Currency _Currency $projection.TransactionCurrency = _Currency.Currency
[1..1] I_CompanyCode _CompanyCode $projection.CompanyCode = _CompanyCode.CompanyCode
[1..1] I_SecurityAccount _SecurityAccount $projection.CompanyCode = _SecurityAccount.CompanyCode and $projection.SecurityAccount = _SecurityAccount.SecurityAccount

Annotations (7)

NameValueLevelField
AbapCatalog.sqlViewName PFINTRANS view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #NOT_REQUIRED view
AbapCatalog.preserveKey true view
VDM.viewType #BASIC view
VDM.private true view

Fields (16)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode vtbfha bukrs
KEY FinancialTransaction vtbfha rfha
KEY FinancialInstrumentActivity vtbfha rfhazul
TreasuryContractType vtbfha rantyp
FinancialInstrProductCategory
FinancialInstrumentProductType vtbfha sgsart
FinancialInstrTransactionType
Counterparty
DifferentiationPortfolio vtbfha rportb
TransactionCurrency vtbfha wgschft
SecurityAccount vtbfha rldepo
TermStartDate vtbfha dblfz
TermEndDate vtbfhazu delfz
_Currency _Currency
_CompanyCode _CompanyCode
_SecurityAccount _SecurityAccount 
@AbapCatalog.sqlViewName: 'PFINTRANS'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.preserveKey:true 
@VDM.viewType: #BASIC
@VDM.private:true
define view P_IRM_Financial_Transaction
  as select from vtbfha   as FinancialTransaction
    inner join   vtbfhazu as TransactionHistory on  FinancialTransaction.bukrs   = TransactionHistory.bukrs
                                                and FinancialTransaction.rfha    = TransactionHistory.rfha
                                                and FinancialTransaction.rfhazul = TransactionHistory.rfhazu

  association [1..1] to I_Currency        as _Currency        on $projection.TransactionCurrency = _Currency.Currency
  association [1..1] to I_CompanyCode     as _CompanyCode     on $projection.CompanyCode         = _CompanyCode.CompanyCode
  association [1..1] to I_SecurityAccount as _SecurityAccount on $projection.CompanyCode         = _SecurityAccount.CompanyCode 
                                                             and $projection.SecurityAccount     = _SecurityAccount.SecurityAccount
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key FinancialTransaction.bukrs                                               as CompanyCode,
  key FinancialTransaction.rfha                                                as FinancialTransaction,
  key FinancialTransaction.rfhazul                                             as FinancialInstrumentActivity,

      FinancialTransaction.rantyp                                              as TreasuryContractType,
      cast(FinancialTransaction.sanlf  as ftr_gen_fin_instr_prod_categ)        as FinancialInstrProductCategory,
      FinancialTransaction.sgsart                                              as FinancialInstrumentProductType,
      cast(FinancialTransaction.sfhaart as ftr_gen_transaction_type)           as FinancialInstrTransactionType,
      cast(FinancialTransaction.kontrh as rkontrah_new)                        as Counterparty,
      FinancialTransaction.rportb                                              as DifferentiationPortfolio,
      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      FinancialTransaction.wgschft                                             as TransactionCurrency,
      @ObjectModel.foreignKey.association: '_SecurityAccount'
      FinancialTransaction.rldepo                                              as SecurityAccount,

      FinancialTransaction.dblfz                                               as TermStartDate,
      TransactionHistory.delfz                                                 as TermEndDate,

      _Currency,
      _CompanyCode,
      _SecurityAccount
}
where
  //Security

     FinancialTransaction.sanlf = '020'
  or FinancialTransaction.sanlf = '040'
  or FinancialTransaction.sanlf = '042'
  //Money market

  or FinancialTransaction.sanlf = '510'
  or FinancialTransaction.sanlf = '520'
  or FinancialTransaction.sanlf = '530'
  or FinancialTransaction.sanlf = '540'
  or FinancialTransaction.sanlf = '550'
  or FinancialTransaction.sanlf = '580'

Learn More