P_FixedAssetTransaction

@AbapCatalog: {sqlViewName: 'PFASSETTRAN', preserveKey: true}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true

define view P_FixedAssetTransaction
  with parameters
    P_AssetAccountingKeyFigureSet : faa_key_figure_set

  as select from P_FxdAstValueWithCurrencyRole
    inner join   I_AssetKeyFigureSetSpec       as AssetKeyFigureSetSpec on AssetKeyFigureSetSpec.AssetAccountingKeyFigureSet = :P_AssetAccountingKeyFigureSet
    inner join   I_AssetKeyFigureSpecification as AssetKeyFigureSpec    on  AssetKeyFigureSpec.AssetAccountingKeyFigure      = AssetKeyFigureSetSpec.AssetAccountingKeyFigure
                                                                        and AssetKeyFigureSpec.AssetAcctAnlytlTransClassfctn = P_FxdAstValueWithCurrencyRole.AssetAcctTransClassfctn
                                                                        and AssetKeyFigureSpec.SubLedgerAcctLineItemType     = P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType

{
  key P_FxdAstValueWithCurrencyRole.CompanyCode,
  key MasterFixedAsset,
  key FixedAsset,
  key FiscalYear,
  key FiscalPeriod,
  key AssetDepreciationArea,
  key LedgerGroup,
  key Ledger,
  key AccountingDocument,
  key TransactionSubitem,
  key DebitCreditCode,
  key CurrencyRole,
  key P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType,

      LedgerFiscalYear,
      FiscalYearVariant,
      FiscalYearPeriod,

      AssetKeyFigureSpec.AssetAccountingKeyFigure,
      GroupMasterFixedAsset,
      GroupFixedAsset,
      ChartOfDepreciation,
      AccountingDocumentCreationDate,
      CreationTime,
      PostingDate,
      DocumentDate,
      AssetValueDate,
      AccountingDocCreatedByUser,
      AssetTransactionType,
      AssetAcctTransClassfctn,
      AssignmentReference,
      DocumentItemText,
      ReferenceDocumentType,
      ReferenceDocument,
      LogicalSystem,
      ReferenceDocumentContext,
      ReversalReferenceDocumentCntxt,
      ReversalReferenceDocument,
      ReversalTransactionSubitem,
      IsReversal,
      IsReversed,
      BusinessArea,
      Segment,
      FinancialAccountType,
      ControllingArea,
      FinancialManagementArea,
      Fund,
      GrantID,
      FunctionalArea,
      BudgetPeriod,

      case when AssetAcctTransClassfctn = '11' or AssetAcctTransClassfctn = '15' or
                AssetAcctTransClassfctn = '21' or AssetAcctTransClassfctn = '31' or
                AssetAcctTransClassfctn = 'M1'
                then cast('1' as fis_assettransactionvariant preserving type)  //Acquistion

           when AssetAcctTransClassfctn = '12' or AssetAcctTransClassfctn = 'A8' or
                AssetAcctTransClassfctn = 'B8'
                then cast('2' as fis_assettransactionvariant preserving type)  //Retirement

           when AssetAcctTransClassfctn = '13' or AssetAcctTransClassfctn = '14' or
                AssetAcctTransClassfctn = 'M2'
                then cast('3' as fis_assettransactionvariant preserving type)  //Intercompany Transfer

           when AssetAcctTransClassfctn = '' and ( P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType = '07902' or
                                                   P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType = '07903' or
                                                   P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType = '07904')
                then cast('2' as fis_assettransactionvariant preserving type)  //Retirement

      else
          cast('0' as fis_assettransactionvariant preserving type)  //Other Transactions

      end as AssetTransactionVariant,

      @Semantics.currencyCode:true
      DisplayCurrency,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      AmountInDisplayCurrency,

      IsStatisticalDocument
}
where
           AssetAcctTransClassfctn                                 <> '00' //No balance carry forward items

  and(
           AssetAcctTransClassfctn                                 <> '06'
    or //No items from depreciation run

    (
           AssetAcctTransClassfctn                                 =  '06'
      and(
           P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType =  '07203'
        or P_FxdAstValueWithCurrencyRole.SubLedgerAcctLineItemType =  '07204'
      )
    )
  ) //No items from depreciation run but revaluations

  and      AssetAcctTransClassfctn                                 <> 'C7' //No items from Legacy Data Transfer FY Start Value

  and      AssetAcctTransClassfctn                                 <> 'E7' //No items from Legacy Data Transfer FY Ending Balance