P_ES_TaxReturnBoxATRCheckCorr

@AbapCatalog.sqlViewName: 'PESBOXATRCHKCORR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private: true
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@AbapCatalog.preserveKey: true

define view P_ES_TaxReturnBoxATRCheckCorr
  with parameters
    P_TaxBoxConfiguration : figen_tdt_taxbox_config
  as select from I_StRpTaxItemBoxConfiguration ( P_TaxBoxConfiguration  : $parameters.P_TaxBoxConfiguration )
{
  key Country,
      // key TaxItemGroupingVersion, // Superfluous, already covered by UnifiedTaxBoxStructureType

  key TaxCode,
  key TransactionTypeDetermination,
  key DebitCreditCode,
  key TaxDeclnAmountType,
  key TaxBoxStrucValidityStartDate,
  key UnifiedTaxBoxStructureType,
      // key TaxBoxStructureType, // Superfluous, already covered by UnifiedTaxBoxStructureType

  key AccountingDocumentType,
  key SupplierAccountGroup,
  key TaxRateValidityStartDate,
  key SpecialGLCode,
  key TaxCountry,
      // key TaxJurisdiction // Not Propagated

      TaxBoxStrucValidityEndDate, // Boud to TaxBoxStrucValidityStartDate

      TaxRateValidityEndDate, // Bound to TaxRateValidityStartDate

      'X' as InCorrectionBox
}
where
  // Output VAT

     TaxBox = '14' // Correction invoices taxable amount

  or TaxBox = '15' // Correction invoices tax amount

  or TaxBox = '25' // Correction invoices taxable amount Equalization VAT

  or TaxBox = '26' // Correction invoices tax amount Equalization VAT (Only equalization VAT ASB)

  // Input VAT

  or TaxBox = '40' // Correction invoices taxable amount

  or TaxBox = '41' // Correction invoices tax amount

group by
  Country,
  TaxCode,
  TransactionTypeDetermination,
  DebitCreditCode,
  TaxDeclnAmountType,
  TaxBoxStrucValidityStartDate,
  UnifiedTaxBoxStructureType,
  AccountingDocumentType,
  SupplierAccountGroup,
  TaxRateValidityStartDate,
  SpecialGLCode,
  TaxCountry,
  TaxBoxStrucValidityEndDate,
  TaxRateValidityEndDate