P_FSTMT_GLACCOUNT_ENH

@AbapCatalog.sqlViewName: 'PFSTMT_GLACCTEN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
//@EndUserText.label: 'GL account info regarding reclass'

@ObjectModel.usageType : { dataClass:      #CUSTOMIZING,
                           serviceQuality: #D,
                            sizeCategory:  #S }
@VDM.private: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_FSTMT_GLACCOUNT_ENH   with parameters 
    p_keydate     :abap.dats,
    p_hierarchy   :hryid 

  as select distinct from        P_FSTMT_MAP_ACCT_HIER( p_keydate:$parameters.p_keydate , p_hierarchy:$parameters.p_hierarchy ) as acct
                                                              
        left outer join R_HierRuntimeRprstnNode as node on node.HierarchyNodeClass = acct.hier_CoA
                                            and node.HierarchyID =  $parameters.p_hierarchy
                                            and node.HierarchyNodeVal = acct.FSVAccount
                                            and node.ValidityEndDate  >= $parameters.p_keydate
                                            and node.ValidityStartDate <= $parameters.p_keydate
                                            and node.NodeType          = 'L'
                                            
                                            
                        left outer join R_HierRuntimeRprstnNodeAttrib as attr on attr.HierarchyID = node.HierarchyID
                                                         and attr.ValidityEndDate  = node.ValidityEndDate
                                                         and attr.HierarchyNode   = node.HierarchyNode
                                                         and attr.HierarchyNodeClass = acct.hier_CoA
                                                         and attr.ParentNode   = node.ParentNode
                                                         and attr.HierarchyNodeAttributeName = 'REGROUPING'

                                                         
                                 left outer to one join R_HierRuntimeRprstnAttrib as header on header.HierarchyID = $parameters.p_hierarchy
                                                           and header.ValidityEndDate = node.ValidityEndDate 
                                                           and header.HierarchyAttributeName = 'AGING'
                                                              
                 
{
  key Ledger                     as Ledger,
  key acct.CompanyCode           as CompanyCode,
  key acct.GLAccount             as GLAccount,
      acct.FSVAccount            as FSVAccount,
      acct.AlternativeGLAccount  as AlternativeGLAccount,
      acct.CorporateGroupAccount as CorporateGroupAccount,
      node.HierarchyID           as hierarchy,
      node.HierarchyVersion      as hryver,
      acct.AccountIsOpenItemManaged,
           
      case attr.HierarchyNodeAttributeName 
           when 'REGROUPING' 
           then 'X' else '' end as AccountIsToReclassify,
        header.HierAttributeRangeFromVal as aging,
      node.HierarchyNode                 as Node,
      coalesce( node.ParentNode, '00NOTASSGND' )  as ParentNode,
      node.HierarchyNodeLevel as NodeLevel,
      node.HierarchyNodeVal as   NodeValue,           
      case node.DebitCreditCode
         when 'S' then '+'
         when 'H' then '-'
         else '' end as plumi,
      attr.HierNodeAttributeRangeFromVal as AgingIncrement
//      skb.ReconciliationAccountType


      
      

      
//     tag.IsFunctionalAreaPermitted           

}