P_EBWObjectWIPReserves

@AbapCatalog.sqlViewName: 'PFIEBWOBJWIPRSRV'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'EBW Object Actual Cost'

@VDM.viewType: #BASIC
@VDM.private:true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view P_EBWObjectWIPReserves
  with parameters
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod
  as select from acdoca   as _item
    inner join   I_Ledger as _ledger on  _ledger.Ledger          = _item.rldnr
                                     and _ledger.IsLeadingLedger = 'X'
{
  key rbukrs                                    as CompanyCode,
  key cast(concat(accasty, accas) as j_objnr )  as ObjectNumber,
  key aufnr                                     as OrderNumber,
  key racct                                     as GLAccount,
  key gkont                                     as OffsettingAccount,
  key slalittype                                as SubLedgerAcctLineItemType,

      sum( hsl )                                as hsl,
      sum( ksl )                                as ksl,
      sum( osl )                                as osl,
      sum( vsl )                                as vsl,
      sum( bsl )                                as bsl,
      sum( csl )                                as csl,
      sum( dsl )                                as dsl,
      sum( esl )                                as esl,
      sum( fsl )                                as fsl,
      sum( gsl )                                as gsl

}
where
       bttype            = 'EBWP'
  and(
       slalittype        = '09100'
    or slalittype        = '09110'
  )
  and  _item.fiscyearper >= $parameters.P_FromFiscalYearPeriod
  and  _item.fiscyearper <= $parameters.P_ToFiscalYearPeriod
group by
  rbukrs,
  accasty,
  accas,
  racct,
  gkont,
  aufnr,
  slalittype