P_FSTMT_Hry_leaf

@AbapCatalog.sqlViewName: 'PFSTMT_HR_LEAF'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType : { dataClass:      #CUSTOMIZING,
                           serviceQuality: #D,
                            sizeCategory:  #S }
@VDM.private: true
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE

define view P_FSTMT_Hry_leaf
 
  as select from        hrrp_node  as leaf
     inner join hrrp_node as parnode
             on leaf.hryid    = parnode.hryid     and
                leaf.hryver   = parnode.hryver    and
                leaf.parnode  = parnode.hrynode   and
                leaf.hryvalto = parnode.hryvalto  and
                parnode.nodecls   = '' and
                ( parnode.nodetype  = 'N' or parnode.nodetype  = 'O' )

{
  key leaf.hryid,
  key leaf.hryver,
  key leaf.nodecls,
  key leaf.hrynode  as childnode,
  key leaf.parnode  as hrynode,
  key leaf.hryvalto,
      leaf.hryvalfrom,
      leaf.balind,
      case parnode.nodetype
        when 'O'
        then leaf.parnode
        else leaf.hrynode end as balnode,
      leaf.nodetype,
      leaf.nodevalue,
      leaf.nodevalue as racct,
      '' as sign,
      parnode.parnode,
      parnode.hryseqnbr,
      parnode.hrylevel  
}
   where leaf.nodetype = 'L'
   union select distinct from hrrp_node as plnode        // profilt&loss node

      inner join hrrp_node as dnode
              on plnode.hryid    = dnode.hryid     and
                 plnode.hryver   = dnode.hryver    and
                 plnode.nodecls  = ''              and
                 plnode.hrynode  = dnode.parnode   and
                 plnode.hryvalto = dnode.hryvalto  and
                 dnode.nodetype  = 'D' 
   {
      key dnode.hryid ,
      key dnode.hryver,
      key dnode.nodecls,
      key plnode.nodevalue as childnode,
      key dnode.parnode    as hrynode,
      key dnode.hryvalto,
          dnode.hryvalfrom,
          plnode.balind,
          plnode.hrynode  as balnode,
          'L' as NODETYPE,
          plnode.nodevalue,
          dnode.nodevalue as racct ,
          '-' as sign,
          plnode.parnode,
          plnode.hryseqnbr,
          plnode.hrylevel 
}
   where plnode.nodetype = 'A' or
         plnode.nodetype = 'K' or
         plnode.nodetype = 'M'