P_FixedAssetForLedger

@AbapCatalog: { sqlViewName: 'PFIASSETFORLDGR', preserveKey: true, compiler.compareFilter: true }
@VDM.viewType: #BASIC
@VDM.private:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_FixedAssetForLedger
  as select from anla
    inner join   finsc_ledger                                                    on finsc_ledger.mandt = anla.mandt
    inner join   P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = ''
{
  key anla.bukrs         as CompanyCode,
  key anla.anln1         as MasterFixedAsset,
  key anla.anln2         as FixedAsset,
  key finsc_ledger.rldnr as Ledger,

      anla.aktiv         as AssetCapitalizationDate,
      anla.deakt         as AssetDeactivationDate,
      anla.zugdt         as AcquisitionValueDate,
      anla.zujhr         as FirstAcquisitionFiscalYear,
      anla.zuper         as FirstAcquisitionFiscalPeriod,
      anla.lrvdat        as LastRevaluationDate
}

union all select from faat_md_ld
  inner join          P_TF_AssetRedesignSwitchStatus( P_SAPClient : $session.client ) on P_TF_AssetRedesignSwitchStatus.IsActive = 'X'
{
  key    faat_md_ld.comp_code           as CompanyCode,
  key    faat_md_ld.asset_no            as MasterFixedAsset,
  key    faat_md_ld.asset_subno         as FixedAsset,
  key    faat_md_ld.ledger              as Ledger,

         faat_md_ld.capitalization_date as AssetCapitalizationDate,
         faat_md_ld.deactivation_date   as AssetDeactivationDate,
         faat_md_ld.acquisition_date    as AcquisitionValueDate,
         faat_md_ld.acquisition_year    as FirstAcquisitionFiscalYear,
         faat_md_ld.acquisition_period  as FirstAcquisitionFiscalPeriod,
         faat_md_ld.last_reval_date     as LastRevaluationDate
}