P_GoodsIssueDataSIT

@AbapCatalog.sqlViewName: 'PGOODSISSDATASIT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass:#MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Private View for Goods Issue Data SIT'


@VDM.private: true
@VDM.viewType: #COMPOSITE

define view P_GoodsIssueDataSIT
  as select from I_PurchasingDocumentHistoryBsc as _purchDoc
  
  association [1..1] to I_GoodsMovementDocument as _matDoc on  _purchDoc.PurchasingHistoryDocument     = _matDoc.MaterialDocument
                                                           and _purchDoc.PurchasingHistoryDocumentItem = _matDoc.MaterialDocumentItem
                                                           and _purchDoc.PurchasingHistoryDocumentYear = _matDoc.MaterialDocumentYear
                                                           and _purchDoc.PurchasingDocument            = _matDoc.PurchaseOrder
                                                           and _purchDoc.PurchasingDocumentItem        = _matDoc.PurchaseOrderItem     
                                                           and _purchDoc.Material                      = _matDoc.Material                                                                                                                            
                                                           and _matDoc.MaterialDocumentRecordType      = 'MDOC'

{

  key _purchDoc.PurchasingHistoryDocument                                                                  as MaterialDocument,
  key _purchDoc.PurchasingHistoryDocumentItem                                                              as MaterialDocumentItem,
  key _purchDoc.PurchasingHistoryDocumentYear                                                              as MaterialDocumentYear,  
  key _purchDoc.PurchasingDocument                                                                         as PurchaseOrder,
  key _purchDoc.PurchasingDocumentItem                                                                     as PurchaseOrderItem,
  
      _purchDoc.Material,
      _matDoc.StorageLocation,
      _matDoc.Batch,
      _matDoc.MaterialBaseUnit, //2813353

      cast(_purchDoc.GoodsMovementType  as nsdm_gi_bwart preserving type)                                  as GoodsIssueMovementType,
      cast(_purchDoc.PostingDate        as nsdm_gi_budat preserving type)                                  as GoodsIssuePostingDate,
      cast(_matDoc.QuantityInBaseUnit as nsdm_gi_bstmg preserving type)                                    as GoodsIssueQuantity,
      cast(_matDoc.GoodsReceiptQtyInOrderUnit as nsdm_gi_bstmg preserving type)                            as GoodsIssueQtyInOrderUnit, //2813353

      _matDoc.GoodsMovementIsCancelled                                                                     as GoodsIssueIsCanceled,
      cast(_matDoc.Plant as nsdm_gi_werks preserving type)                                                 as IssuingPlant,
      cast(_matDoc.CompanyCode as nsdm_gi_bukrs preserving type)                                           as IssuingCompanyCode,       //3277117

      cast(_purchDoc.CreatedByUser as mmim_gi_created_by_user       preserving type)                       as GICreatedByUser,
      cast(_matDoc.StorageLocation as mmim_issuing_storage_location preserving type)                       as IssuingStorageLocation,
      cast(_matDoc.Batch as mmim_issuing_batch preserving type)                                            as IssuingBatch,
      cast(_purchDoc.DeliveryDocument as mmim_gi_delivery_document preserving type)                        as GoodsIssueForDeliveryDoc,
      cast(_purchDoc.DeliveryDocumentItem as mmim_gi_delivery_document_item preserving type)               as GoodsIssueForDeliveryDocItem,
      cast(_matDoc._DeliveryDocumentItem.CreationDate as mmim_gi_deliv_doc_itm_crtn_dte  preserving type)  as GoodsIssueDelivDocItmCrtnDte,
      cast(_matDoc._DeliveryDocumentItem.ActualDeliveredQtyInBaseUnit as mmim_gi_deliv_doc_itm_quantity )  as GoodsIssueDelivDocItmQty,
      cast(_matDoc._DeliveryDocumentItem.Batch as mmim_gi_deliv_doc_itm_batch)                             as GoodsIssueDelivDocItmBatch,
      cast(_matDoc._DeliveryDocument.DeliveryDocumentType as mmim_gi_deliv_doc_type)                       as GoodsIssueDelivDocType,
      cast(_matDoc._DeliveryDocument.SDDocumentCategory as mmim_gi_deliv_doc_cat preserving type)          as GoodsIssueDelivDocCat,      
      cast(_matDoc._DeliveryDocumentItem.GoodsMovementStatus as mmim_gi_deliv_doc_itm_status)              as GoodsIssueDelivDocItmStatus,

      cast( dats_tims_to_tstmp(_matDoc.CreationDate, _matDoc.CreationTime, 'UTC', $session.client, 'NULL' )  
                                                                          as  mmim_date_time )             as GoodsIssueUTCDateTime,
      _purchDoc.Quantity                                                                                   as QuantityInPurchaseOrderUnit,
      DebitCreditCode                                                      //3293401

}

where
     _purchDoc.PurchasingHistoryCategory = 'U'
 and _matDoc.IsEffectiveGoodsMovement    = 'X'